source: trunk/bootcode/regular/driveio.asm@ 169

Last change on this file since 169 was 169, checked in by Ben Rietbroek, 8 years ago

Added a double check when writing LVM sectors [v1.1.1-testing]

Writing an LVM sector is always the result of modifications to a
previously loaded one. So we first do a load and validate to make sure
the addressed sector contains LVM information.

CAUTION:
This is a testbuild !
AirBoot uses the BIOS to access disks and a small coding error can trash
partition tables or other vital disk structures. You are advised to make
backups of TRACK0 and EBRs before using this testbuild. More info at:
​https://rousseaux.github.io/netlabs.air-boot/pdf/AirBoot-v1.1.0-manual.pdf
File size: 74.3 KB
Line 
1; AiR-BOOT (c) Copyright 1998-2008 M. Kiewitz
2;
3; This file is part of AiR-BOOT
4;
5; AiR-BOOT is free software: you can redistribute it and/or modify it under
6; the terms of the GNU General Public License as published by the Free
7; Software Foundation, either version 3 of the License, or (at your option)
8; any later version.
9;
10; AiR-BOOT is distributed in the hope that it will be useful, but WITHOUT ANY
11; WARRANTY: without even the implied warranty of MERCHANTABILITY or FITNESS
12; FOR A PARTICULAR PURPOSE. See the GNU General Public License for more
13; details.
14;
15; You should have received a copy of the GNU General Public License along with
16; AiR-BOOT. If not, see <http://www.gnu.org/licenses/>.
17;
18;---------------------------------------------------------------------------
19; AiR-BOOT / DRIVE I/O
20;---------------------------------------------------------------------------
21
22
23
24IFDEF MODULE_NAMES
25DB 'DRIVEIO',0
26ENDIF
27
28;
29; Check if INT13X extensions are supported.
30; AirBoot requires these extensions, and will halt if they are not available.
31; Modified: [CurIO_UseExtension]
32DriveIO_CheckFor13extensions Proc Near Uses ax bx cx dx
33 mov ah, 41h
34 mov bx, 55AAh
35 mov dl, [BIOS_BootDisk] ; We check using the boot-disk
36 int 13h
37
38IFDEF AUX_DEBUG
39 IF 0
40 DBG_TEXT_OUT_AUX 'DriveIO_CheckFor13extensions:'
41 PUSHRF
42 call DEBUG_DumpRegisters
43 ;~ call AuxIO_DumpParagraph
44 ;~ call AuxIO_TeletypeNL
45 mov si, offset [Scratch]
46 mov word ptr [si], 50h
47 mov ah, 48h
48 int 13h
49 call DEBUG_DumpRegisters
50 ;~ call AuxIO_DumpSector
51 POPRF
52 ENDIF
53ENDIF
54
55 jc PCCF13E_NotFound ; Error occured
56 cmp bx, 0AA55h
57 je PCCF13E_Found
58 PCCF13E_NotFound:
59 ret
60 PCCF13E_Found:
61 and cx, 1 ; Check 42h-44h,47h,48h supported
62 jz PCCF13E_NotFound ; Sig OK but no support, strange beast
63 mov byte ptr [CurIO_UseExtension], 1
64 ret
65DriveIO_CheckFor13extensions EndP
66
67
68; Note: Some routines set DS/ES to CS or even address via CS, even if its not
69; needed. This was done for SECURITY. So DO NOT remove it.
70; Its there to make sure the correct data is loaded/written to/from
71; harddrive.
72;
73; IF YOU MODIFY ANYTHING IN HERE, YOU MAY EASILY BREAK YOUR HARDDRIVE!
74
75; Will only load base-configuration, will NOT load IPT nor Hide-Config
76; Those are originally loaded on startup and will NOT get reloaded.
77DriveIO_LoadConfiguration Proc Near Uses ax bx cx dx es
78
79IFDEF AUX_DEBUG
80 IF 0
81 DBG_TEXT_OUT_AUX 'DriveIO_LoadConfiguration:'
82 PUSHRF
83 ;~ call DEBUG_DumpRegisters
84 ;~ call AuxIO_DumpParagraph
85 ;~ call AuxIO_TeletypeNL
86 POPRF
87 ENDIF
88ENDIF
89
90;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
91 mov ax, cs
92 mov es, ax
93 mov bx, offset Configuration
94 xor dh, dh
95 mov dl, [BIOS_BootDisk] ; Disk we booted from
96 mov cx, 0037h ; Sector 55 (CHS)
97 mov ax, 0201h ; Function 02, read 1 sector...
98 int 13h
99 jnc DIOLC_NoError
100 call MBR_LoadError ; Will Abort BootUp
101
102
103 DIOLC_NoError:
104 ret
105DriveIO_LoadConfiguration EndP
106
107DriveIO_SaveConfiguration Proc Near Uses ax bx cx dx ds es si
108
109IFDEF AUX_DEBUG
110 IF 0
111 DBG_TEXT_OUT_AUX 'DriveIO_SaveConfiguration:'
112 PUSHRF
113 call DEBUG_DumpRegisters
114 ;~ call AuxIO_DumpParagraph
115 ;~ call AuxIO_TeletypeNL
116 POPRF
117 ENDIF
118ENDIF
119
120 mov ax, cs
121 mov ds, ax
122 mov es, ax ; Safety first (CS==DS==ES)
123 ; --- Overwrite Floppy-Name with "FloppyDrive"
124 mov si, offset TXT_Floppy_Drive
125 mov di, offset PartitionTable
126 sub di, 30 ; Adjust to Floppy-Name
127 mov cx, 11
128 rep movsb
129 mov si, offset Configuration ; Calculate new checksum
130 xor bx, bx
131
132 ; Changed from 5 to calculated value (not here, see compat. issue below)
133 ; Fixes issue: #2987 -- "air-boot doesn't remember drive letter"
134 ; Size of the ab-configuration in 512 byte sectors
135 ;mov cx, (MBR_BackUpMBR - Configuration) / 200h
136
137 ; AB v1.07 stores a 5 sector configuration with a 5 sector checksum.
138 ; AB v1.0.8+ *should* stores a 7 sector configuration with a
139 ; 7 sector checksum.
140 ; Because 5 was hardcoded here, SET(A)BOOT v1.07 will see see an AB v1.0.8+
141 ; config as corrupted, while this is not the case.
142 ; So, for compatibility reasons, in v1.0.8+, the checksum stored is over
143 ; 5 sectors, to be compatible with v1.07.
144 ; This may change (be corrected) in future versions !
145 mov cx,5
146
147 mov dx, [CFG_CheckConfig]
148 mov [CFG_CheckConfig], bx
149 DIOSC_Loop:
150 call MBR_GetCheckOfSector
151 loop DIOSC_Loop
152 mov [CFG_CheckConfig], bx
153 ; --------------------------------------------------------------------
154 ; ES == CS
155 mov bx, offset Configuration
156 xor dh, dh
157 mov dl, [BIOS_BootDisk] ; Disk we booted from
158 mov cx, 0037h ; Sector 55 (CHS)
159
160 ; Changed from 5 to calculated value
161 ; Fixes issue: #2987 -- "air-boot doesn't remember drive letter"
162 ; Size of the ab-configuration in 512 byte sectors
163 mov al, (MBR_BackUpMBR - Configuration) / 200h
164 mov ah,03h
165;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
166 int 13h
167 jnc DIOSC_NoError
168 call MBR_SaveError ; Will Abort BootUp
169 DIOSC_NoError:
170 ret
171DriveIO_SaveConfiguration EndP
172
173DriveIO_UpdateFloppyName Proc Near Uses bx cx dx ds si es di
174 mov ax, cs
175 mov ds, ax
176 mov es, ax
177
178 mov ah, 00h ; Function 0 - Reset Drive
179 xor dl, dl
180 int 13h
181 xor dx, dx ; Cylinder=0, Head=0
182 mov cx, 1 ; Sector=1, Drive=0
183 mov bx, offset TmpSector ; ES:BX - TmpSector
184 mov ax, 0201h ; Function 2 - Load Sector
185 int 13h
186 jnc DIOUFN_AllFine
187
188 ; --- Overwrite Floppy-Name with "No Disc"
189 mov si, offset TXT_Floppy_NoDisc
190 xor ax, ax
191 DIOUFN_WriteFloppyName:
192 mov di, offset PartitionTable
193 sub di, 30 ; Adjust to Floppy-Name
194 mov cl, 11
195 rep movsb
196 ret ; AX=-1 -> GotDisc, =0 -> NoDisc
197
198 ; --- Floppy found and read, data in TempSector
199 DIOUFN_AllFine:
200 mov ax, -1
201 mov si, offset TXT_Floppy_NoName
202 cmp wptr es:[bx+54], 'AF'
203 jne DIOUFN_WriteFloppyName
204 cmp wptr es:[bx+56], '1T'
205 jne DIOUFN_WriteFloppyName
206 cmp bptr es:[bx+58], '2'
207 jne DIOUFN_WriteFloppyName
208 mov si, bx
209 add si, 43 ; FAT12 - Volume Label Location
210 jmp DIOUFN_WriteFloppyName
211DriveIO_UpdateFloppyName EndP
212
213; =============================================================================
214; HARDDRIVE / GENERAL ACCESS
215; =============================================================================
216; The following routines are used for harddisc/floppy access.
217; The access is done via INT 13h/CHS or INT 13h/LBA.
218; Access will be done prefered by INT 13h/CHS, because it's (I wonder!) much
219; faster, than the LBA-method. I don't know, why LBA is so slow. Perhaps BIOS.
220;
221; Internal access (to AiR-BOOT) is always done via INT 13h/CHS.
222
223DriveIO_GetHardDriveCount Proc Near Uses ds si
224 push ds
225 push si
226 push 0040h
227 pop ds
228 mov si, 0075h
229 mov dh, ds:[si] ; 40:75 -> POST: Total Harddiscs == DH
230 pop si
231 pop ds
232 mov [TotalHarddiscs], dh
233 ret
234DriveIO_GetHardDriveCount EndP
235
236
237; Fills our LBA-Usage table. It holds the LBA-address, where BIOS/CHS access is
238; stopped and BIOS/LBA access is started.
239; This is calculated by Sector*Heads. Comparing will get done with Bit 25-10
240; on LBA sectors, so we actually divide sector number by 1024.
241DriveIO_InitLBASwitchTable Proc Near Uses es di
242 mov di, offset LBASwitchTable
243 mov dh, [TotalHarddiscs]
244 mov dl, 80h ; First disk to process
245 DIOILUT_DriveLoop:
246 push dx
247 push di
248 mov ah, 08h
249 int 13h ; DISK - GET DRIVE PARAMETERS
250 mov ah, 0FBh ; Assume 255 heads/63 sectors, if error
251 jc DIOILUT_Error
252 and cl, 111111b ; Isolate lower 6 bits of CL -> sector count
253;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
254 ;movzx ax, cl
255 mov al,cl
256 mov ah,0
257
258 mov bl, dh ; DH -> max head number
259 mul bl ; AX = Sectors*Heads
260 shl ah, 1
261 shl ah, 1 ; Shift 2 bits, so we are able to compare to
262 ; bit 16-23 of the LBA address
263 DIOILUT_Error:
264 pop di
265 pop dx
266 mov bptr ds:[di], ah ; Save that value
267 inc di ; Go to next BYTE
268 inc dl ; Next disk
269 dec dh ; Decrease disks to process
270 jnz DIOILUT_DriveLoop ; Next disk if DH != 0
271 ret
272DriveIO_InitLBASwitchTable EndP
273
274; #########################################################################
275; Routine: Loads partition to ExecBase and checks for validity
276; #########################################################################
277; Calling : bx:ax - Absolute sector
278; cx:dx - Cylinder/Sector, Side/Drive (hi/lo-byte)
279; Returns : Carry Set if invalid partition encountered
280; Preserve: all registers
281; #########################################################################
282DriveIO_LoadPartition Proc Near Uses si
283
284IFDEF AUX_DEBUG
285 IF 0
286 DBG_TEXT_OUT_AUX 'DriveIO_LoadPartition:'
287 PUSHRF
288 call DEBUG_DumpRegisters
289 ;~ call AuxIO_DumpParagraph
290 ;~ call AuxIO_TeletypeNL
291 POPRF
292 ENDIF
293ENDIF
294
295 mov wptr cs:[CurPartition_Location+0], ax
296 mov wptr cs:[CurPartition_Location+2], bx
297 mov wptr cs:[CurPartition_Location+4], dx
298 mov wptr cs:[CurPartition_Location+6], cx ; Saves the location
299 mov si, offset [PartitionSector] ; DS:SI - ExecBase
300
301
302;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
303 call DriveIO_LoadSector
304
305 clc
306 cmp wptr [si+LocBR_Magic], 0AA55h
307 je DIOLP_Success
308 ; We check, if we are scanning partitions. In that case, if CHS is not 0/0/1
309 ; we will display a "bad partition table" message and halt the system.
310 cmp cx, 0001h
311 jne DIOLP_Failed
312 or dh, dh
313 jnz DIOLP_Failed
314 stc ; Set carry, so no partition table
315 DIOLP_Success:
316
317
318
319 ret
320 DIOLP_Failed:
321 jmp DriveIO_GotLoadError
322DriveIO_LoadPartition EndP
323
324; #########################################################################
325; Routine: Writes a partition from ExecBase to its original sector
326; #########################################################################
327; Calling : none
328; Returns : none
329; Preserve: all registers
330; #########################################################################
331DriveIO_SavePartition Proc Near Uses ax bx cx dx si
332
333IFDEF AUX_DEBUG
334 IF 0
335 DBG_TEXT_OUT_AUX 'DriveIO_SavePartition:'
336 PUSHRF
337 call DEBUG_DumpRegisters
338 ;~ call AuxIO_DumpParagraph
339 ;~ call AuxIO_TeletypeNL
340 POPRF
341 ENDIF
342ENDIF
343
344 mov ax, wptr cs:[CurPartition_Location+0]
345 mov bx, wptr cs:[CurPartition_Location+2]
346 mov dx, wptr cs:[CurPartition_Location+4]
347 mov cx, wptr cs:[CurPartition_Location+6] ; Gets prev. saved location
348 mov si, offset PartitionSector ; DS:SI - ExecBase
349 cmp wptr [si+LocBR_Magic], 0AA55h ; Checks for signature, if not found
350 jne DIOSP_SevereError ; we assume a really bad error
351 call DriveIO_SaveSector
352 DIOSP_SevereError:
353 ret
354DriveIO_SavePartition EndP
355
356
357
358;##############################################################################
359;# The location of LVM sectors depends on the OS/2 geometry used when the disk
360;# was prepared. This geometry is present in the Master LVM sector, which has
361;# already been located if it exists. All partitions, whether primary or
362;# logical, have an entry in a partition table. For primary partitions this
363;# table is located in the MBR, while for logical partitions this table is
364;# located in the EBR for that logical partition. An LVM record is located
365;# LVM_SPT-1 sectors above an MBR or EBR. The Master LVM record contains the
366;# information for all primary partitions. For logical partitions, the LVM
367;# sector only has one entry, because EBRs are chained. The global LVM info,
368;# like disk-name, sectors per track, etc. is replicated between the Master
369;# LVM sector and LVM sectors corresponding to logical partitions. This info
370;# is kept in sync by the OS/2 LVM Engine.
371;##############################################################################
372;# ACTION : Attempts to load the corresponding LVM sector for a partition
373;# ----------------------------------------------------------------------------
374;# EFFECTS : Modifies DAP structure and fills or clears sector buffer
375;# ----------------------------------------------------------------------------
376;# IN : MEM - Location info is in [CurPartition_Location]
377;# ----------------------------------------------------------------------------
378;# OUT : CF=1 - failure, no valid LVM sector was loaded
379;# : SI - Points to the sector buffer ([LVMSector])
380;##############################################################################
381DriveIO_LoadLVMSector Proc Near Uses ax bx cx dx di
382
383IFDEF AUX_DEBUG
384 IF 0
385 DBG_TEXT_OUT_AUX 'DriveIO_LoadLVMSector:'
386 PUSHRF
387 call DEBUG_DumpRegisters
388 ;~ call AuxIO_DumpSector
389 ;~ call AuxIO_DumpParagraph
390 ;~ call AuxIO_TeletypeNL
391 POPRF
392 ENDIF
393ENDIF
394
395 ; Clear the sector buffer
396 mov si, offset [LVMSector]
397 call ClearSectorBuffer
398
399 ; Quit with CY if LVM is ignored in SETUP
400 test byte ptr [CFG_IgnoreLVM], 1 ; ZF=0 means ignore LVM
401 jnz DIOLLVMS_NoLVMSector ; Quit if so
402
403 ; Load the location of the current partition being acted upon.
404 ; Note that this is not the actual LBA of the partition, but the
405 ; sector that has the partition table that contains the entry
406 ; for the partition. In other words, for primary partitions the LBA
407 ; address points to the MBR while for extended partitions it points
408 ; to an EBR. In both cases the LVM sector is located LVM_SPT-1 above.
409 ; Also note that the BIOS CHS values (DH and CX) below are not used,
410 ; because we explicitly use LBA sector loading.
411 mov ax, wptr cs:[CurPartition_Location+0] ; LBA lo of MBR/EBR
412 mov bx, wptr cs:[CurPartition_Location+2] ; LBA hi of MBR/EBR
413 mov dx, wptr cs:[CurPartition_Location+4] ; BIOS disk num & head
414 mov cx, wptr cs:[CurPartition_Location+6] ; BIOS cyl & sec
415
416 ; Do the actual loading.
417 ; This is in a separate function so that LVM records can also be
418 ; loaded using the MBR/EBR LBA addresses from IPT entries.
419 call DriveIO_LoadLVMSectorXBR
420 jc DIOLLVMS_NoLVMSector
421
422 ; We're done, indicate success and return
423 clc
424 jmp DIOLLVMS_Done
425
426 DIOLLVMS_NoLVMSector:
427
428 ; Clear the sector buffer
429 mov si, offset [LVMSector]
430 call ClearSectorBuffer
431 mov bptr [si+LocLVM_SignatureStart], 0
432
433 ; Indicate no valid LVM sector was loaded
434 stc
435
436 DIOLLVMS_Done:
437
438 ret
439DriveIO_LoadLVMSector EndP
440
441
442
443
444
445;------------------------------------------------------------------------------
446; Attempts to load the corresponding LVM sector for a partition
447;------------------------------------------------------------------------------
448; IN : AX - LBA lo of MBR or EBR
449; : BX - LBA hi of MBR or EBR
450; ; DL - BIOS disk number
451; ; SI - Pointer to sector buffer (usually [LVMSec])
452; OUT : CF=0 - A valid LVM sector was loaded
453; NOTE : LocIPT_AbsolutePartTable and LocIPT_Drive can provide LBA and DISK
454;------------------------------------------------------------------------------
455DriveIO_LoadLVMSectorXBR Proc Near
456
457IFDEF AUX_DEBUG
458 IF 0
459 DBG_TEXT_OUT_AUX 'DriveIO_LoadLVMSectorXBR:'
460 PUSHRF
461 call DEBUG_DumpRegisters
462 ;~ call AuxIO_DumpSector
463 ;~ call AuxIO_DumpParagraph
464 ;~ call AuxIO_TeletypeNL
465 POPRF
466 ENDIF
467ENDIF
468
469 ; Save all registers
470 pusha
471
472 ; Calculate the entry in the DISKINFO array for this disk,
473 ; and put the LVM_SPT in DI
474 push bx
475 call DriveIO_CalcDiskInfoPointer
476 mov di, [bx+LocDISKINFO_LVM_Secs]
477 pop bx
478
479 ; If the LVM_SPT is ZERO, no LVM info is present and we quit with CY
480 test di, di ; See if it is 0
481 jz DriveIO_LoadLVMSectorXBR_no_lvm ; Quit if so
482
483 ; Adjust the location to point to the LVM sector
484 add ax, di ; Add the LVM sectors-per-track
485 adc bx, 0 ; Propagate LBA lo overflow to LBA hi
486 sub ax, 1 ; LVM sector is located one sector below
487 sbb bx, 0 ; Propagate borrow to LBA hi
488
489 ; Load the LVM sector into sector buffer pointed to by SI
490 mov di, ds ; Segment of that buffer
491 call DriveIO_ReadSectorLBA ; Read the LVM sector
492
493IFDEF AUX_DEBUG
494 IF 0
495 DBG_TEXT_OUT_AUX 'LVMSecLoaded'
496 PUSHRF
497 call DEBUG_DumpRegisters
498 ;~ call AuxIO_DumpSector
499 mov cx, 3
500 @@:
501 call AuxIO_DumpParagraph
502 call AuxIO_TeletypeNL
503 add si, 16
504 loop @B
505 ;~ call AuxIO_DumpParagraph
506 ;~ call AuxIO_TeletypeNL
507 POPRF
508 ENDIF
509ENDIF
510
511 jc DriveIO_LoadLVMSectorXBR_no_lvm ; Quit on error
512
513 ; Check the validity of the LVM sector, quit with CY if invalid
514 call LVM_ValidateSector ; Check signature and CRC
515 jnc DriveIO_LoadLVMSectorXBR_no_lvm ; Quit if not valid
516
517 ; We're done, indicate success and return
518 clc
519 jmp DriveIO_LoadLVMSectorXBR_done
520
521 DriveIO_LoadLVMSectorXBR_no_lvm:
522 ; Indicate no valid LVM sector was loaded
523 stc
524
525 DriveIO_LoadLVMSectorXBR_done:
526 ; Restore all registers
527 popa
528
529 ret
530DriveIO_LoadLVMSectorXBR EndP
531
532
533;##############################################################################
534;# The location of LVM sectors depends on the OS/2 geometry used when the disk
535;# was prepared. This geometry is present in the Master LVM sector, which has
536;# already been located if it exists. All partitions, whether primary or
537;# logical, have an entry in a partition table. For primary partitions this
538;# table is located in the MBR, while for logical partitions this table is
539;# located in the EBR for that logical partition. An LVM record is located
540;# LVM_SPT-1 sectors above an MBR or EBR. The Master LVM record contains the
541;# information for all primary partitions. For logical partitions, the LVM
542;# sector only has one entry, because EBRs are chained. The global LVM info,
543;# like disk-name, sectors per track, etc. is replicated between the Master
544;# LVM sector and LVM sectors corresponding to logical partitions. This info
545;# is kept in sync by the OS/2 LVM Engine.
546;##############################################################################
547;# ACTION : Attempts to save the corresponding LVM sector for a partition
548;# ----------------------------------------------------------------------------
549;# EFFECTS : Modifies DAP structure and writes LVM sector to disk
550;# ----------------------------------------------------------------------------
551;# IN : MEM - Location info is in [CurPartition_Location]
552;# : SI - Pointer to sector buffer
553;# ----------------------------------------------------------------------------
554;# OUT : CF=1 - failure, no valid LVM sector was saved
555;##############################################################################
556DriveIO_SaveLVMSector Proc Near Uses ax bx cx dx di
557
558IFDEF AUX_DEBUG
559 IF 0
560 DBG_TEXT_OUT_AUX 'DriveIO_SaveLVMSector:'
561 PUSHRF
562 call DEBUG_DumpRegisters
563 ;~ call AuxIO_DumpParagraph
564 ;~ call AuxIO_TeletypeNL
565 POPRF
566 ENDIF
567ENDIF
568
569 ; Quit with CY if LVM is ignored in SETUP
570 test byte ptr [CFG_IgnoreLVM], 1 ; ZF=0 means ignore LVM
571 jnz DIOSLVMS_NoLVMSector ; Quit if so
572
573 ; Load the location of the current partition being acted upon.
574 ; Note that this is not the actual LBA of the partition, but the
575 ; sector that has the partition table that contains the entry
576 ; for the partition. In other words, for primary partitions the LBA
577 ; address points to the MBR while for extended partitions it points
578 ; to an EBR. In both cases the LVM sector is located LVM_SPT-1 above.
579 ; Also note that the BIOS CHS values (DH and CX) below are not used,
580 ; because we explicitly use LBA sector loading.
581 mov ax, wptr cs:[CurPartition_Location+0] ; LBA lo of MBR/EBR
582 mov bx, wptr cs:[CurPartition_Location+2] ; LBA hi of MBR/EBR
583 mov dx, wptr cs:[CurPartition_Location+4] ; BIOS disk num & head
584 mov cx, wptr cs:[CurPartition_Location+6] ; BIOS cyl & sec
585
586 ; Do the actual saving.
587 ; This is in a separate function so that LVM records can also be
588 ; saved using the MBR/EBR LBA addresses from IPT entries.
589 call DriveIO_SaveLVMSectorXBR
590 jc DIOSLVMS_NoLVMSector
591
592 ; We're done, indicate success and return
593 clc
594 jmp DIOSLVMS_Done
595
596 DIOSLVMS_NoLVMSector:
597 ; Indicate no valid LVM sector was saved
598 stc
599
600 DIOSLVMS_Done:
601 ret
602DriveIO_SaveLVMSector EndP
603
604
605;------------------------------------------------------------------------------
606; Attempts to save the corresponding LVM sector for a partition
607;------------------------------------------------------------------------------
608; IN : AX - LBA lo of MBR or EBR
609; : BX - LBA hi of MBR or EBR
610; ; DL - BIOS disk number
611; ; SI - Pointer to sector buffer (usually [LVMSec])
612; OUT : CF=0 - A valid LVM sector was saved
613; NOTE : LocIPT_AbsolutePartTable and LocIPT_Drive can provide LBA and DISK
614;------------------------------------------------------------------------------
615DriveIO_SaveLVMSectorXBR Proc Near
616
617IFDEF AUX_DEBUG
618 IF 1
619 DBG_TEXT_OUT_AUX 'DriveIO_SaveLVMSectorXBR:'
620 PUSHRF
621 call DEBUG_DumpRegisters
622 call AuxIO_DumpSector
623 ;~ call AuxIO_DumpParagraph
624 ;~ call AuxIO_TeletypeNL
625 POPRF
626 ENDIF
627ENDIF
628
629 ; Save all registers
630 pusha
631
632 ; Check the validity of the LVM sector, quit with CY if invalid
633 push ax ; Save LBA lo
634 call LVM_ValidateSector ; Check signature and CRC
635 pop ax ; Restore LBA lo
636 jnc DriveIO_SaveLVMSectorXBR_no_lvm ; Quit if not valid
637
638 ; Calculate the entry in the DISKINFO array for this disk,
639 ; and put the LVM_SPT in DI
640 push bx
641 call DriveIO_CalcDiskInfoPointer
642 mov di, [bx+LocDISKINFO_LVM_Secs]
643 pop bx
644
645 ; If the LVM_SPT is ZERO, no LVM info is present and we quit with CY
646 test di, di ; See if it is 0
647 jz DriveIO_SaveLVMSectorXBR_no_lvm ; Quit if so
648
649 ; Adjust the location to point to the LVM sector
650 add ax, di ; Add the LVM sectors-per-track
651 adc bx, 0 ; Propagate LBA lo overflow to LBA hi
652 sub ax, 1 ; LVM sector is located one sector below
653 sbb bx, 0 ; Propagate borrow to LBA hi
654
655 ; Writing an LVM sector is always the result of modifications to a
656 ; previously loaded one. So, now that we have the LBA address of the
657 ; LVM sector, the one about to be overwritten should be there.
658 ; If it's not, something is seriously wrong and we quit immetiately.
659 pusha ; Push our context except the flags
660 mov si, offset [Scratch] ; Sector buffer to load the LVM sector
661 call ClearSectorBuffer ; Make sure no old LVM info is present
662 mov di, ds ; Segment of buffer
663 call DriveIO_ReadSectorLBA ; Load the old LVM sector
664 call LVM_ValidateSector ; CF=1 if valid
665 cmc ; Complement for disk i/o semantics
666 popa ; Restore our context except the flags
667
668 ; OOPS, There was no LVM sector there !!
669 jc DriveIO_SaveLVMSectorXBR_no_lvm
670
671 ; Save the LVM sector pointed to by SI
672 mov di, ds ; Segment of that buffer
673 call DriveIO_WriteSectorLBA ; Write the LVM sector
674
675IFDEF AUX_DEBUG
676 IF 1
677 DBG_TEXT_OUT_AUX 'LVMSecSaved'
678 PUSHRF
679 call DEBUG_DumpRegisters
680 call AuxIO_DumpSector
681 ;~ call AuxIO_DumpParagraph
682 ;~ call AuxIO_TeletypeNL
683 POPRF
684 ENDIF
685ENDIF
686
687 jc DriveIO_SaveLVMSectorXBR_no_lvm ; Quit on error
688
689 ; We're done, indicate success and return
690 clc
691 jmp DriveIO_SaveLVMSectorXBR_done
692
693 DriveIO_SaveLVMSectorXBR_no_lvm:
694 ; Indicate no valid LVM sector was saved
695 stc
696
697 DriveIO_SaveLVMSectorXBR_done:
698 ; Restore all registers
699 popa
700
701 ret
702DriveIO_SaveLVMSectorXBR EndP
703
704
705
706; Special error message instead of "LOAD ERROR" during partition scanning,
707; so users will notice that something is bad with their partition table(s)
708DriveIO_GotLoadError Proc Near
709 test byte ptr cs:[CurIO_Scanning], 1 ; Must be CS:, cause DS!=CS maybe here
710 jnz InScanMode
711 jmp MBR_LoadError
712 InScanMode:
713 mov si, offset TXT_BrokenPartitionTable
714 push cs
715 pop ds
716 call MBR_Teletype
717 mov si, offset BrokenHDD
718 sub dl, 50h ; 80h -> '0'
719 cmp dl, 39h
720 jbe DIOGLE_BelowA
721 add dl, 7 ; 3Ah -> 'A'
722 DIOGLE_BelowA:
723 mov bptr [si+5], dl
724 call MBR_Teletype
725
726 ; JWasm: cannot jump to local label in other procedure.
727 ; Changed to halt here.
728 ;jmp MBRLE_Halt
729 DriveIO_GotLoadError_halt:
730 jmp DriveIO_GotLoadError_halt
731DriveIO_GotLoadError EndP
732
733; #########################################################################
734; Routine: Loads a specified sector to DS:DI
735; #########################################################################
736; Calling : bx:ax - Absolute sector
737; cx:dx - Cylinder/Sector, Side/Drive (hi/lo-byte)
738; ds:si - Destination-Adress
739; Returns : none
740; Preserve: all registers
741; #########################################################################
742DriveIO_LoadSector Proc Near Uses ax bx cx dx ds si es di
743
744IFDEF AUX_DEBUG
745 IF 0
746 DBG_TEXT_OUT_AUX 'DriveIO_LoadSector:'
747 PUSHRF
748 call DEBUG_DumpRegisters
749 ;~ call AuxIO_DumpParagraph
750 ;~ call AuxIO_TeletypeNL
751 POPRF
752 ENDIF
753ENDIF
754
755 ; Is the drive not a harddrive?
756 cmp dl, 80h
757 jb DIOLS_UseNormal
758
759 test byte ptr cs:[CurIO_UseExtension], 1
760 jz DIOLS_UseNormal
761 ; Are we forced do use LBA via Setting?
762 jnz DIOLS_UseExtension
763
764 ; Upper 8 bits of LBA-address set?
765 ; Then use LBA (maximum boundary is 16320x16x63 = FB0400h)
766 or bh, bh
767 jnz DIOLS_UseExtension
768 ; Compare Switch-Table value to bit 16-23 of LBA-address
769 mov di, dx
770 and di, 007Fh
771 cmp bptr cs:[LBASwitchTable+di], bl
772 jbe DIOLS_UseExtension
773
774 DIOLS_UseNormal:
775
776IFDEF AUX_DEBUG
777 IF 0
778 DBG_TEXT_OUT_AUX 'DriveIO_ReadSectorCHS:'
779 PUSHRF
780 call DEBUG_DumpRegisters
781 call AuxIO_DumpParagraph
782 call AuxIO_TeletypeNL
783 POPRF
784 ENDIF
785ENDIF
786
787 mov di, 3 ; retry count
788 DIOLS_ErrorLoop:
789 push ds
790 pop es
791 mov bx, si ; ES:BX - Destination
792 mov ax, 0201h ; Function 2 - Load Sector
793 int 13h
794 jnc DIOLS_Success
795 dec di ; decrement retry count
796 jnz DIOLS_ErrorLoop
797
798 ; Sector load failed...
799 jmp DriveIO_GotLoadError
800
801 DIOLS_UseExtension:
802
803 mov di, ds ; segment for transfer address
804 call DriveIO_ReadSectorLBA ; extended read
805 jc DriveIO_GotLoadError ; halt on error
806
807 ;~ push cx
808 ;~ mov cs:[INT13X_DAP_NumBlocks], 1 ; Copy ONE sector
809 ;~ mov wptr cs:[INT13X_DAP_Transfer+0], si
810 ;~ mov cx, ds
811 ;~ mov wptr cs:[INT13X_DAP_Transfer+2], cx ; Fill out Transfer Adress
812 ;~ mov wptr cs:[INT13X_DAP_Absolute+0], ax
813 ;~ mov wptr cs:[INT13X_DAP_Absolute+2], bx ; Fill out Absolute Sector
814 ;~ push cs
815 ;~ pop ds
816 ;~ mov si, offset [INT13X_DAP]
817 ;~ mov ah, 42h ; Extended Read
818 ;~ int 13h
819 ;~ pop cx
820 ;~ jnc DIOLS_Success
821
822 ; Sector load failed...
823 ;~ jmp DriveIO_GotLoadError
824
825 DIOLS_Success:
826
827IFDEF AUX_DEBUG
828 IF 0
829 DBG_TEXT_OUT_AUX 'sector loaded'
830 PUSHRF
831 ;~ call DEBUG_DumpRegisters
832 ;~ call AuxIO_DumpSector
833 mov cx, 32
834 @@:
835 call AuxIO_DumpParagraph
836 call AuxIO_TeletypeNL
837 add si, 16
838 loop @B
839 POPRF
840 ENDIF
841ENDIF
842 ret
843DriveIO_LoadSector EndP
844
845
846;##############################################################################
847;# ACTION : Loads the Master Boot Record from the specified drive into buffer
848;# ----------------------------------------------------------------------------
849;# EFFECTS : Modifies DAP structure and fills or clears transfer buffer
850;# ----------------------------------------------------------------------------
851;# IN : DL - BIOS disk number (80h,81h,etc)
852;# : SI - Pointer to transfer buffer
853;# ----------------------------------------------------------------------------
854;# OUT : CF=1 - failure
855;# : AL.0 - MBR signature present
856;# : AL.1 - Primary partitions present
857;# : AL.2 - Extended partitions present
858;# : AL.3 - AiR-BOOT signature present
859;# : AL.4:7 - Reserved, returned as 0
860;# : AH.0:7 - Reserved, returned as 0
861;##############################################################################
862DriveIO_LoadMBR Proc Near uses bx cx dx si di
863
864 ; Always clear the transfer buffer first
865 call ClearSectorBuffer
866
867 ; Assume an invalid MBR
868 xor ax, ax
869
870 ; Accept only valid harddisks
871 call DriveIO_IsValidHarddisk
872 jc DriveIO_LoadMBR_exit
873
874 ; Save the address of the transfer buffer
875 mov di, si
876
877 ; Read the MBR from disk
878 xor ax, ax ; LBA low
879 xor bx, bx ; LBA high
880 xor dh, dh ; Head 0
881 mov cx, 1 ; Sector 1
882 call DriveIO_LoadSector ; Read the sector from disk
883
884 ; Check the loaded MBR for a signature
885 xor ax, ax ; Assume an invalid MBR
886 mov dx, [si+LocBR_Magic] ; Get word from MBR signature location
887 cmp dx, 0aa55h ; Is it the magic value ?
888 jne DriveIO_LoadMBR_exit ; Nope, no need to test anything else
889
890 ; Indicate we have a MBR signature
891 or al, 01h
892
893 ; Advance to the partition table
894 add si, 01beh
895
896 ; Total of 4 entries to check
897 mov cx, 4
898
899 DriveIO_LoadMBR_next_entry:
900 mov dl, [si+LocBRPT_SystemID] ; Get partition-type / system-id
901 add si, 10h ; Point to next entry
902 test dl, dl ; Nothing in this one ?
903 loopz DriveIO_LoadMBR_next_entry ; Then check next entry
904
905 ; All entries checked and last one was also empty, we're done
906 jz DriveIO_LoadMBR_check_ab
907
908 ; Found a non-empty entry, set bits according to its type
909 cmp dl, 05h ; Old style extended container ?
910 jne @F ; Nope...
911 or al, 04h ; Yep, mark ext. container present
912 @@: cmp dl, 0fh ; New style extended container ?
913 jne @F ; Nope...
914 or al, 04h ; Yep, mark ext. container present
915 @@: or al, 02h ; Then is must be a primary
916 jcxz DriveIO_LoadMBR_check_ab ; CX=0? Then all entries processed,
917 jmp DriveIO_LoadMBR_next_entry ; otherwise check next entry
918
919 ; Check if an AiR-BOOT signature is present
920 DriveIO_LoadMBR_check_ab:
921 mov si, offset [MBR_ABSig] ; Offset of AiR-BOOT signature
922 inc di ; Advance buffer pointer
923 inc di ; to AiR-BOOT signature location
924 mov cx, 7 ; Length of AiR-BOOT signature
925 cld ; Direction upwards
926 repe cmpsb ; Compare 7 bytes
927 jne DriveIO_LoadMBR_exit ; Nope, no AiR-BOOT on this disk
928 or al, 08h ; Yep, AiR-BOOT is on this disk
929 ;~ jmp DriveIO_LoadMBR_exit
930
931 DriveIO_LoadMBR_exit:
932 ret
933DriveIO_LoadMBR EndP
934
935
936;##############################################################################
937;# ACTION : Reads a sector from disk using INT13 extensions
938;# ----------------------------------------------------------------------------
939;# EFFECTS : Modifies DAP structure and fills transfer buffer
940;# ----------------------------------------------------------------------------
941;# IN : BX:AX - LBA address of sector
942;# : DI:SI - SEG:OFF of transfer buffer
943;# ----------------------------------------------------------------------------
944;# OUT : CF=1 - failure
945;##############################################################################
946DriveIO_ReadSectorLBA Proc Near
947
948IFDEF AUX_DEBUG
949 IF 0
950 DBG_TEXT_OUT_AUX 'DriveIO_ReadSectorLBA:'
951 PUSHRF
952 call DEBUG_DumpRegisters
953 call AuxIO_DumpParagraph
954 call AuxIO_TeletypeNL
955 POPRF
956 ENDIF
957ENDIF
958
959 ; Push all registers
960 pusha
961 push ds
962 push es
963
964 ; One sector to read
965 mov cs:[INT13X_DAP_NumBlocks], 1
966
967 ; Setup transfer address
968 mov wptr cs:[INT13X_DAP_Transfer+0], si ; offset
969 mov wptr cs:[INT13X_DAP_Transfer+2], di ; segment
970
971 ; Setup LBA64 address of requested sector
972 mov wptr cs:[INT13X_DAP_Absolute+0], ax ; low word lower part
973 mov wptr cs:[INT13X_DAP_Absolute+2], bx ; high word lower part
974 mov wptr cs:[INT13X_DAP_Absolute+4], 0 ; low word upper part
975 mov wptr cs:[INT13X_DAP_Absolute+6], 0 ; high word upper part
976
977 ; Address of packet
978 mov si, offset [INT13X_DAP] ; disk address packet
979
980 ; Do the extended read
981 mov ah, 42h ; read function
982 int 13h ; transfer to bios
983
984 ; Error occured
985 jc DriveIO_ReadSectorLBA_exit
986
987 ; AH should also be zero
988 test ah, ah
989 stc
990 jnz DriveIO_ReadSectorLBA_exit
991
992 ; Disk read succeeded, clear CF
993 clc
994
995 DriveIO_ReadSectorLBA_exit:
996
997 ; Pop all registers
998 pop es
999 pop ds
1000 popa
1001
1002 ret
1003DriveIO_ReadSectorLBA EndP
1004
1005
1006
1007;##############################################################################
1008;# ACTION : Writes a sector to disk using INT13 extensions
1009;# ----------------------------------------------------------------------------
1010;# EFFECTS : Modifies DAP structure and mofifies the disk
1011;# ----------------------------------------------------------------------------
1012;# IN : BX:AX - LBA address of sector
1013;# : DI:SI - SEG:OFF of transfer buffer
1014;# ----------------------------------------------------------------------------
1015;# OUT : CF=1 - failure
1016;##############################################################################
1017DriveIO_WriteSectorLBA Proc Near
1018
1019IFDEF AUX_DEBUG
1020 IF 0
1021 DBG_TEXT_OUT_AUX 'DriveIO_WriteSectorLBA:'
1022 PUSHRF
1023 call DEBUG_DumpRegisters
1024 call AuxIO_DumpParagraph
1025 call AuxIO_TeletypeNL
1026 POPRF
1027 ENDIF
1028ENDIF
1029
1030 ; Push all registers
1031 pusha
1032 push ds
1033 push es
1034
1035 ; One sector to read
1036 mov cs:[INT13X_DAP_NumBlocks], 1
1037
1038 ; Setup transfer address
1039 mov wptr cs:[INT13X_DAP_Transfer+0], si ; offset
1040 mov wptr cs:[INT13X_DAP_Transfer+2], di ; segment
1041
1042 ; Setup LBA64 address of requested sector
1043 mov wptr cs:[INT13X_DAP_Absolute+0], ax ; low word lower part
1044 mov wptr cs:[INT13X_DAP_Absolute+2], bx ; high word lower part
1045 mov wptr cs:[INT13X_DAP_Absolute+4], 0 ; low word upper part
1046 mov wptr cs:[INT13X_DAP_Absolute+6], 0 ; high word upper part
1047
1048 ; Address of packet
1049 mov si, offset [INT13X_DAP] ; disk address packet
1050
1051 ; Do the extended write
1052 xor al, al ; no write verify
1053 mov ah, 43h ; write function
1054 int 13h ; transfer to bios
1055
1056 ; Error occured
1057 jc DriveIO_WriteSectorLBA_exit
1058
1059 ; AH should also be zero
1060 test ah, ah
1061 stc
1062 jnz DriveIO_WriteSectorLBA_exit
1063
1064 ; Disk write succeeded, clear CF
1065 clc
1066
1067 DriveIO_WriteSectorLBA_exit:
1068
1069 ; Skip the removable drive check on success
1070 jnc @F
1071
1072 ; Here, CF=1 because of a failure.
1073 ; This could be from a removable drive that is set to read-only,
1074 ; in which case we want to fake success. What this boils down to
1075 ; is that CY must be set to !IsRemovable.
1076 call DriveIO_CalcDiskInfoPointer ; Get DISKINFO pointer
1077 mov dx, [bx+LocDISKINFO_I13X_Flags] ; Get INT13X flags
1078 xor dl, 04h ; Invert 'removable' bit
1079 and dl, 04h ; Mask it out
1080 rcr dl, 3 ; Move it to CY
1081
1082 @@:
1083
1084 ; Pop all registers
1085 pop es
1086 pop ds
1087 popa
1088
1089 ret
1090DriveIO_WriteSectorLBA EndP
1091
1092
1093
1094
1095;##############################################################################
1096;# The Master LVM sector is *not* necessarily located at the end of the BIOS
1097;# view of TRACK0. Its location depends on the *OS/2 geometry* active when the
1098;# disk was partitioned. For disks < 502MiB this will most likely be LBA sector
1099;# 62, but for disks >502MiB, *extended* OS/2 geometry was used and DANIS506
1100;# uses SPT=127 for disks < 1TiB while IBMS506 uses SPT=255.
1101;# When a huge disk < 1TiB was partitioned with IBMS506, thus using SPT=255,
1102;# and the driver was later changed to DANIS506, DANI uses SPT=255, eventhough
1103;# the disk < 1TiB. Whether it is DANI that is LVM aware or something else
1104;# (maybe LVM itself) that makes DANI use the correct geometry has yet to be
1105;# investigated.
1106;#
1107;# Related geometry issues are also present with USB sticks, which can get
1108;# assigned a geometry by OS/2, which can depend if the stick was partitioned
1109;# on foreign systems or not, or even OS/2 manufacturing a geometry that is not
1110;# the same as the BIOS reports to us here. In both cases, fixed disks and
1111;# removable disks, the geometry recorded in the BPB of a partition can also
1112;# influence the geometry that OS/2 assigns. This is the case when 'preparing'
1113;# disks for LVM use, in which case BPB values could be incorporated.
1114;#
1115;# What this all boils down to, is that the geometry reported by the BIOS is
1116;# of no practical use, especially not when taking BIOS USB MSD emulation into
1117;# account. These are among the reasons why AirBoot needs to use LBA addressing
1118;# when handling LVM stuff and why LBA use cannot be disabled in the SETUP
1119;# anymore.
1120;#
1121;# So, a Master LVM sector can be present on any sector from LBA 254 downwards
1122;# and the only way to locate the correct one is to scan all the way down and,
1123;# if one is found, do proper validation on its values, because it may also be
1124;# a 'phantom' LVM sector left over from previous partition layouts.
1125;# Most of such 'phantoms' can be filtered out by verifying the location of
1126;# the found sector against the OS/2 geometry it specifies itself, which means
1127;# it must be located at the LBA of the SPT-1 it specifies.
1128;##############################################################################
1129;# ACTION : Locates the Master LVM sector on the specified disk
1130;# ----------------------------------------------------------------------------
1131;# EFFECTS : Leaves [Scratch] with last sector read or cleared
1132;# ----------------------------------------------------------------------------
1133;# IN : DL - BIOS disk number of drive to search
1134;# ----------------------------------------------------------------------------
1135;# OUT : CF=1 - found
1136;# : BX:AX - LBA address of LVM sector if found, 0 otherwise
1137;##############################################################################
1138DriveIO_LocateMasterLVMSector Proc Near uses cx dx si di ds es
1139
1140IFDEF AUX_DEBUG
1141 IF 0
1142 DBG_TEXT_OUT_AUX 'DriveIO_LocateMasterLVMSector:'
1143 PUSHRF
1144 call DEBUG_DumpRegisters
1145 ;~ call AuxIO_DumpSector
1146 ;~ call AuxIO_DumpParagraph
1147 ;~ call AuxIO_TeletypeNL
1148 POPRF
1149 ENDIF
1150ENDIF
1151
1152 ; LBA address to start scanning down from
1153 mov cx, 255
1154
1155 ; Make sure ES==DS
1156 push ds
1157 pop es
1158
1159 ; Because JCXZ is used, LBA sector 0 is never loaded and checked.
1160 ; This is of course no problem since it is the MBR.
1161 DriveIO_LocateMasterLVMSector_next:
1162 mov si, offset [Scratch] ; Use scratch area to load sectors
1163 call ClearSectorBuffer ; Clear the scratch area
1164 clc ; Indicate Master LVM sector not found
1165 jcxz DriveIO_LocateMasterLVMSector_done
1166
1167 ; Read the LBA sector specified in CX
1168 mov ax, cx ; LBA low
1169 xor bx, bx ; LBA high
1170 mov di, ds ; Segment of scratch buffer
1171 mov si, offset [Scratch] ; Offset of scratch buffer
1172 call DriveIO_ReadSectorLBA ; Read the sector
1173 lahf ; Save CF
1174 dec cx ; Prepare LBA of next sector to read
1175 sahf ; Restore CF
1176 ; No need to do any LVM sector validation when read error, read next
1177 jc DriveIO_LocateMasterLVMSector_next
1178
1179 ; See if the read sector has a valid signature and checksum
1180 call LVM_ValidateSector
1181
1182 ; NC indicates invalid or none-LVM sector, read next
1183 jnc DriveIO_LocateMasterLVMSector_next
1184
1185 ; We have found a valid LVM sector !
1186 ; So it contains the OS/2 geometry for the disk.
1187 ; That means this LVM sector itself must be located on the last sector
1188 ; of the SPT value its OS/2 geometery specifies, which, in LBA terms
1189 ; is LVM SPT-1 -- let's check that...
1190 mov bx, offset [Scratch] ; Offset of the loaded LVM sector
1191 mov al, [bx+LocLVM_Secs] ; Get the LVM SPT value (<=255)
1192 dec al ; Adjust to LVM LBA
1193 mov ah, cl ; Get next LVM LBA to search
1194 inc ah ; This one was found here
1195 cmp al, ah ; If same, LVM LBA location OK
1196 jne DriveIO_LocateMasterLVMSector_next
1197
1198 ; The LVM sector we found is at the location it should be on disk,
1199 ; so it's almost 99% sure this is the correct one.
1200 ; Now we should compare the start and sizes of the partitions in the
1201 ; MBR with the partitions specified in this LVM record.
1202 ; We'll implement that later after some more research.
1203 ; For now we assume this is the correct Master LVM sector for the disk.
1204 inc cx ; CX was prepared to read next, correct that
1205 stc ; Indicate we have found the Master LVM sector
1206
1207 DriveIO_LocateMasterLVMSector_done:
1208 mov bx, 0 ; A Master LVM sector always has high LBA=0
1209 mov ax, cx ; Low LBA of Master LVM sector
1210
1211 ; We leave it up to the caller to store the value in a proper place
1212 ret
1213DriveIO_LocateMasterLVMSector EndP
1214
1215
1216
1217;
1218; ############################################################
1219; # Check for a valid MBR-sector to be written to disk #
1220; ############################################################
1221;
1222; In
1223; --
1224; DL = Physical Disk
1225; BX:CX = LBA sector
1226; DI:SI = Source buffer
1227;
1228; Out
1229; ---
1230; CY = 1 if invalid MBR in source buffer, 0 if valid
1231;
1232; This routine is called when DriveIO_SaveSector attempts to write to the MBR.
1233; It checks if the sector to be written has some sensible values in certain
1234; places. In fact, if the sector is written to the boot-disk, the AiR-BOOT
1235; signature should be present and the partition table should be the same
1236; as the one at the start of the AiR-BOOT code in memory, except maybe for the
1237; active flags.
1238; For other disks, only the active flags are checked to be 00h or 80h and
1239; the AA55h MBR signature.
1240;
1241DriveIO_ProtectMBR Proc Near
1242 pusha ; Push all registers
1243 push es ; Push ES because we need it for string instructions
1244 push cs ; Make ES point...
1245 pop es ; to CS
1246
1247 ; Save the pointer to the sector to write in BX
1248 mov bx,si
1249
1250 ;
1251 ; If the sector to be written is not the boot-disk, then skip
1252 ; checking the AiR-BOOT MBR.
1253 ;
1254 cmp dl, [BIOS_BootDisk]
1255 jne DriveIO_ProtectMBR_is_not_bootdisk
1256
1257 ;
1258 ; The boot-disk is accessed so the sector to be written must be
1259 ; the AiR-BOOT MBR. This is the same as the first 512 bytes
1260 ; relocated to 8000:0000 and this the start of the AB-code.
1261 ;
1262 mov si,bx ; Get pointer to sector to write
1263 xor di,di ; Point DI to start of AB-code (MBR)
1264 mov cx, offset [MBR_PartTable] ; Bytes upto P-table must be same
1265 cld ; Compare upwards
1266 repe cmpsb ; Compare upto P-table
1267
1268 ; If not the same this is not the an AiR-BOOT boot-disk MBR !
1269 jne DriveIO_ProtectMBR_not_valid_MBR ; SEVERE ERROR !
1270
1271 ; Continue with signature check
1272 jmp DriveIO_ProtectMBR_check_signature
1273
1274
1275 ;
1276 ; The disk is not the boot-disk so we don't know what kind of MBR is on it.
1277 ; Some sanity checks should be here.
1278 ;
1279 DriveIO_ProtectMBR_is_not_bootdisk:
1280
1281 ;
1282 ; sanity checks...
1283 ;
1284
1285 ; Continue with signature check
1286 jmp DriveIO_ProtectMBR_check_signature
1287
1288
1289 DriveIO_ProtectMBR_check_signature:
1290 ; See if the sector to write contains a valid signature
1291 mov si,bx ; Get pointer to sector to write
1292 mov di, offset [MBR_Sig] ; Offset to MBR signature
1293 add si,di ; Make SI point to it in sec to write
1294 lodsw ; Load it
1295 cmp ax,0aa55h ; See if it is valid
1296
1297 ; If no signature this cannot be a valid MBR !
1298 jne DriveIO_ProtectMBR_not_valid_MBR ; SEVERE ERROR !
1299
1300
1301 ;
1302 ; The sector to be written seems to be valid.
1303 ; Set CY=0 to indicate a valid MBR.
1304 ;
1305 DriveIO_ProtectMBR_is_valid_MBR:
1306 clc
1307 jmp DriveIO_ProtectMBR_end
1308
1309 ;
1310 ; Something is terribly wrong; a non-MBR sector seems about to be written.
1311 ; Set CY=1 and let the calling code handle this situation.
1312 ;
1313 DriveIO_ProtectMBR_not_valid_MBR:
1314 stc
1315 jmp DriveIO_ProtectMBR_end
1316
1317 ;
1318 ; Return to the caller with no registers modyfied except FLAGS.
1319 ;
1320 DriveIO_ProtectMBR_end:
1321 pop es
1322 popa
1323 ret
1324DriveIO_ProtectMBR Endp
1325
1326
1327
1328; #########################################################################
1329; Routine: Checks if the MBR is addressed by either CHS or LBA
1330; #########################################################################
1331; Calling : bx:ax - Absolute sector
1332; cx:dx - Cylinder/Sector, Side/Drive (hi/lo-byte)
1333; Returns : ZF=1 if MBR is addressed, else ZF=0
1334; Preserve: all registers
1335; #########################################################################
1336DriveIO_MBR_Addressed Proc
1337 push ax
1338 push bx
1339
1340 or bx,ax ; Results in 0 in BX if MBR is addressed by LBA
1341 jz DriveIO_MBR_Addressed_done
1342
1343 mov ax,cx ; Results in 1 in AX if CYL 0, SEC 1 is addressed
1344 add al,dh ; Results in 1 in AX if HEAD 0 is addressed
1345 dec ax ; Results in 0 in AX if MBR is addressed by CHS
1346
1347 DriveIO_MBR_Addressed_done:
1348 pop bx
1349 pop ax
1350 ret
1351DriveIO_MBR_Addressed EndP
1352
1353
1354
1355
1356; #########################################################################
1357; Routine: Writes DS:SI to a specified sector
1358; #########################################################################
1359; Calling : bx:ax - Absolute sector
1360; cx:dx - Cylinder/Sector, Side/Drive (hi/lo-byte)
1361; ds:si - Source-Adress
1362; Returns : none
1363; Preserve: all registers
1364; #########################################################################
1365DriveIO_SaveSector Proc Near Uses ax bx cx dx ds si es di
1366
1367IFDEF AUX_DEBUG
1368 IF 0
1369 DBG_TEXT_OUT_AUX 'DriveIO_SaveSector:'
1370 PUSHRF
1371 call DEBUG_DumpRegisters
1372 ;~ call AuxIO_DumpParagraph
1373 ;~ call AuxIO_TeletypeNL
1374 POPRF
1375 ENDIF
1376ENDIF
1377
1378
1379;!
1380;! DEBUG_BLOCK
1381;! Force write to LBA0 to test interception routine.
1382;! Do *NOT* enable unless you are debugging, will overwrite MBR !
1383;!
1384IFDEF AUX_DEBUG
1385 IF 0
1386 pushf
1387 pusha
1388 xor ax,ax
1389 xor bx,bx
1390 xor cx,cx
1391 inc cx
1392 xor dh,dh
1393 popa
1394 popf
1395 ENDIF
1396ENDIF
1397
1398 ;
1399 ; Check if the MBR is the destination for the write.
1400 ; ZF=1 if so.
1401 ;
1402 call DriveIO_MBR_Addressed
1403 jnz DriveIO_SaveSector_continue_write
1404
1405
1406 ; MBR is addressed, check the sector that is requested to be written.
1407 ; For the bootdisk it should contain the AiR-BOOT signature, valid
1408 ; partition-table entries and the AA55h signature.
1409 ; If not, something is terribly wrong in some piece of the AB code.
1410 ; For any other disk (80h+) at least a valid partition table should
1411 ; be present together with the AA55h signature.
1412 call DriveIO_ProtectMBR
1413 jnc DriveIO_SaveSector_continue_write
1414
1415
1416 ;
1417 ; WE HAVE A SEVERE ERROR CONDITION !
1418 ; SOME AB CODE TRIES TO WRITE A NON-MBR TO THE DISK !
1419 ; ASK THE USER TO REPORT THIS !
1420 ; HALT THE SYSTEM !
1421 ;
1422
1423 ; Show error-box
1424 mov cx, 0C04h
1425 mov si, offset NonMBRwrite
1426 call SETUP_ShowErrorBox
1427 mov cx, 0C04h
1428 mov si, offset NonMBRwrite_rep
1429 call SETUP_ShowErrorBox
1430
1431
1432IFDEF AUX_DEBUG
1433 IF 0
1434 pushf
1435 pusha
1436 mov si, offset [NonMBRwrite]
1437 call AuxIO_TeletypeNL
1438 call AuxIO_Print
1439 call AuxIO_TeletypeNL
1440 popa
1441 popf
1442 ENDIF
1443ENDIF
1444
1445 ; Show popup and halt the system.
1446 jmp HaltSystem
1447
1448
1449
1450 ;
1451 ; Continue the write if not MBR sector or MBR to write is validated.
1452 ;
1453 DriveIO_SaveSector_continue_write:
1454 test byte ptr cs:[CurIO_UseExtension], 1
1455 jz DIOSS_UseNormal
1456 ; Are we forced do use LBA via Setting?
1457 ; Always use INT13X on v1.0.8+.
1458 ;~ test byte ptr cs:[CFG_ForceLBAUsage], 1
1459 ;~ jnz DIOSS_UseExtension
1460 jmp DIOSS_UseExtension
1461 ; Is the drive not a harddrive?
1462 cmp dl, 80h
1463 jb DIOSS_UseNormal
1464 ; Upper 8 bits of LBA-address set? -> Use LBA (maximum boundary is FB0400h)
1465 or bh, bh
1466 jnz DIOSS_UseExtension
1467 ; Compare Switch-Table value to bit 16-23 of LBA-address
1468 mov di, dx
1469 and di, 007Fh
1470 cmp bptr cs:[LBASwitchTable+di], bl
1471 jbe DIOSS_UseExtension
1472
1473 DIOSS_UseNormal:
1474
1475IFDEF AUX_DEBUG
1476 IF 0
1477 DBG_TEXT_OUT_AUX 'DriveIO_WriteSectorCHS:'
1478 PUSHRF
1479 call DEBUG_DumpRegisters
1480 call AuxIO_DumpParagraph
1481 call AuxIO_TeletypeNL
1482 POPRF
1483 ENDIF
1484ENDIF
1485
1486 mov di, 3 ; retry count
1487 DIOSS_ErrorLoop:
1488 push ds
1489 pop es
1490 mov bx, si ; ES:BX - Destination
1491 mov ax, 0301h ; Function 3 - Write Sector
1492 int 13h
1493 jnc DIOSS_Success
1494 dec di ; decrement retry count
1495 jnz DIOSS_ErrorLoop
1496 call MBR_SaveError
1497
1498 DIOSS_UseExtension:
1499
1500 mov di, ds ; segment for transfer address
1501 call DriveIO_WriteSectorLBA ; extended write
1502 jc MBR_SaveError ; halt on error
1503
1504 ;~ push cx
1505 ;~ mov cs:[INT13X_DAP_NumBlocks], 1 ; Copy ONE sector
1506 ;~ mov wptr cs:[INT13X_DAP_Transfer+0], si
1507 ;~ mov cx, ds
1508 ;~ mov wptr cs:[INT13X_DAP_Transfer+2], cx ; Fill out Transfer Adress
1509 ;~ mov wptr cs:[INT13X_DAP_Absolute+0], ax
1510 ;~ mov wptr cs:[INT13X_DAP_Absolute+2], bx ; Fill out Absolute Sector
1511 ;~ push cs
1512 ;~ pop ds
1513 ;~ mov si, offset [INT13X_DAP]
1514 ;~ mov ax, 4300h ; Extended Write (No Verify)
1515 ;~ int 13h
1516 ;~ pop cx
1517 ;~ jnc DIOSS_Success
1518 ;~ call MBR_SaveError
1519
1520 DIOSS_Success:
1521 ret
1522DriveIO_SaveSector EndP
1523
1524
1525
1526
1527;##############################################################################
1528;# When a disk has a Master LVM sector, it means it has been prepared for use
1529;# by OS/2 and contains important information about how OS/2 views its geometry
1530;# and other disk related properties. This function assumes the LBA address
1531;# of the Master LVM sector has already been located and simply loads the
1532;# sector into [LVMSector].
1533;#
1534;# Note that because this is an operation similar to the regular loading of
1535;# sectors, the disk I/O semantics are used here. This means CF=0 when an LVM
1536;# sector is successfully loaded and CF=1 otherwise.
1537;##############################################################################
1538;# ACTION : Loads the Master LVM sector if one exists
1539;# ----------------------------------------------------------------------------
1540;# EFFECTS : Modifies DAP structure and [LVMSector]
1541;# ----------------------------------------------------------------------------
1542;# IN : DL - BIOS disk number (80h,81h,etc)
1543;# ----------------------------------------------------------------------------
1544;# OUT : CF=0 - Valid Master LVM sector found and loaded
1545;##############################################################################
1546DriveIO_LoadMasterLVMSector Proc Near
1547
1548IFDEF AUX_DEBUG
1549 IF 0
1550 DBG_TEXT_OUT_AUX 'DriveIO_LoadMasterLVMSector:'
1551 PUSHRF
1552 ;~ call DEBUG_DumpRegisters
1553 ;~ call AuxIO_DumpParagraph
1554 ;~ call AuxIO_TeletypeNL
1555 POPRF
1556 ENDIF
1557ENDIF
1558
1559 ; Save all registers
1560 pusha
1561
1562 ; Check if BIOS disk number is valid
1563 call DriveIO_IsValidHarddisk
1564 jc DriveIO_LoadMasterLVMSector_error
1565
1566 ; Calculate the entry in the DISKINFO array for this disk
1567 call DriveIO_CalcDiskInfoPointer
1568
1569 ; Save the entry for later recalls
1570 mov bp, bx
1571
1572 ; Get the LBA address of the Master LVM sector
1573 mov ax, [bx+LocDISKINFO_LVM_MasterLBA+00h]
1574 mov bx, [bx+LocDISKINFO_LVM_MasterLBA+02h]
1575
1576 ; LBA of Master LVM sector cannot be 0, so none was found during
1577 ; the gathering of disk information.
1578 mov cx, ax
1579 or cx, bx
1580 jz DriveIO_LoadMasterLVMSector_error
1581
1582 ; Load it into [LVMSector]
1583 mov di, ds
1584 mov si, offset [LVMSector]
1585 call DriveIO_ReadSectorLBA
1586 jc DriveIO_LoadMasterLVMSector_error
1587
1588 ; Validate the Master LVM sector
1589 call LVM_ValidateSector
1590
1591 ; Complement success indicator to conform to semantics of this function
1592 cmc
1593
1594 ; Master LVM sector was valid and is now loaded in [LVMSector]
1595 jnc DriveIO_LoadMasterLVMSector_ret
1596
1597 DriveIO_LoadMasterLVMSector_error:
1598
1599 ; Clear the sector buffer for safety reasons
1600 mov si, offset [LVMSector]
1601 call ClearSectorBuffer
1602
1603 ; Indicate no Master LVM sector loaded
1604 stc
1605
1606 DriveIO_LoadMasterLVMSector_ret:
1607
1608 ; Restore all registers
1609 popa
1610
1611 ret
1612DriveIO_LoadMasterLVMSector Endp
1613
1614
1615
1616
1617;##############################################################################
1618;# There is much information to know about the connected disks.
1619;# We also want this information clustered per disk and available before
1620;# further disk and partition scanning takes place.
1621;# This function gathers such information like INT13, INT13X, MBR, LVM, more.
1622;# Especially important is the LVM information, because that contains the
1623;# geometry OS/2 uses to access the disk. Other important information is the
1624;# presence of valid MBRs, logical partitions and whatnot.
1625;# This function gathers such information and stores it in a DISKINFO structure
1626;# for which an instance exists for every disk found.
1627;##############################################################################
1628;# ACTION : Gather disk information and store this in the BSS
1629;# ----------------------------------------------------------------------------
1630;# EFFECTS : Modifies DAP structure and the buffers it uses, fills DISKINFO[n]
1631;# ----------------------------------------------------------------------------
1632;# IN : DL - BIOS disk number (80h,81h,etc)
1633;# ----------------------------------------------------------------------------
1634;# OUT : CF=1 - failure
1635;##############################################################################
1636DriveIO_GatherDiskInfo Proc Near
1637
1638IFDEF AUX_DEBUG
1639 IF 0
1640 DBG_TEXT_OUT_AUX 'DriveIO_GatherDiskInfo:'
1641 PUSHRF
1642 call DEBUG_DumpRegisters
1643 ;~ call AuxIO_DumpParagraph
1644 ;~ call AuxIO_TeletypeNL
1645 POPRF
1646 ENDIF
1647ENDIF
1648
1649 ; Push all registers we use
1650 pusha
1651 push ds
1652 push es
1653
1654 ; Make sure ES=DS
1655 push ds
1656 pop es
1657
1658 ; Check if BIOS disk number is valid
1659 call DriveIO_IsValidHarddisk
1660 jc DriveIO_GatherDiskInfo_error
1661
1662 ; Calculate the entry in the DISKINFO array for this disk
1663 call DriveIO_CalcDiskInfoPointer
1664
1665 ; Save the entry for later recalls
1666 mov bp, bx
1667
1668 ; Store the BIOS disk number in the structure
1669 mov [bx+LocDISKINFO_DiskNum], dl
1670
1671; ------------------------------------------------------------------- [ INT13 ]
1672
1673 ; Get BIOS Disk Parameters (legacy method)
1674 mov ah, 08h ; Get Disk Parameters
1675 int 13h ; Call BIOS
1676
1677 ; CF=1 or AH!=0 indicates error
1678 jc DriveIO_GatherDiskInfo_error
1679 test ah, ah
1680 jnz DriveIO_GatherDiskInfo_error
1681
1682 ; Recall DISKINFO entry
1683 mov bx, bp
1684
1685 ; Store SPT (WORD)
1686 xor ah, ah ; Zero extend SPT to 16 bits
1687 mov al, cl ; Hi 2 bits max cyl and max sec
1688 and al, 3fh ; Mask max sec (1-based)
1689 mov [bx+LocDISKINFO_I13_Secs], ax ; Store SPT
1690
1691 ; Store HEADS (WORD)
1692 xor dl, dl ; Zero extend HEADS to 16 bits
1693 xchg dl, dh ; Get max head (0-based)
1694 inc dx ; Head count
1695 mov [bx+LocDISKINFO_I13_Heads], dx ; Store HEADS
1696
1697 ; Store CYLS (WORD)
1698 shr cl, 6 ; Hi 2 bits of max cyl to 1:0
1699 xchg cl, ch ; Max cyl (0-based)
1700 inc cx ; Cyl count
1701 mov [bx+LocDISKINFO_I13_Cyls], cx ; Store CYLS
1702
1703 ; Recall BIOS disk number
1704 mov dl, [bx+LocDISKINFO_DiskNum]
1705
1706; ------------------------------------------------------------------ [ INT13X ]
1707
1708 ; Get BIOS Disk Parameters (extended method)
1709 mov si, offset [Scratch] ; Buffer to return disk info
1710 mov ax, 80h ; Size of buffer
1711 mov [si], ax ; Store it in first word
1712 mov ah, 48h ; Get Extended Disk Parameters
1713 int 13h ; Call BIOS
1714
1715 ; CF=1 or AH!=0 indicates error
1716 jc DriveIO_GatherDiskInfo_error
1717 test ah, ah
1718 jnz DriveIO_GatherDiskInfo_error
1719
1720 ; Store flags (WORD)
1721 cld ; Direction up
1722 lodsw ; Buffersize, discard
1723 lodsw ; Flags (CHS valid etc)
1724 mov [bx+LocDISKINFO_I13X_Flags], ax ; Store them
1725
1726 ; Store CYLS (DWORD)
1727 lodsw ; Cyl count low
1728 mov [bx+LocDISKINFO_I13X_Cyls+00h], ax ; Store CYLS low
1729 lodsw ; Cyl count high
1730 mov [bx+LocDISKINFO_I13X_Cyls+02h], ax ; Store CYLS high
1731
1732 ; Store HEADS (DWORD)
1733 lodsw ; Head count low
1734 mov [bx+LocDISKINFO_I13X_Heads+00h], ax ; Store HEADS low
1735 lodsw ; Head count high
1736 mov [bx+LocDISKINFO_I13X_Heads+02h], ax ; Store HEADS high
1737
1738 ; Store SPT (DWORD)
1739 lodsw ; Secs per track low
1740 mov [bx+LocDISKINFO_I13X_Secs+00h], ax ; Store SPT low
1741 lodsw ; Secs per track high
1742 mov [bx+LocDISKINFO_I13X_Secs+02h], ax ; Store SPT high
1743
1744 ; Store total LBA sectors (QWORD)
1745 lea di, [bx+LocDISKINFO_I13X_SecsLBA]
1746 mov cx, 4
1747 rep movsw
1748
1749 ; Store sector size (WORD)
1750 lodsw
1751 mov [bx+LocDISKINFO_I13X_SecSize], ax
1752
1753 ; Store bus name (4 bytes, space padded, v3.0+)
1754 lea si, [Scratch+24h]
1755 lea di, [bx+LocDISKINFO_I13X_HostBus]
1756 movsw
1757 movsw
1758
1759 ; Store interface name (8 bytes, space padded, v3.0+)
1760 lea di, [bx+LocDISKINFO_I13X_Interface]
1761 mov cx, 4
1762 rep movsw
1763
1764 ; Should gather some more INT13X info here,
1765 ; like maybe Advanced Format stuff or so.
1766 ; We'll investigate that at a later time.
1767
1768; --------------------------------------------------------------------- [ MBR ]
1769
1770 ; Load the MBR
1771 mov si, offset [TmpSector]
1772 call DriveIO_LoadMBR
1773
1774 ; Store MBR flags (valid sig, partitions present, airboot installed)
1775 mov [bx+LocDISKINFO_MbrFlags], al
1776
1777 ; Recall BIOS disk number
1778 mov dl, [bx+LocDISKINFO_DiskNum]
1779
1780; --------------------------------------------------------------------- [ LVM ]
1781
1782 ; Locate the Master LVM sector, if any
1783 call DriveIO_LocateMasterLVMSector
1784
1785 ; Save Master LVM sector LBA high
1786 mov cx, bx
1787
1788 ; Recall DISKINFO entry
1789 mov bx, bp
1790
1791 ; Store Master LVM sector LBA
1792 mov [bx+LocDISKINFO_LVM_MasterLBA+00h], ax
1793 mov [bx+LocDISKINFO_LVM_MasterLBA+02h], cx
1794
1795 ; No Master LVM sector found, so skip storing LVM info for this disk
1796 jnc DriveIO_GatherDiskInfo_no_master_lvm
1797
1798 ; Load the Master LVM sector into [LVMSector]
1799 call DriveIO_LoadMasterLVMSector
1800
1801 ; No valid Master LVM sector, so skip storing LVM info for this disk
1802 jc DriveIO_GatherDiskInfo_no_master_lvm
1803
1804 ; A valid Master LVM sector has been loaded into [LVMSector]
1805 mov si, offset [LVMSector]
1806
1807 ; Get the number of sectors per track (OS/2 geometry)
1808 mov ax, [si+LocLVM_Secs+00h]
1809 mov cx, [si+LocLVM_Secs+02h]
1810
1811 ; Store it
1812 mov [bx+LocDISKINFO_LVM_Secs+00h], ax
1813 mov [bx+LocDISKINFO_LVM_Secs+02h], cx
1814
1815 ; Get the number of heads (OS/2 geometry)
1816 mov ax, [si+LocLVM_Heads+00h]
1817 mov cx, [si+LocLVM_Heads+02h]
1818
1819 ; Store it
1820 mov [bx+LocDISKINFO_LVM_Heads+00h], ax
1821 mov [bx+LocDISKINFO_LVM_Heads+02h], cx
1822
1823 ; Should gather some more LVM info here,
1824 ; like OS/2 extended geometry and other flags.
1825 ; We'll implement that at a later time.
1826
1827 DriveIO_GatherDiskInfo_no_master_lvm:
1828
1829 ; When no Master LVM sector was found,
1830 ; the LVM info in the DISKINFO structure for the disk
1831 ; will be ZERO because the area was cleared in PRECRAP.
1832
1833 ; Indicate success
1834 clc
1835
1836 jmp DriveIO_GatherDiskInfo_ret
1837
1838 DriveIO_GatherDiskInfo_error:
1839 stc
1840 DriveIO_GatherDiskInfo_ret:
1841
1842
1843IFDEF AUX_DEBUG
1844 IF 0
1845 DBG_TEXT_OUT_AUX '[DISKINFO]'
1846 PUSHRF
1847 call DEBUG_DumpRegisters
1848 ;~ call AuxIO_DumpParagraph
1849 ;~ call AuxIO_TeletypeNL
1850 mov si, bp
1851 mov cx, 4
1852 @@:
1853 call AuxIO_DumpParagraph
1854 call AuxIO_TeletypeNL
1855 add si, 16
1856 loop @B
1857 mov si, offset [Scratch]
1858 mov cx, 4
1859 @@:
1860 call AuxIO_DumpParagraph
1861 call AuxIO_TeletypeNL
1862 add si, 16
1863 loop @B
1864 mov si, offset [LVMSector]
1865 mov cx, 7
1866 @@:
1867 call AuxIO_DumpParagraph
1868 call AuxIO_TeletypeNL
1869 add si, 16
1870 loop @B
1871 POPRF
1872 ENDIF
1873ENDIF
1874
1875 ; Restore registers
1876 pop es
1877 pop ds
1878 popa
1879
1880 ret
1881DriveIO_GatherDiskInfo EndP
1882
1883;------------------------------------------------------------------------------
1884; Scan all disks to gather information
1885;------------------------------------------------------------------------------
1886; IN : None
1887; OUT : CF=1 - some failure occured
1888; : ZF=1 - no harddisks
1889; NOTE : This does the preliminary gathering of disk information
1890;------------------------------------------------------------------------------
1891DriveIO_ScanDisks Proc Near
1892
1893IFDEF AUX_DEBUG
1894 IF 0
1895 DBG_TEXT_OUT_AUX 'DriveIO_ScanDisks:'
1896 PUSHRF
1897 call DEBUG_DumpRegisters
1898 ;~ call AuxIO_DumpParagraph
1899 ;~ call AuxIO_TeletypeNL
1900 POPRF
1901 ENDIF
1902ENDIF
1903
1904 ; Save all registers
1905 pusha
1906
1907 ; Get number of disks in DH
1908 call DriveIO_GetHardDriveCount
1909
1910 ; Check if there are any disks to scan
1911 xor cx, cx ; Prepare 16-bit counter
1912 mov cl, dh ; Number of disks now in CX
1913 jcxz DriveIO_ScanDisks_end ; Quit if no disks
1914
1915 ; Scan disks from 80h upward
1916 mov dl, 80h ; BIOS number of first disk
1917 DriveIO_ScanDisks_next:
1918 call DriveIO_GatherDiskInfo ; Gather info for this disk
1919 jc DriveIO_ScanDisks_end ; Quit if some error occured
1920 inc dl ; Advance to next disk
1921 loop DriveIO_ScanDisks_next ; Scan next disk if there is one
1922 test dl, dl ; Set ZF=0
1923 clc ; Indicate success
1924
1925 DriveIO_ScanDisks_end:
1926 ; Restore all registers
1927 popa
1928
1929 ret
1930DriveIO_ScanDisks EndP
1931
1932;------------------------------------------------------------------------------
1933; Calculate pointer to entry in DISKINFO structure
1934;------------------------------------------------------------------------------
1935; IN : DL BIOS disk number (80h etc)
1936; OUT : BX Pointer to entry
1937; NOTE : BIOS disk number must be valid
1938;------------------------------------------------------------------------------
1939DriveIO_CalcDiskInfoPointer Proc Near
1940 xchg bx, ax ; AX is used for calculation
1941 mov al, DISKINFO_Size ; Size of DISKINFO structure
1942 mov ah, dl ; BIOS disk number
1943 sub ah, 80h ; Now 0-based index
1944 mul ah ; Now offset into DISKINFO array
1945 add ax, offset [DiskInformation] ; Base of DISKINFO array
1946 xchg bx, ax ; BX now points to entry for disk
1947 ret
1948DriveIO_CalcDiskInfoPointer EndP
1949
1950;------------------------------------------------------------------------------
1951; Check if the BIOS disk number in DL is a harddisk and in range
1952;------------------------------------------------------------------------------
1953; IN : DL BIOS disk number (80h etc)
1954; OUT : CF=1 if invalid disk number or out of range
1955; NOTE : Only modifies flags
1956;------------------------------------------------------------------------------
1957DriveIO_IsValidHarddisk Proc Near Uses dx
1958 cmp dl, 80h ; BIOS disk number must be at least 80h
1959 jb @F ; Not a harddisk, exit with CY
1960 mov dh, dl ; Save to do compare
1961 sub dh, 80h ; Now 0 based disk number
1962 inc dh ; Now 1 based disk number
1963 cmp [TotalHarddiscs], dh ; Out of range, exit with CY
1964 @@: ret
1965DriveIO_IsValidHarddisk EndP
1966
1967
1968; Values for sectors per track table corresponding to DriveIO_IsHugeDrive return value.
1969;~ secs_per_track_table db 63,127,255,255,255,255
1970
1971;~ db_lmlvm db 'Load Master LVM -- disk: ',0
Note: See TracBrowser for help on using the repository browser.