source: smplayer/trunk/src/smplayer.pro

Last change on this file was 189, checked in by Silvan Scherrer, 8 years ago

SMPlayer: adjust version info in readme and some small glitches
  • Property svn:eol-style set to LF
File size: 16.1 KB
Line 
1TEMPLATE = app
2LANGUAGE = C++
3
4CONFIG += qt warn_on
5CONFIG += release
6#CONFIG += debug
7
8QT += network xml
9
10RESOURCES = icons.qrc
11
12#DEFINES += EXPERIMENTAL
13DEFINES += SINGLE_INSTANCE
14DEFINES += FIND_SUBTITLES
15DEFINES += VIDEOPREVIEW
16DEFINES += YOUTUBE_SUPPORT
17DEFINES += BLURAY_SUPPORT
18DEFINES += TV_SUPPORT
19DEFINES += GUI_CHANGE_ON_RUNTIME
20DEFINES += LOG_MPLAYER
21DEFINES += LOG_SMPLAYER
22DEFINES += DEFAULTGUI
23DEFINES += MINIGUI
24DEFINES += MPCGUI
25DEFINES += SKINS
26!os2 {
27DEFINES += MPRIS2
28}
29DEFINES += UPDATE_CHECKER
30DEFINES += CHECK_UPGRADED
31!os2 {
32DEFINES += AUTO_SHUTDOWN_PC
33}
34DEFINES += CAPTURE_STREAM
35DEFINES += BOOKMARKS
36DEFINES += MOUSE_GESTURES
37DEFINES += GLOBALSHORTCUTS
38DEFINES += ADD_BLACKBORDERS_FS
39DEFINES += INITIAL_BLACKBORDERS
40!os2 {
41DEFINES += CHROMECAST_SUPPORT
42DEFINES += MPV_SUPPORT
43}
44DEFINES += MPLAYER_SUPPORT
45
46# Whether to include support for the obsolete mplayer2 or not
47# (requires MPLAYER_SUPPORT)
48DEFINES += MPLAYER2_SUPPORT
49
50# Note to distro maintainers:
51# By disabling SHARE_ACTIONS or SHARE_WIDGET
52# you're preventing SMPlayer to receive donations and thus
53# SERIOUSLY HURTING THE DEVELOPMENT AND PUTTING
54# AT RISK THE CONTINUATION OF THIS PROJECT
55# Please don't.
56
57#DEFINES += SHARE_ACTIONS
58#DEFINES += SHARE_WIDGET
59
60# If Qt >= 5.4
61greaterThan(QT_MAJOR_VERSION, 4):greaterThan(QT_MINOR_VERSION, 3) {
62 DEFINES += HDPI_SUPPORT
63}
64
65#DEFINES += SIMPLE_BUILD
66#DEFINES += IDOPT_BUILD
67
68contains( DEFINES, SIMPLE_BUILD ) {
69 DEFINES -= SINGLE_INSTANCE
70 DEFINES -= FIND_SUBTITLES
71 DEFINES -= VIDEOPREVIEW
72 DEFINES -= LOG_MPLAYER
73 DEFINES -= LOG_SMPLAYER
74 DEFINES -= MINIGUI
75 DEFINES -= MPCGUI
76 DEFINES -= SKINS
77 DEFINES -= MPRIS2
78 DEFINES -= UPDATE_CHECKER
79 DEFINES -= CHECK_UPGRADED
80 DEFINES -= SHARE_ACTIONS
81 DEFINES -= SHARE_WIDGET
82 DEFINES -= AUTO_SHUTDOWN_PC
83 DEFINES -= BOOKMARKS
84 DEFINES -= TV_SUPPORT
85 DEFINES -= CHROMECAST_SUPPORT
86}
87
88contains( DEFINES, IDOPT_BUILD ) {
89 DEFINES -= MPCGUI
90 DEFINES -= SKINS
91 DEFINES -= CAPTURE_STREAM
92 DEFINES -= TV_SUPPORT
93 DEFINES -= MPLAYER_SUPPORT
94 DEFINES -= MPLAYER2_SUPPORT
95}
96
97isEqual(QT_MAJOR_VERSION, 5) {
98 QT += widgets gui
99 #DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x040000
100 win32 {
101 DEFINES -= MPRIS2
102 }
103}
104
105contains(QT_VERSION, ^4\\.[0-3]\\..*) {
106 message("Some features requires Qt > 4.3.")
107
108 contains( DEFINES, SINGLE_INSTANCE ) {
109 DEFINES -= SINGLE_INSTANCE
110 message("SINGLE_INSTANCE disabled.")
111 }
112
113 contains( DEFINES, YOUTUBE_SUPPORT ) {
114 DEFINES -= YOUTUBE_SUPPORT
115 message("YOUTUBE_SUPPORT disabled.")
116 }
117
118 contains( DEFINES, SKINS ) {
119 DEFINES -= SKINS
120 message("SKINS disabled.")
121 }
122
123 contains( DEFINES, FIND_SUBTITLES ) {
124 DEFINES -= FIND_SUBTITLES
125 message("FIND_SUBTITLES disabled.")
126 }
127
128 contains( DEFINES, UPDATE_CHECKER ) {
129 DEFINES -= UPDATE_CHECKER
130 message("UPDATE_CHECKER disabled.")
131 }
132}
133
134contains( DEFINES, GLOBALSHORTCUTS ) {
135 lessThan(QT_MAJOR_VERSION, 5) {
136 DEFINES -= GLOBALSHORTCUTS
137 message("GLOBALSHORTCUTS requires Qt 5. Disabled.")
138 }
139}
140
141HEADERS += guiconfig.h \
142 config.h \
143 constants.h \
144 links.h \
145 svn_revision.h \
146 version.h \
147 chapters.h \
148 global.h \
149 paths.h \
150 helper.h \
151 colorutils.h \
152 translator.h \
153 subtracks.h \
154 tracks.h \
155 titletracks.h \
156 discname.h \
157 extensions.h \
158 desktopinfo.h \
159 myprocess.h \
160 mplayerversion.h \
161 playerid.h \
162 playerprocess.h \
163 infoprovider.h \
164 mplayerwindow.h \
165 mediadata.h \
166 audioequalizerlist.h \
167 mediasettings.h \
168 assstyles.h \
169 filters.h \
170 preferences.h \
171 filesettingsbase.h \
172 filesettings.h \
173 filesettingshash.h \
174 filehash.h \
175 images.h \
176 inforeader.h \
177 deviceinfo.h \
178 recents.h \
179 urlhistory.h \
180 core.h \
181 myscroller.h \
182 logwindow.h \
183 infowindow.h \
184 infofile.h \
185 seekwidget.h \
186 mytablewidget.h \
187 shortcutgetter.h \
188 actionseditor.h \
189 filechooser.h \
190 vdpauproperties.h \
191 preferencesdialog.h \
192 lineedit_with_icon.h \
193 mylineedit.h \
194 mycombobox.h \
195 tristatecombo.h \
196 languages.h \
197 selectcolorbutton.h \
198 prefwidget.h \
199 prefgeneral.h \
200 prefdrives.h \
201 prefinterface.h \
202 prefperformance.h \
203 prefinput.h \
204 prefsubtitles.h \
205 prefadvanced.h \
206 prefplaylist.h \
207 prefupdates.h \
208 prefnetwork.h \
209 filepropertiesdialog.h \
210 multilineinputdialog.h \
211 playlist.h \
212 playlistdock.h \
213 verticaltext.h \
214 eqslider.h \
215 videoequalizer.h \
216 audioequalizer.h \
217 myslider.h \
218 timeslider.h \
219 inputdvddirectory.h \
220 inputurl.h \
221 stereo3ddialog.h \
222 myaction.h \
223 myactiongroup.h \
224 filedialog.h \
225 inputmplayerversion.h \
226 about.h \
227 errordialog.h \
228 timedialog.h \
229 favorites.h \
230 favoriteeditor.h \
231 statewidget.h \
232 basegui.h \
233 baseguiplus.h \
234 autohidewidget.h \
235 widgetactions.h \
236 toolbareditor.h \
237 editabletoolbar.h \
238 clhelp.h \
239 cleanconfig.h \
240 smplayer.h \
241 myapplication.h
242
243
244SOURCES += version.cpp \
245 global.cpp \
246 paths.cpp \
247 chapters.cpp \
248 helper.cpp \
249 colorutils.cpp \
250 translator.cpp \
251 subtracks.cpp \
252 tracks.cpp \
253 titletracks.cpp \
254 discname.cpp \
255 extensions.cpp \
256 desktopinfo.cpp \
257 myprocess.cpp \
258 mplayerversion.cpp \
259 playerid.cpp \
260 playerprocess.cpp \
261 infoprovider.cpp \
262 mplayerwindow.cpp \
263 mediadata.cpp \
264 mediasettings.cpp \
265 assstyles.cpp \
266 filters.cpp \
267 preferences.cpp \
268 filesettingsbase.cpp \
269 filesettings.cpp \
270 filesettingshash.cpp \
271 filehash.cpp \
272 images.cpp \
273 inforeader.cpp \
274 deviceinfo.cpp \
275 recents.cpp \
276 urlhistory.cpp \
277 core.cpp \
278 myscroller.cpp \
279 logwindow.cpp \
280 infowindow.cpp \
281 infofile.cpp \
282 seekwidget.cpp \
283 mytablewidget.cpp \
284 shortcutgetter.cpp \
285 actionseditor.cpp \
286 filechooser.cpp \
287 vdpauproperties.cpp \
288 preferencesdialog.cpp \
289 lineedit_with_icon.cpp \
290 mylineedit.cpp \
291 mycombobox.cpp \
292 tristatecombo.cpp \
293 languages.cpp \
294 selectcolorbutton.cpp \
295 prefwidget.cpp \
296 prefgeneral.cpp \
297 prefdrives.cpp \
298 prefinterface.cpp \
299 prefperformance.cpp \
300 prefinput.cpp \
301 prefsubtitles.cpp \
302 prefadvanced.cpp \
303 prefplaylist.cpp \
304 prefupdates.cpp \
305 prefnetwork.cpp \
306 filepropertiesdialog.cpp \
307 multilineinputdialog.cpp \
308 playlist.cpp \
309 playlistdock.cpp \
310 verticaltext.cpp \
311 eqslider.cpp \
312 videoequalizer.cpp \
313 audioequalizer.cpp \
314 myslider.cpp \
315 timeslider.cpp \
316 inputdvddirectory.cpp \
317 inputurl.cpp \
318 stereo3ddialog.cpp \
319 myaction.cpp \
320 myactiongroup.cpp \
321 filedialog.cpp \
322 inputmplayerversion.cpp \
323 about.cpp \
324 errordialog.cpp \
325 timedialog.cpp \
326 favorites.cpp \
327 favoriteeditor.cpp \
328 statewidget.cpp \
329 basegui.cpp \
330 baseguiplus.cpp \
331 autohidewidget.cpp \
332 widgetactions.cpp \
333 toolbareditor.cpp \
334 editabletoolbar.cpp \
335 clhelp.cpp \
336 cleanconfig.cpp \
337 smplayer.cpp \
338 myapplication.cpp \
339 main.cpp
340
341FORMS = inputdvddirectory.ui logwindow.ui infowindow.ui filepropertiesdialog.ui \
342 eqslider.ui seekwidget.ui inputurl.ui videoequalizer.ui vdpauproperties.ui \
343 preferencesdialog.ui prefgeneral.ui prefdrives.ui prefinterface.ui \
344 prefperformance.ui prefinput.ui prefsubtitles.ui prefadvanced.ui \
345 prefplaylist.ui prefupdates.ui prefnetwork.ui favoriteeditor.ui \
346 about.ui inputmplayerversion.ui errordialog.ui timedialog.ui stereo3ddialog.ui \
347 toolbareditor.ui multilineinputdialog.ui
348
349contains( DEFINES, TV_SUPPORT ) {
350 HEADERS += tvlist.h preftv.h tvsettings.h
351 SOURCES += tvlist.cpp preftv.cpp tvsettings.cpp
352 FORMS += preftv.ui
353}
354
355contains( DEFINES, MPV_SUPPORT ) {
356 HEADERS += mpvprocess.h inforeadermpv.h
357 SOURCES += mpvprocess.cpp inforeadermpv.cpp
358}
359
360contains( DEFINES, MPLAYER_SUPPORT ) {
361 HEADERS += mplayerprocess.h inforeadermplayer.h
362 SOURCES += mplayerprocess.cpp inforeadermplayer.cpp
363}
364
365# qtsingleapplication
366contains( DEFINES, SINGLE_INSTANCE ) {
367 INCLUDEPATH += qtsingleapplication
368 DEPENDPATH += qtsingleapplication
369
370 SOURCES += qtsingleapplication/qtsingleapplication.cpp qtsingleapplication/qtlocalpeer.cpp
371 HEADERS += qtsingleapplication/qtsingleapplication.h qtsingleapplication/qtlocalpeer.h
372}
373
374# Find subtitles dialog
375contains( DEFINES, FIND_SUBTITLES ) {
376 DEFINES += DOWNLOAD_SUBS
377 DEFINES += OS_SEARCH_WORKAROUND
378 #DEFINES += USE_QUAZIP
379
380 INCLUDEPATH += findsubtitles
381 DEPENDPATH += findsubtitles
382
383 INCLUDEPATH += findsubtitles/maia
384 DEPENDPATH += findsubtitles/maia
385
386 HEADERS += findsubtitles/findsubtitlesconfigdialog.h findsubtitles/findsubtitleswindow.h
387 SOURCES += findsubtitles/findsubtitlesconfigdialog.cpp findsubtitles/findsubtitleswindow.cpp
388 FORMS += findsubtitles/findsubtitleswindow.ui findsubtitles/findsubtitlesconfigdialog.ui
389
390 # xmlrpc client code to connect to opensubtitles.org
391 HEADERS += findsubtitles/maia/maiaObject.h findsubtitles/maia/maiaFault.h findsubtitles/maia/maiaXmlRpcClient.h findsubtitles/osclient.h
392 SOURCES += findsubtitles/maia/maiaObject.cpp findsubtitles/maia/maiaFault.cpp findsubtitles/maia/maiaXmlRpcClient.cpp findsubtitles/osclient.cpp
393}
394
395# Download subtitles
396contains( DEFINES, DOWNLOAD_SUBS ) {
397 INCLUDEPATH += findsubtitles/filedownloader
398 DEPENDPATH += findsubtitles/filedownloader
399
400 HEADERS += findsubtitles/filedownloader/filedownloader.h findsubtitles/subchooserdialog.h findsubtitles/fixsubs.h
401 SOURCES += findsubtitles/filedownloader/filedownloader.cpp findsubtitles/subchooserdialog.cpp findsubtitles/fixsubs.cpp
402
403 FORMS += findsubtitles/subchooserdialog.ui
404
405 contains( DEFINES, USE_QUAZIP ) {
406 INCLUDEPATH += findsubtitles/quazip
407 DEPENDPATH += findsubtitles/quazip
408
409 HEADERS += crypt.h \
410 ioapi.h \
411 quazip.h \
412 quazipfile.h \
413 quazipfileinfo.h \
414 quazipnewinfo.h \
415 unzip.h \
416 zip.h
417
418 SOURCES += ioapi.c \
419 quazip.cpp \
420 quazipfile.cpp \
421 quazipnewinfo.cpp \
422 unzip.c \
423 zip.c
424}
425
426 LIBS += -lz
427
428 win32 {
429 INCLUDEPATH += ..\\zlib
430 LIBS += -L..\\zlib
431 }
432}
433
434# Youtube support
435contains( DEFINES, YOUTUBE_SUPPORT ) {
436 DEFINES += YT_USE_SCRIPT
437 INCLUDEPATH += youtube
438 DEPENDPATH += youtube
439
440 HEADERS += youtube/retrieveyoutubeurl.h youtube/loadpage.h
441 SOURCES += youtube/retrieveyoutubeurl.cpp youtube/loadpage.cpp
442
443 contains( DEFINES, YT_USE_SCRIPT ) {
444 DEFINES += YT_USE_SIG
445 DEFINES += YT_USE_YTSIG
446 QT += script
447 }
448
449 contains( DEFINES, YT_USE_SIG ) {
450 HEADERS += youtube/sig.h
451 SOURCES += youtube/sig.cpp
452 }
453
454 contains( DEFINES, YT_USE_YTSIG ) {
455 HEADERS += youtube/ytsig.h youtube/codedownloader.h
456 SOURCES += youtube/ytsig.cpp youtube/codedownloader.cpp
457 }
458}
459
460# defaultgui
461contains( DEFINES, DEFAULTGUI ) {
462 HEADERS += defaultgui.h
463 SOURCES += defaultgui.cpp
464}
465
466# minigui
467contains( DEFINES, MINIGUI ) {
468 HEADERS += minigui.h
469 SOURCES += minigui.cpp
470}
471
472# mpcgui
473contains( DEFINES, MPCGUI ) {
474 INCLUDEPATH += mpcgui
475 DEPENDPATH += mpcgui
476
477 HEADERS += mpcgui/mpcgui.h mpcgui/mpcstyles.h
478 SOURCES += mpcgui/mpcgui.cpp mpcgui/mpcstyles.cpp
479}
480
481# Skins support
482contains( DEFINES, SKINS ) {
483 INCLUDEPATH += skingui
484 DEPENDPATH += skingui
485
486 HEADERS += skingui/myicon.h skingui/mybutton.h skingui/panelseeker.h skingui/playcontrol.h \
487 skingui/mediapanel.h skingui/volumecontrolpanel.h skingui/mediabarpanel.h \
488 skingui/qpropertysetter.h skingui/actiontools.h skingui/skingui.h
489 SOURCES += skingui/myicon.cpp skingui/mybutton.cpp skingui/panelseeker.cpp skingui/playcontrol.cpp \
490 skingui/mediapanel.cpp skingui/volumecontrolpanel.cpp skingui/mediabarpanel.cpp \
491 skingui/qpropertysetter.cpp skingui/actiontools.cpp skingui/skingui.cpp
492 FORMS += skingui/mediapanel.ui skingui/mediabarpanel.ui
493}
494
495contains( DEFINES, MPRIS2 ) {
496 INCLUDEPATH += mpris2
497 DEPENDPATH += mpris2
498
499 HEADERS += mpris2/mediaplayer2.h mpris2/mediaplayer2player.h mpris2/mpris2.h
500 SOURCES += mpris2/mediaplayer2.cpp mpris2/mediaplayer2player.cpp mpris2/mpris2.cpp
501
502 QT += dbus
503}
504
505# Update checker
506contains( DEFINES, UPDATE_CHECKER ) {
507 HEADERS += updatechecker.h updatecheckerdata.h
508 SOURCES += updatechecker.cpp updatecheckerdata.cpp
509}
510
511# Videopreview
512contains( DEFINES, VIDEOPREVIEW ) {
513 INCLUDEPATH += videopreview
514 DEPENDPATH += videopreview
515
516 HEADERS += videopreview/videopreview.h videopreview/videopreviewconfigdialog.h
517 SOURCES += videopreview/videopreview.cpp videopreview/videopreviewconfigdialog.cpp
518
519 FORMS += videopreview/videopreviewconfigdialog.ui
520}
521
522
523contains( DEFINES, SHARE_ACTIONS ) {
524 HEADERS += sharedialog.h
525 SOURCES += sharedialog.cpp
526 FORMS += sharedialog.ui
527}
528
529contains( DEFINES, SHARE_WIDGET|SHARE_ACTIONS ) {
530 HEADERS += sharewidget.h sharedata.h
531 SOURCES += sharewidget.cpp sharedata.cpp
532}
533
534contains( DEFINES, AUTO_SHUTDOWN_PC ) {
535 HEADERS += shutdowndialog.h shutdown.h
536 SOURCES += shutdowndialog.cpp shutdown.cpp
537 FORMS += shutdowndialog.ui
538
539 unix { QT += dbus }
540}
541
542contains( DEFINES, BOOKMARKS ) {
543 HEADERS += inputbookmark.h bookmarkdialog.h
544 SOURCES += inputbookmark.cpp bookmarkdialog.cpp
545 FORMS += inputbookmark.ui bookmarkdialog.ui
546}
547
548contains( DEFINES, GLOBALSHORTCUTS ) {
549 HEADERS += globalshortcuts/globalshortcuts.h
550 SOURCES += globalshortcuts/globalshortcuts.cpp
551 unix {
552 QT += gui-private
553 LIBS += $${QMAKE_LIBS_X11}
554 }
555}
556
557contains( DEFINES, HDPI_SUPPORT ) {
558 HEADERS += hdpisupport.h
559 SOURCES += hdpisupport.cpp
560}
561
562contains( DEFINES, CHROMECAST_SUPPORT ) {
563 HEADERS += chromecast.h
564 SOURCES += chromecast.cpp
565}
566
567unix {
568 UI_DIR = .ui
569 MOC_DIR = .moc
570 OBJECTS_DIR = .obj
571
572 DEFINES += DATA_PATH=$(DATA_PATH)
573 DEFINES += DOC_PATH=$(DOC_PATH)
574 DEFINES += TRANSLATION_PATH=$(TRANSLATION_PATH)
575 DEFINES += THEMES_PATH=$(THEMES_PATH)
576 DEFINES += SHORTCUTS_PATH=$(SHORTCUTS_PATH)
577 #DEFINES += NO_DEBUG_ON_CONSOLE
578
579 ### PulseAudio
580 #CONFIG += link_pkgconfig
581 #PKGCONFIG += libpulse-mainloop-glib
582}
583
584win32 {
585 DEFINES += SCREENSAVER_OFF
586 DEFINES += AVOID_SCREENSAVER
587 #DEFINES += FONTCACHE_DIALOG
588 #DEFINES += FONTS_HACK
589
590 contains( DEFINES, SCREENSAVER_OFF ) {
591 HEADERS += screensaver.h
592 SOURCES += screensaver.cpp
593 }
594
595 contains( DEFINES, FONTCACHE_DIALOG ) {
596 HEADERS += fontcache.h
597 SOURCES += fontcache.cpp
598 }
599
600 !contains( DEFINES, PORTABLE_APP ) {
601 DEFINES += USE_ASSOCIATIONS
602 } else {
603 DEFINES -= HDPI_SUPPORT
604 }
605
606 contains( DEFINES, USE_ASSOCIATIONS ) {
607 HEADERS += prefassociations.h winfileassoc.h
608 SOURCES += prefassociations.cpp winfileassoc.cpp
609 FORMS += prefassociations.ui
610 }
611
612 contains(TEMPLATE,vcapp) {
613 LIBS += ole32.lib user32.lib
614 } else {
615 LIBS += libole32
616 }
617
618 LIBS += -ldsound -lddraw
619
620 RC_FILE = smplayer.rc
621 DEFINES += NO_DEBUG_ON_CONSOLE
622 #debug {
623 # CONFIG += console
624 #}
625}
626
627os2 {
628 DEFINES += SCREENSAVER_OFF
629 DEFINES += AVOID_SCREENSAVER
630 INCLUDEPATH += .
631 contains( DEFINES, SCREENSAVER_OFF ) {
632 HEADERS += screensaver.h
633 SOURCES += screensaver.cpp
634 }
635 RC_FILE = smplayer_os2.rc
636
637 # define the vendor part
638 DEF_FILE_VENDOR = bww bitwise works GmbH
639 DEF_FILE_VERSION = $$APPLICATION_VERSION
640 DEF_FILE_DESCRIPTION = OS/2 and OS/2-based systems port of SMPlayer
641}
642
643
644TRANSLATIONS = translations/smplayer_es.ts translations/smplayer_de.ts \
645 translations/smplayer_sk.ts translations/smplayer_it.ts \
646 translations/smplayer_fr.ts translations/smplayer_zh_CN.ts \
647 translations/smplayer_ru_RU.ts translations/smplayer_hu.ts \
648 translations/smplayer_en.ts translations/smplayer_pl.ts \
649 translations/smplayer_ja.ts translations/smplayer_nl.ts \
650 translations/smplayer_uk_UA.ts translations/smplayer_pt_BR.ts \
651 translations/smplayer_ka.ts translations/smplayer_cs.ts \
652 translations/smplayer_bg.ts translations/smplayer_tr.ts \
653 translations/smplayer_sv.ts translations/smplayer_sr.ts \
654 translations/smplayer_zh_TW.ts translations/smplayer_ro_RO.ts \
655 translations/smplayer_pt.ts translations/smplayer_el.ts \
656 translations/smplayer_fi.ts translations/smplayer_ko.ts \
657 translations/smplayer_mk.ts translations/smplayer_eu.ts \
658 translations/smplayer_ca.ts translations/smplayer_sl_SI.ts \
659 translations/smplayer_ar_SY.ts translations/smplayer_ku.ts \
660 translations/smplayer_gl.ts translations/smplayer_vi_VN.ts \
661 translations/smplayer_et.ts translations/smplayer_lt.ts \
662 translations/smplayer_da.ts translations/smplayer_hr.ts \
663 translations/smplayer_he_IL.ts translations/smplayer_th.ts \
664 translations/smplayer_ms_MY.ts translations/smplayer_uz.ts \
665 translations/smplayer_nn_NO.ts translations/smplayer_id.ts \
666 translations/smplayer_ar.ts translations/smplayer_en_GB.ts \
667 translations/smplayer_sq_AL.ts translations/smplayer_am.ts \
668 translations/smplayer_fa.ts translations/smplayer_en_US.ts
669
Note: See TracBrowser for help on using the repository browser.