source: smplayer/trunk/src/smplayer.pro@ 177

Last change on this file since 177 was 176, checked in by Silvan Scherrer, 10 years ago

smplayer: update trunk to version 16.4
  • Property svn:eol-style set to LF
File size: 15.2 KB
Line 
1TEMPLATE = app
2LANGUAGE = C++
3
4CONFIG += qt warn_on
5CONFIG += release
6#CONFIG += debug
7
8QT += network xml
9
10RESOURCES = icons.qrc
11
12#DEFINES += EXPERIMENTAL
13DEFINES += SINGLE_INSTANCE
14DEFINES += FIND_SUBTITLES
15DEFINES += VIDEOPREVIEW
16DEFINES += YOUTUBE_SUPPORT
17DEFINES += BLURAY_SUPPORT
18DEFINES += GUI_CHANGE_ON_RUNTIME
19DEFINES += LOG_MPLAYER
20DEFINES += LOG_SMPLAYER
21DEFINES += DEFAULTGUI
22DEFINES += MINIGUI
23DEFINES += MPCGUI
24DEFINES += SKINS
25!os2 {
26DEFINES += MPRIS2
27}
28DEFINES += UPDATE_CHECKER
29DEFINES += CHECK_UPGRADED
30!os2 {
31DEFINES += AUTO_SHUTDOWN_PC
32}
33DEFINES += CAPTURE_STREAM
34DEFINES += BOOKMARKS
35DEFINES += MOUSE_GESTURES
36
37!os2 {
38DEFINES += MPV_SUPPORT
39}
40DEFINES += MPLAYER_SUPPORT
41
42# Whether to include support for the obsolete mplayer2 or not
43# (requires MPLAYER_SUPPORT)
44DEFINES += MPLAYER2_SUPPORT
45
46# Note to distro maintainers:
47# By disabling SHARE_ACTIONS or SHARE_WIDGET
48# you're preventing SMPlayer to receive donations and thus
49# SERIOUSLY HURTING THE DEVELOPMENT AND PUTTING
50# AT RISK THE CONTINUATION OF THIS PROJECT
51# Please don't.
52
53DEFINES += SHARE_ACTIONS
54DEFINES += SHARE_WIDGET
55
56
57#DEFINES += SIMPLE_BUILD
58
59contains( DEFINES, SIMPLE_BUILD ) {
60 DEFINES -= SINGLE_INSTANCE
61 DEFINES -= FIND_SUBTITLES
62 DEFINES -= VIDEOPREVIEW
63 DEFINES -= LOG_MPLAYER
64 DEFINES -= LOG_SMPLAYER
65 DEFINES -= MINIGUI
66 DEFINES -= MPCGUI
67 DEFINES -= SKINS
68 DEFINES -= MPRIS2
69 DEFINES -= UPDATE_CHECKER
70 DEFINES -= CHECK_UPGRADED
71 DEFINES -= SHARE_ACTIONS
72 DEFINES -= SHARE_WIDGET
73 DEFINES -= AUTO_SHUTDOWN_PC
74 DEFINES -= BOOKMARKS
75}
76
77isEqual(QT_MAJOR_VERSION, 5) {
78 QT += widgets gui
79 #DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x040000
80 DEFINES -= MPCGUI
81 win32 {
82 DEFINES -= MPRIS2
83 }
84}
85
86contains(QT_VERSION, ^4\\.[0-3]\\..*) {
87 message("Some features requires Qt > 4.3.")
88
89 contains( DEFINES, SINGLE_INSTANCE ) {
90 DEFINES -= SINGLE_INSTANCE
91 message("SINGLE_INSTANCE disabled.")
92 }
93
94 contains( DEFINES, YOUTUBE_SUPPORT ) {
95 DEFINES -= YOUTUBE_SUPPORT
96 message("YOUTUBE_SUPPORT disabled.")
97 }
98
99 contains( DEFINES, SKINS ) {
100 DEFINES -= SKINS
101 message("SKINS disabled.")
102 }
103
104 contains( DEFINES, FIND_SUBTITLES ) {
105 DEFINES -= FIND_SUBTITLES
106 message("FIND_SUBTITLES disabled.")
107 }
108
109 contains( DEFINES, UPDATE_CHECKER ) {
110 DEFINES -= UPDATE_CHECKER
111 message("UPDATE_CHECKER disabled.")
112 }
113}
114
115HEADERS += guiconfig.h \
116 config.h \
117 constants.h \
118 links.h \
119 svn_revision.h \
120 version.h \
121 chapters.h \
122 global.h \
123 paths.h \
124 helper.h \
125 colorutils.h \
126 translator.h \
127 subtracks.h \
128 tracks.h \
129 titletracks.h \
130 discname.h \
131 extensions.h \
132 desktopinfo.h \
133 myprocess.h \
134 mplayerversion.h \
135 playerid.h \
136 playerprocess.h \
137 infoprovider.h \
138 mplayerwindow.h \
139 mediadata.h \
140 audioequalizerlist.h \
141 mediasettings.h \
142 assstyles.h \
143 filters.h \
144 preferences.h \
145 filesettingsbase.h \
146 filesettings.h \
147 filesettingshash.h \
148 filehash.h \
149 tvsettings.h \
150 images.h \
151 inforeader.h \
152 deviceinfo.h \
153 recents.h \
154 urlhistory.h \
155 core.h \
156 logwindow.h \
157 infofile.h \
158 seekwidget.h \
159 mytablewidget.h \
160 shortcutgetter.h \
161 actionseditor.h \
162 filechooser.h \
163 vdpauproperties.h \
164 preferencesdialog.h \
165 lineedit_with_icon.h \
166 mylineedit.h \
167 mycombobox.h \
168 tristatecombo.h \
169 languages.h \
170 selectcolorbutton.h \
171 prefwidget.h \
172 prefgeneral.h \
173 prefdrives.h \
174 prefinterface.h \
175 prefperformance.h \
176 prefinput.h \
177 prefsubtitles.h \
178 prefadvanced.h \
179 prefplaylist.h \
180 preftv.h \
181 prefupdates.h \
182 prefnetwork.h \
183 filepropertiesdialog.h \
184 multilineinputdialog.h \
185 playlist.h \
186 playlistdock.h \
187 verticaltext.h \
188 eqslider.h \
189 videoequalizer.h \
190 audioequalizer.h \
191 myslider.h \
192 timeslider.h \
193 inputdvddirectory.h \
194 inputurl.h \
195 stereo3ddialog.h \
196 myaction.h \
197 myactiongroup.h \
198 filedialog.h \
199 inputmplayerversion.h \
200 about.h \
201 errordialog.h \
202 timedialog.h \
203 favorites.h \
204 tvlist.h \
205 favoriteeditor.h \
206 statewidget.h \
207 basegui.h \
208 baseguiplus.h \
209 autohidewidget.h \
210 widgetactions.h \
211 toolbareditor.h \
212 editabletoolbar.h \
213 clhelp.h \
214 cleanconfig.h \
215 smplayer.h \
216 myapplication.h
217
218
219SOURCES += version.cpp \
220 global.cpp \
221 paths.cpp \
222 chapters.cpp \
223 helper.cpp \
224 colorutils.cpp \
225 translator.cpp \
226 subtracks.cpp \
227 tracks.cpp \
228 titletracks.cpp \
229 discname.cpp \
230 extensions.cpp \
231 desktopinfo.cpp \
232 myprocess.cpp \
233 mplayerversion.cpp \
234 playerid.cpp \
235 playerprocess.cpp \
236 infoprovider.cpp \
237 mplayerwindow.cpp \
238 mediadata.cpp \
239 mediasettings.cpp \
240 assstyles.cpp \
241 filters.cpp \
242 preferences.cpp \
243 filesettingsbase.cpp \
244 filesettings.cpp \
245 filesettingshash.cpp \
246 filehash.cpp \
247 tvsettings.cpp \
248 images.cpp \
249 inforeader.cpp \
250 deviceinfo.cpp \
251 recents.cpp \
252 urlhistory.cpp \
253 core.cpp \
254 logwindow.cpp \
255 infofile.cpp \
256 seekwidget.cpp \
257 mytablewidget.cpp \
258 shortcutgetter.cpp \
259 actionseditor.cpp \
260 filechooser.cpp \
261 vdpauproperties.cpp \
262 preferencesdialog.cpp \
263 lineedit_with_icon.cpp \
264 mylineedit.cpp \
265 mycombobox.cpp \
266 tristatecombo.cpp \
267 languages.cpp \
268 selectcolorbutton.cpp \
269 prefwidget.cpp \
270 prefgeneral.cpp \
271 prefdrives.cpp \
272 prefinterface.cpp \
273 prefperformance.cpp \
274 prefinput.cpp \
275 prefsubtitles.cpp \
276 prefadvanced.cpp \
277 prefplaylist.cpp \
278 preftv.cpp \
279 prefupdates.cpp \
280 prefnetwork.cpp \
281 filepropertiesdialog.cpp \
282 multilineinputdialog.cpp \
283 playlist.cpp \
284 playlistdock.cpp \
285 verticaltext.cpp \
286 eqslider.cpp \
287 videoequalizer.cpp \
288 audioequalizer.cpp \
289 myslider.cpp \
290 timeslider.cpp \
291 inputdvddirectory.cpp \
292 inputurl.cpp \
293 stereo3ddialog.cpp \
294 myaction.cpp \
295 myactiongroup.cpp \
296 filedialog.cpp \
297 inputmplayerversion.cpp \
298 about.cpp \
299 errordialog.cpp \
300 timedialog.cpp \
301 favorites.cpp \
302 tvlist.cpp \
303 favoriteeditor.cpp \
304 statewidget.cpp \
305 basegui.cpp \
306 baseguiplus.cpp \
307 autohidewidget.cpp \
308 widgetactions.cpp \
309 toolbareditor.cpp \
310 editabletoolbar.cpp \
311 clhelp.cpp \
312 cleanconfig.cpp \
313 smplayer.cpp \
314 myapplication.cpp \
315 main.cpp
316
317FORMS = inputdvddirectory.ui logwindowbase.ui filepropertiesdialog.ui \
318 eqslider.ui seekwidget.ui inputurl.ui videoequalizer.ui vdpauproperties.ui \
319 preferencesdialog.ui prefgeneral.ui prefdrives.ui prefinterface.ui \
320 prefperformance.ui prefinput.ui prefsubtitles.ui prefadvanced.ui \
321 prefplaylist.ui preftv.ui prefupdates.ui prefnetwork.ui favoriteeditor.ui \
322 about.ui inputmplayerversion.ui errordialog.ui timedialog.ui stereo3ddialog.ui \
323 toolbareditor.ui multilineinputdialog.ui
324
325contains( DEFINES, MPV_SUPPORT ) {
326 HEADERS += mpvprocess.h inforeadermpv.h
327 SOURCES += mpvprocess.cpp inforeadermpv.cpp
328}
329
330contains( DEFINES, MPLAYER_SUPPORT ) {
331 HEADERS += mplayerprocess.h inforeadermplayer.h
332 SOURCES += mplayerprocess.cpp inforeadermplayer.cpp
333}
334
335# qtsingleapplication
336contains( DEFINES, SINGLE_INSTANCE ) {
337 INCLUDEPATH += qtsingleapplication
338 DEPENDPATH += qtsingleapplication
339
340 SOURCES += qtsingleapplication/qtsingleapplication.cpp qtsingleapplication/qtlocalpeer.cpp
341 HEADERS += qtsingleapplication/qtsingleapplication.h qtsingleapplication/qtlocalpeer.h
342}
343
344# Find subtitles dialog
345contains( DEFINES, FIND_SUBTITLES ) {
346 DEFINES += DOWNLOAD_SUBS
347 DEFINES += OS_SEARCH_WORKAROUND
348 #DEFINES += USE_QUAZIP
349
350 INCLUDEPATH += findsubtitles
351 DEPENDPATH += findsubtitles
352
353 INCLUDEPATH += findsubtitles/maia
354 DEPENDPATH += findsubtitles/maia
355
356 HEADERS += findsubtitles/findsubtitlesconfigdialog.h findsubtitles/findsubtitleswindow.h
357 SOURCES += findsubtitles/findsubtitlesconfigdialog.cpp findsubtitles/findsubtitleswindow.cpp
358 FORMS += findsubtitles/findsubtitleswindow.ui findsubtitles/findsubtitlesconfigdialog.ui
359
360 # xmlrpc client code to connect to opensubtitles.org
361 HEADERS += findsubtitles/maia/maiaObject.h findsubtitles/maia/maiaFault.h findsubtitles/maia/maiaXmlRpcClient.h findsubtitles/osclient.h
362 SOURCES += findsubtitles/maia/maiaObject.cpp findsubtitles/maia/maiaFault.cpp findsubtitles/maia/maiaXmlRpcClient.cpp findsubtitles/osclient.cpp
363}
364
365# Download subtitles
366contains( DEFINES, DOWNLOAD_SUBS ) {
367 INCLUDEPATH += findsubtitles/filedownloader
368 DEPENDPATH += findsubtitles/filedownloader
369
370 HEADERS += findsubtitles/filedownloader/filedownloader.h findsubtitles/subchooserdialog.h findsubtitles/fixsubs.h
371 SOURCES += findsubtitles/filedownloader/filedownloader.cpp findsubtitles/subchooserdialog.cpp findsubtitles/fixsubs.cpp
372
373 FORMS += findsubtitles/subchooserdialog.ui
374
375 contains( DEFINES, USE_QUAZIP ) {
376 INCLUDEPATH += findsubtitles/quazip
377 DEPENDPATH += findsubtitles/quazip
378
379 HEADERS += crypt.h \
380 ioapi.h \
381 quazip.h \
382 quazipfile.h \
383 quazipfileinfo.h \
384 quazipnewinfo.h \
385 unzip.h \
386 zip.h
387
388 SOURCES += ioapi.c \
389 quazip.cpp \
390 quazipfile.cpp \
391 quazipnewinfo.cpp \
392 unzip.c \
393 zip.c
394}
395
396 LIBS += -lz
397
398 win32 {
399 INCLUDEPATH += ..\\zlib
400 LIBS += -L..\\zlib
401 }
402}
403
404# Youtube support
405contains( DEFINES, YOUTUBE_SUPPORT ) {
406 DEFINES += YT_USE_SCRIPT
407 INCLUDEPATH += youtube
408 DEPENDPATH += youtube
409
410 HEADERS += youtube/retrieveyoutubeurl.h youtube/loadpage.h
411 SOURCES += youtube/retrieveyoutubeurl.cpp youtube/loadpage.cpp
412
413 contains( DEFINES, YT_USE_SCRIPT ) {
414 DEFINES += YT_USE_SIG
415 DEFINES += YT_USE_YTSIG
416 QT += script
417 }
418
419 contains( DEFINES, YT_USE_SIG ) {
420 HEADERS += youtube/sig.h
421 SOURCES += youtube/sig.cpp
422 }
423
424 contains( DEFINES, YT_USE_YTSIG ) {
425 HEADERS += youtube/ytsig.h youtube/codedownloader.h
426 SOURCES += youtube/ytsig.cpp youtube/codedownloader.cpp
427 }
428}
429
430# defaultgui
431contains( DEFINES, DEFAULTGUI ) {
432 HEADERS += defaultgui.h
433 SOURCES += defaultgui.cpp
434}
435
436# minigui
437contains( DEFINES, MINIGUI ) {
438 HEADERS += minigui.h
439 SOURCES += minigui.cpp
440}
441
442# mpcgui
443contains( DEFINES, MPCGUI ) {
444 INCLUDEPATH += mpcgui
445 DEPENDPATH += mpcgui
446
447 HEADERS += mpcgui/mpcgui.h mpcgui/mpcstyles.h
448 SOURCES += mpcgui/mpcgui.cpp mpcgui/mpcstyles.cpp
449}
450
451# Skins support
452contains( DEFINES, SKINS ) {
453 INCLUDEPATH += skingui
454 DEPENDPATH += skingui
455
456 HEADERS += skingui/myicon.h skingui/mybutton.h skingui/panelseeker.h skingui/playcontrol.h \
457 skingui/mediapanel.h skingui/volumecontrolpanel.h skingui/mediabarpanel.h \
458 skingui/qpropertysetter.h skingui/actiontools.h skingui/skingui.h
459 SOURCES += skingui/myicon.cpp skingui/mybutton.cpp skingui/panelseeker.cpp skingui/playcontrol.cpp \
460 skingui/mediapanel.cpp skingui/volumecontrolpanel.cpp skingui/mediabarpanel.cpp \
461 skingui/qpropertysetter.cpp skingui/actiontools.cpp skingui/skingui.cpp
462 FORMS += skingui/mediapanel.ui skingui/mediabarpanel.ui
463}
464
465contains( DEFINES, MPRIS2 ) {
466 INCLUDEPATH += mpris2
467 DEPENDPATH += mpris2
468
469 HEADERS += mpris2/mediaplayer2.h mpris2/mediaplayer2player.h mpris2/mpris2.h
470 SOURCES += mpris2/mediaplayer2.cpp mpris2/mediaplayer2player.cpp mpris2/mpris2.cpp
471
472 QT += dbus
473}
474
475# Update checker
476contains( DEFINES, UPDATE_CHECKER ) {
477 HEADERS += updatechecker.h updatecheckerdata.h
478 SOURCES += updatechecker.cpp updatecheckerdata.cpp
479}
480
481# Videopreview
482contains( DEFINES, VIDEOPREVIEW ) {
483 INCLUDEPATH += videopreview
484 DEPENDPATH += videopreview
485
486 HEADERS += videopreview/videopreview.h videopreview/videopreviewconfigdialog.h
487 SOURCES += videopreview/videopreview.cpp videopreview/videopreviewconfigdialog.cpp
488
489 FORMS += videopreview/videopreviewconfigdialog.ui
490}
491
492
493!contains(DEFINES, SHARE_ACTIONS) | !contains(DEFINES, SHARE_WIDGET) {
494 message("Note to distro maintainers:")
495 message("By disabling SHARE_ACTIONS or SHARE_WIDGET")
496 message("you're preventing SMPlayer to receive donations and thus")
497 message("SERIOUSLY HURTING THE DEVELOPMENT AND PUTTING")
498 message("AT RISK THE CONTINUATION OF THIS PROJECT")
499 message("Please don't.")
500}
501
502contains( DEFINES, SHARE_ACTIONS ) {
503 HEADERS += sharedialog.h
504 SOURCES += sharedialog.cpp
505 FORMS += sharedialog.ui
506}
507
508contains( DEFINES, SHARE_WIDGET|SHARE_ACTIONS ) {
509 HEADERS += sharewidget.h sharedata.h
510 SOURCES += sharewidget.cpp sharedata.cpp
511}
512
513contains( DEFINES, AUTO_SHUTDOWN_PC ) {
514 HEADERS += shutdowndialog.h shutdown.h
515 SOURCES += shutdowndialog.cpp shutdown.cpp
516 FORMS += shutdowndialog.ui
517
518 unix { QT += dbus }
519}
520
521contains( DEFINES, BOOKMARKS ) {
522 HEADERS += inputbookmark.h bookmarkdialog.h
523 SOURCES += inputbookmark.cpp bookmarkdialog.cpp
524 FORMS += inputbookmark.ui bookmarkdialog.ui
525}
526
527unix {
528 UI_DIR = .ui
529 MOC_DIR = .moc
530 OBJECTS_DIR = .obj
531
532 DEFINES += DATA_PATH=$(DATA_PATH)
533 DEFINES += DOC_PATH=$(DOC_PATH)
534 DEFINES += TRANSLATION_PATH=$(TRANSLATION_PATH)
535 DEFINES += THEMES_PATH=$(THEMES_PATH)
536 DEFINES += SHORTCUTS_PATH=$(SHORTCUTS_PATH)
537 #DEFINES += NO_DEBUG_ON_CONSOLE
538}
539
540win32 {
541 DEFINES += SCREENSAVER_OFF
542 DEFINES += AVOID_SCREENSAVER
543 #DEFINES += FONTCACHE_DIALOG
544 #DEFINES += FONTS_HACK
545
546 contains( DEFINES, SCREENSAVER_OFF ) {
547 HEADERS += screensaver.h
548 SOURCES += screensaver.cpp
549 }
550
551 contains( DEFINES, FONTCACHE_DIALOG ) {
552 HEADERS += fontcache.h
553 SOURCES += fontcache.cpp
554 }
555
556 !contains( DEFINES, PORTABLE_APP ) {
557 DEFINES += USE_ASSOCIATIONS
558 }
559
560 contains( DEFINES, USE_ASSOCIATIONS ) {
561 HEADERS += prefassociations.h winfileassoc.h
562 SOURCES += prefassociations.cpp winfileassoc.cpp
563 FORMS += prefassociations.ui
564 }
565
566 contains(TEMPLATE,vcapp) {
567 LIBS += ole32.lib user32.lib
568 } else {
569 LIBS += libole32
570 }
571
572 RC_FILE = smplayer.rc
573 DEFINES += NO_DEBUG_ON_CONSOLE
574 #debug {
575 # CONFIG += console
576 #}
577}
578
579os2 {
580 DEFINES += SCREENSAVER_OFF
581 DEFINES += AVOID_SCREENSAVER
582 INCLUDEPATH += .
583 contains( DEFINES, SCREENSAVER_OFF ) {
584 HEADERS += screensaver.h
585 SOURCES += screensaver.cpp
586 }
587 RC_FILE = smplayer_os2.rc
588
589 # define the vendor part
590 DEF_FILE_VENDOR = bww bitwise works GmbH
591 DEF_FILE_VERSION = $$APPLICATION_VERSION
592 DEF_FILE_DESCRIPTION = OS/2 and OS/2-based systems port of SMPlayer
593}
594
595
596TRANSLATIONS = translations/smplayer_es.ts translations/smplayer_de.ts \
597 translations/smplayer_sk.ts translations/smplayer_it.ts \
598 translations/smplayer_fr.ts translations/smplayer_zh_CN.ts \
599 translations/smplayer_ru_RU.ts translations/smplayer_hu.ts \
600 translations/smplayer_en_US.ts translations/smplayer_pl.ts \
601 translations/smplayer_ja.ts translations/smplayer_nl.ts \
602 translations/smplayer_uk_UA.ts translations/smplayer_pt_BR.ts \
603 translations/smplayer_ka.ts translations/smplayer_cs.ts \
604 translations/smplayer_bg.ts translations/smplayer_tr.ts \
605 translations/smplayer_sv.ts translations/smplayer_sr.ts \
606 translations/smplayer_zh_TW.ts translations/smplayer_ro_RO.ts \
607 translations/smplayer_pt.ts translations/smplayer_el_GR.ts \
608 translations/smplayer_fi.ts translations/smplayer_ko.ts \
609 translations/smplayer_mk.ts translations/smplayer_eu.ts \
610 translations/smplayer_ca.ts translations/smplayer_sl_SI.ts \
611 translations/smplayer_ar_SY.ts translations/smplayer_ku.ts \
612 translations/smplayer_gl.ts translations/smplayer_vi_VN.ts \
613 translations/smplayer_et.ts translations/smplayer_lt.ts \
614 translations/smplayer_da.ts translations/smplayer_hr.ts \
615 translations/smplayer_he_IL.ts translations/smplayer_th.ts \
616 translations/smplayer_ms_MY.ts translations/smplayer_uz.ts \
617 translations/smplayer_nn_NO.ts translations/smplayer_id.ts \
618 translations/smplayer_ar.ts translations/smplayer_en_GB.ts \
619 translations/smplayer_sq_AL.ts translations/smplayer_am.ts \
620 translations/smplayer_fa.ts
621
Note: See TracBrowser for help on using the repository browser.