source: trunk/bootcode/regular/driveio.asm@ 168

Last change on this file since 168 was 168, checked in by Ben Rietbroek, 8 years ago

Fake write succes on removable disks [v1.1.1-testing]

Accessing, and thus writing, removable disks is highly dependent on
the BIOS USB mass-storage emulation. Also, some removable disks have
a small switch to set it to read-only. We don't want such stuff to halt
AiR-BOOT with a 'SAVE ERROR', so we fake success in such cases.

CAUTION:
This is a testbuild !
AirBoot uses the BIOS to access disks and a small coding error can trash
partition tables or other vital disk structures. You are advised to make
backups of TRACK0 and EBRs before using this testbuild. More info at:
​https://rousseaux.github.io/netlabs.air-boot/pdf/AirBoot-v1.1.0-manual.pdf
File size: 73.4 KB
Line 
1; AiR-BOOT (c) Copyright 1998-2008 M. Kiewitz
2;
3; This file is part of AiR-BOOT
4;
5; AiR-BOOT is free software: you can redistribute it and/or modify it under
6; the terms of the GNU General Public License as published by the Free
7; Software Foundation, either version 3 of the License, or (at your option)
8; any later version.
9;
10; AiR-BOOT is distributed in the hope that it will be useful, but WITHOUT ANY
11; WARRANTY: without even the implied warranty of MERCHANTABILITY or FITNESS
12; FOR A PARTICULAR PURPOSE. See the GNU General Public License for more
13; details.
14;
15; You should have received a copy of the GNU General Public License along with
16; AiR-BOOT. If not, see <http://www.gnu.org/licenses/>.
17;
18;---------------------------------------------------------------------------
19; AiR-BOOT / DRIVE I/O
20;---------------------------------------------------------------------------
21
22
23
24IFDEF MODULE_NAMES
25DB 'DRIVEIO',0
26ENDIF
27
28;
29; Check if INT13X extensions are supported.
30; AirBoot requires these extensions, and will halt if they are not available.
31; Modified: [CurIO_UseExtension]
32DriveIO_CheckFor13extensions Proc Near Uses ax bx cx dx
33 mov ah, 41h
34 mov bx, 55AAh
35 mov dl, [BIOS_BootDisk] ; We check using the boot-disk
36 int 13h
37
38IFDEF AUX_DEBUG
39 IF 0
40 DBG_TEXT_OUT_AUX 'DriveIO_CheckFor13extensions:'
41 PUSHRF
42 call DEBUG_DumpRegisters
43 ;~ call AuxIO_DumpParagraph
44 ;~ call AuxIO_TeletypeNL
45 mov si, offset [Scratch]
46 mov word ptr [si], 50h
47 mov ah, 48h
48 int 13h
49 call DEBUG_DumpRegisters
50 ;~ call AuxIO_DumpSector
51 POPRF
52 ENDIF
53ENDIF
54
55 jc PCCF13E_NotFound ; Error occured
56 cmp bx, 0AA55h
57 je PCCF13E_Found
58 PCCF13E_NotFound:
59 ret
60 PCCF13E_Found:
61 and cx, 1 ; Check 42h-44h,47h,48h supported
62 jz PCCF13E_NotFound ; Sig OK but no support, strange beast
63 mov byte ptr [CurIO_UseExtension], 1
64 ret
65DriveIO_CheckFor13extensions EndP
66
67
68; Note: Some routines set DS/ES to CS or even address via CS, even if its not
69; needed. This was done for SECURITY. So DO NOT remove it.
70; Its there to make sure the correct data is loaded/written to/from
71; harddrive.
72;
73; IF YOU MODIFY ANYTHING IN HERE, YOU MAY EASILY BREAK YOUR HARDDRIVE!
74
75; Will only load base-configuration, will NOT load IPT nor Hide-Config
76; Those are originally loaded on startup and will NOT get reloaded.
77DriveIO_LoadConfiguration Proc Near Uses ax bx cx dx es
78
79IFDEF AUX_DEBUG
80 IF 0
81 DBG_TEXT_OUT_AUX 'DriveIO_LoadConfiguration:'
82 PUSHRF
83 ;~ call DEBUG_DumpRegisters
84 ;~ call AuxIO_DumpParagraph
85 ;~ call AuxIO_TeletypeNL
86 POPRF
87 ENDIF
88ENDIF
89
90;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
91 mov ax, cs
92 mov es, ax
93 mov bx, offset Configuration
94 xor dh, dh
95 mov dl, [BIOS_BootDisk] ; Disk we booted from
96 mov cx, 0037h ; Sector 55 (CHS)
97 mov ax, 0201h ; Function 02, read 1 sector...
98 int 13h
99 jnc DIOLC_NoError
100 call MBR_LoadError ; Will Abort BootUp
101
102
103 DIOLC_NoError:
104 ret
105DriveIO_LoadConfiguration EndP
106
107DriveIO_SaveConfiguration Proc Near Uses ax bx cx dx ds es si
108
109IFDEF AUX_DEBUG
110 IF 0
111 DBG_TEXT_OUT_AUX 'DriveIO_SaveConfiguration:'
112 PUSHRF
113 call DEBUG_DumpRegisters
114 ;~ call AuxIO_DumpParagraph
115 ;~ call AuxIO_TeletypeNL
116 POPRF
117 ENDIF
118ENDIF
119
120 mov ax, cs
121 mov ds, ax
122 mov es, ax ; Safety first (CS==DS==ES)
123 ; --- Overwrite Floppy-Name with "FloppyDrive"
124 mov si, offset TXT_Floppy_Drive
125 mov di, offset PartitionTable
126 sub di, 30 ; Adjust to Floppy-Name
127 mov cx, 11
128 rep movsb
129 mov si, offset Configuration ; Calculate new checksum
130 xor bx, bx
131
132 ; Changed from 5 to calculated value (not here, see compat. issue below)
133 ; Fixes issue: #2987 -- "air-boot doesn't remember drive letter"
134 ; Size of the ab-configuration in 512 byte sectors
135 ;mov cx, (MBR_BackUpMBR - Configuration) / 200h
136
137 ; AB v1.07 stores a 5 sector configuration with a 5 sector checksum.
138 ; AB v1.0.8+ *should* stores a 7 sector configuration with a
139 ; 7 sector checksum.
140 ; Because 5 was hardcoded here, SET(A)BOOT v1.07 will see see an AB v1.0.8+
141 ; config as corrupted, while this is not the case.
142 ; So, for compatibility reasons, in v1.0.8+, the checksum stored is over
143 ; 5 sectors, to be compatible with v1.07.
144 ; This may change (be corrected) in future versions !
145 mov cx,5
146
147 mov dx, [CFG_CheckConfig]
148 mov [CFG_CheckConfig], bx
149 DIOSC_Loop:
150 call MBR_GetCheckOfSector
151 loop DIOSC_Loop
152 mov [CFG_CheckConfig], bx
153 ; --------------------------------------------------------------------
154 ; ES == CS
155 mov bx, offset Configuration
156 xor dh, dh
157 mov dl, [BIOS_BootDisk] ; Disk we booted from
158 mov cx, 0037h ; Sector 55 (CHS)
159
160 ; Changed from 5 to calculated value
161 ; Fixes issue: #2987 -- "air-boot doesn't remember drive letter"
162 ; Size of the ab-configuration in 512 byte sectors
163 mov al, (MBR_BackUpMBR - Configuration) / 200h
164 mov ah,03h
165;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
166 int 13h
167 jnc DIOSC_NoError
168 call MBR_SaveError ; Will Abort BootUp
169 DIOSC_NoError:
170 ret
171DriveIO_SaveConfiguration EndP
172
173DriveIO_UpdateFloppyName Proc Near Uses bx cx dx ds si es di
174 mov ax, cs
175 mov ds, ax
176 mov es, ax
177
178 mov ah, 00h ; Function 0 - Reset Drive
179 xor dl, dl
180 int 13h
181 xor dx, dx ; Cylinder=0, Head=0
182 mov cx, 1 ; Sector=1, Drive=0
183 mov bx, offset TmpSector ; ES:BX - TmpSector
184 mov ax, 0201h ; Function 2 - Load Sector
185 int 13h
186 jnc DIOUFN_AllFine
187
188 ; --- Overwrite Floppy-Name with "No Disc"
189 mov si, offset TXT_Floppy_NoDisc
190 xor ax, ax
191 DIOUFN_WriteFloppyName:
192 mov di, offset PartitionTable
193 sub di, 30 ; Adjust to Floppy-Name
194 mov cl, 11
195 rep movsb
196 ret ; AX=-1 -> GotDisc, =0 -> NoDisc
197
198 ; --- Floppy found and read, data in TempSector
199 DIOUFN_AllFine:
200 mov ax, -1
201 mov si, offset TXT_Floppy_NoName
202 cmp wptr es:[bx+54], 'AF'
203 jne DIOUFN_WriteFloppyName
204 cmp wptr es:[bx+56], '1T'
205 jne DIOUFN_WriteFloppyName
206 cmp bptr es:[bx+58], '2'
207 jne DIOUFN_WriteFloppyName
208 mov si, bx
209 add si, 43 ; FAT12 - Volume Label Location
210 jmp DIOUFN_WriteFloppyName
211DriveIO_UpdateFloppyName EndP
212
213; =============================================================================
214; HARDDRIVE / GENERAL ACCESS
215; =============================================================================
216; The following routines are used for harddisc/floppy access.
217; The access is done via INT 13h/CHS or INT 13h/LBA.
218; Access will be done prefered by INT 13h/CHS, because it's (I wonder!) much
219; faster, than the LBA-method. I don't know, why LBA is so slow. Perhaps BIOS.
220;
221; Internal access (to AiR-BOOT) is always done via INT 13h/CHS.
222
223DriveIO_GetHardDriveCount Proc Near Uses ds si
224 push ds
225 push si
226 push 0040h
227 pop ds
228 mov si, 0075h
229 mov dh, ds:[si] ; 40:75 -> POST: Total Harddiscs == DH
230 pop si
231 pop ds
232 mov [TotalHarddiscs], dh
233 ret
234DriveIO_GetHardDriveCount EndP
235
236
237; Fills our LBA-Usage table. It holds the LBA-address, where BIOS/CHS access is
238; stopped and BIOS/LBA access is started.
239; This is calculated by Sector*Heads. Comparing will get done with Bit 25-10
240; on LBA sectors, so we actually divide sector number by 1024.
241DriveIO_InitLBASwitchTable Proc Near Uses es di
242 mov di, offset LBASwitchTable
243 mov dh, [TotalHarddiscs]
244 mov dl, 80h ; First disk to process
245 DIOILUT_DriveLoop:
246 push dx
247 push di
248 mov ah, 08h
249 int 13h ; DISK - GET DRIVE PARAMETERS
250 mov ah, 0FBh ; Assume 255 heads/63 sectors, if error
251 jc DIOILUT_Error
252 and cl, 111111b ; Isolate lower 6 bits of CL -> sector count
253;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
254 ;movzx ax, cl
255 mov al,cl
256 mov ah,0
257
258 mov bl, dh ; DH -> max head number
259 mul bl ; AX = Sectors*Heads
260 shl ah, 1
261 shl ah, 1 ; Shift 2 bits, so we are able to compare to
262 ; bit 16-23 of the LBA address
263 DIOILUT_Error:
264 pop di
265 pop dx
266 mov bptr ds:[di], ah ; Save that value
267 inc di ; Go to next BYTE
268 inc dl ; Next disk
269 dec dh ; Decrease disks to process
270 jnz DIOILUT_DriveLoop ; Next disk if DH != 0
271 ret
272DriveIO_InitLBASwitchTable EndP
273
274; #########################################################################
275; Routine: Loads partition to ExecBase and checks for validity
276; #########################################################################
277; Calling : bx:ax - Absolute sector
278; cx:dx - Cylinder/Sector, Side/Drive (hi/lo-byte)
279; Returns : Carry Set if invalid partition encountered
280; Preserve: all registers
281; #########################################################################
282DriveIO_LoadPartition Proc Near Uses si
283
284IFDEF AUX_DEBUG
285 IF 0
286 DBG_TEXT_OUT_AUX 'DriveIO_LoadPartition:'
287 PUSHRF
288 call DEBUG_DumpRegisters
289 ;~ call AuxIO_DumpParagraph
290 ;~ call AuxIO_TeletypeNL
291 POPRF
292 ENDIF
293ENDIF
294
295 mov wptr cs:[CurPartition_Location+0], ax
296 mov wptr cs:[CurPartition_Location+2], bx
297 mov wptr cs:[CurPartition_Location+4], dx
298 mov wptr cs:[CurPartition_Location+6], cx ; Saves the location
299 mov si, offset [PartitionSector] ; DS:SI - ExecBase
300
301
302;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
303 call DriveIO_LoadSector
304
305 clc
306 cmp wptr [si+LocBR_Magic], 0AA55h
307 je DIOLP_Success
308 ; We check, if we are scanning partitions. In that case, if CHS is not 0/0/1
309 ; we will display a "bad partition table" message and halt the system.
310 cmp cx, 0001h
311 jne DIOLP_Failed
312 or dh, dh
313 jnz DIOLP_Failed
314 stc ; Set carry, so no partition table
315 DIOLP_Success:
316
317
318
319 ret
320 DIOLP_Failed:
321 jmp DriveIO_GotLoadError
322DriveIO_LoadPartition EndP
323
324; #########################################################################
325; Routine: Writes a partition from ExecBase to its original sector
326; #########################################################################
327; Calling : none
328; Returns : none
329; Preserve: all registers
330; #########################################################################
331DriveIO_SavePartition Proc Near Uses ax bx cx dx si
332
333IFDEF AUX_DEBUG
334 IF 0
335 DBG_TEXT_OUT_AUX 'DriveIO_SavePartition:'
336 PUSHRF
337 call DEBUG_DumpRegisters
338 ;~ call AuxIO_DumpParagraph
339 ;~ call AuxIO_TeletypeNL
340 POPRF
341 ENDIF
342ENDIF
343
344 mov ax, wptr cs:[CurPartition_Location+0]
345 mov bx, wptr cs:[CurPartition_Location+2]
346 mov dx, wptr cs:[CurPartition_Location+4]
347 mov cx, wptr cs:[CurPartition_Location+6] ; Gets prev. saved location
348 mov si, offset PartitionSector ; DS:SI - ExecBase
349 cmp wptr [si+LocBR_Magic], 0AA55h ; Checks for signature, if not found
350 jne DIOSP_SevereError ; we assume a really bad error
351 call DriveIO_SaveSector
352 DIOSP_SevereError:
353 ret
354DriveIO_SavePartition EndP
355
356
357
358;##############################################################################
359;# The location of LVM sectors depends on the OS/2 geometry used when the disk
360;# was prepared. This geometry is present in the Master LVM sector, which has
361;# already been located if it exists. All partitions, whether primary or
362;# logical, have an entry in a partition table. For primary partitions this
363;# table is located in the MBR, while for logical partitions this table is
364;# located in the EBR for that logical partition. An LVM record is located
365;# LVM_SPT-1 sectors above an MBR or EBR. The Master LVM record contains the
366;# information for all primary partitions. For logical partitions, the LVM
367;# sector only has one entry, because EBRs are chained. The global LVM info,
368;# like disk-name, sectors per track, etc. is replicated between the Master
369;# LVM sector and LVM sectors corresponding to logical partitions. This info
370;# is kept in sync by the OS/2 LVM Engine.
371;##############################################################################
372;# ACTION : Attempts to load the corresponding LVM sector for a partition
373;# ----------------------------------------------------------------------------
374;# EFFECTS : Modifies DAP structure and fills or clears sector buffer
375;# ----------------------------------------------------------------------------
376;# IN : MEM - Location info is in [CurPartition_Location]
377;# ----------------------------------------------------------------------------
378;# OUT : CF=1 - failure, no valid LVM sector was loaded
379;# : SI - Points to the sector buffer ([LVMSector])
380;##############################################################################
381DriveIO_LoadLVMSector Proc Near Uses ax bx cx dx di
382
383IFDEF AUX_DEBUG
384 IF 0
385 DBG_TEXT_OUT_AUX 'DriveIO_LoadLVMSector:'
386 PUSHRF
387 call DEBUG_DumpRegisters
388 ;~ call AuxIO_DumpSector
389 ;~ call AuxIO_DumpParagraph
390 ;~ call AuxIO_TeletypeNL
391 POPRF
392 ENDIF
393ENDIF
394
395 ; Clear the sector buffer
396 mov si, offset [LVMSector]
397 call ClearSectorBuffer
398
399 ; Quit with CY if LVM is ignored in SETUP
400 test byte ptr [CFG_IgnoreLVM], 1 ; ZF=0 means ignore LVM
401 jnz DIOLLVMS_NoLVMSector ; Quit if so
402
403 ; Load the location of the current partition being acted upon.
404 ; Note that this is not the actual LBA of the partition, but the
405 ; sector that has the partition table that contains the entry
406 ; for the partition. In other words, for primary partitions the LBA
407 ; address points to the MBR while for extended partitions it points
408 ; to an EBR. In both cases the LVM sector is located LVM_SPT-1 above.
409 ; Also note that the BIOS CHS values (DH and CX) below are not used,
410 ; because we explicitly use LBA sector loading.
411 mov ax, wptr cs:[CurPartition_Location+0] ; LBA lo of MBR/EBR
412 mov bx, wptr cs:[CurPartition_Location+2] ; LBA hi of MBR/EBR
413 mov dx, wptr cs:[CurPartition_Location+4] ; BIOS disk num & head
414 mov cx, wptr cs:[CurPartition_Location+6] ; BIOS cyl & sec
415
416 ; Do the actual loading.
417 ; This is in a separate function so that LVM records can also be
418 ; loaded using the MBR/EBR LBA addresses from IPT entries.
419 call DriveIO_LoadLVMSectorXBR
420 jc DIOLLVMS_NoLVMSector
421
422 ; We're done, indicate success and return
423 clc
424 jmp DIOLLVMS_Done
425
426 DIOLLVMS_NoLVMSector:
427
428 ; Clear the sector buffer
429 mov si, offset [LVMSector]
430 call ClearSectorBuffer
431 mov bptr [si+LocLVM_SignatureStart], 0
432
433 ; Indicate no valid LVM sector was loaded
434 stc
435
436 DIOLLVMS_Done:
437
438 ret
439DriveIO_LoadLVMSector EndP
440
441
442
443
444
445;------------------------------------------------------------------------------
446; Attempts to load the corresponding LVM sector for a partition
447;------------------------------------------------------------------------------
448; IN : AX - LBA lo of MBR or EBR
449; : BX - LBA hi of MBR or EBR
450; ; DL - BIOS disk number
451; ; SI - Pointer to sector buffer (usually [LVMSec])
452; OUT : CF=0 - A valid LVM sector was loaded
453; NOTE : LocIPT_AbsolutePartTable and LocIPT_Drive can provide LBA and DISK
454;------------------------------------------------------------------------------
455DriveIO_LoadLVMSectorXBR Proc Near
456
457IFDEF AUX_DEBUG
458 IF 0
459 DBG_TEXT_OUT_AUX 'DriveIO_LoadLVMSectorXBR:'
460 PUSHRF
461 call DEBUG_DumpRegisters
462 ;~ call AuxIO_DumpSector
463 ;~ call AuxIO_DumpParagraph
464 ;~ call AuxIO_TeletypeNL
465 POPRF
466 ENDIF
467ENDIF
468
469 ; Save all registers
470 pusha
471
472 ; Calculate the entry in the DISKINFO array for this disk,
473 ; and put the LVM_SPT in DI
474 push bx
475 call DriveIO_CalcDiskInfoPointer
476 mov di, [bx+LocDISKINFO_LVM_Secs]
477 pop bx
478
479 ; If the LVM_SPT is ZERO, no LVM info is present and we quit with CY
480 test di, di ; See if it is 0
481 jz DriveIO_LoadLVMSectorXBR_no_lvm ; Quit if so
482
483 ; Adjust the location to point to the LVM sector
484 add ax, di ; Add the LVM sectors-per-track
485 adc bx, 0 ; Propagate LBA lo overflow to LBA hi
486 sub ax, 1 ; LVM sector is located one sector below
487 sbb bx, 0 ; Propagate borrow to LBA hi
488
489 ; Load the LVM sector into sector buffer pointed to by SI
490 mov di, ds ; Segment of that buffer
491 call DriveIO_ReadSectorLBA ; Read the LVM sector
492
493IFDEF AUX_DEBUG
494 IF 0
495 DBG_TEXT_OUT_AUX 'LVMSecLoaded'
496 PUSHRF
497 call DEBUG_DumpRegisters
498 ;~ call AuxIO_DumpSector
499 mov cx, 3
500 @@:
501 call AuxIO_DumpParagraph
502 call AuxIO_TeletypeNL
503 add si, 16
504 loop @B
505 ;~ call AuxIO_DumpParagraph
506 ;~ call AuxIO_TeletypeNL
507 POPRF
508 ENDIF
509ENDIF
510
511 jc DriveIO_LoadLVMSectorXBR_no_lvm ; Quit on error
512
513 ; Check the validity of the LVM sector, quit with CY if invalid
514 call LVM_ValidateSector ; Check signature and CRC
515 jnc DriveIO_LoadLVMSectorXBR_no_lvm ; Quit if not valid
516
517 ; We're done, indicate success and return
518 clc
519 jmp DriveIO_LoadLVMSectorXBR_done
520
521 DriveIO_LoadLVMSectorXBR_no_lvm:
522 ; Indicate no valid LVM sector was loaded
523 stc
524
525 DriveIO_LoadLVMSectorXBR_done:
526 ; Restore all registers
527 popa
528
529 ret
530DriveIO_LoadLVMSectorXBR EndP
531
532
533;##############################################################################
534;# The location of LVM sectors depends on the OS/2 geometry used when the disk
535;# was prepared. This geometry is present in the Master LVM sector, which has
536;# already been located if it exists. All partitions, whether primary or
537;# logical, have an entry in a partition table. For primary partitions this
538;# table is located in the MBR, while for logical partitions this table is
539;# located in the EBR for that logical partition. An LVM record is located
540;# LVM_SPT-1 sectors above an MBR or EBR. The Master LVM record contains the
541;# information for all primary partitions. For logical partitions, the LVM
542;# sector only has one entry, because EBRs are chained. The global LVM info,
543;# like disk-name, sectors per track, etc. is replicated between the Master
544;# LVM sector and LVM sectors corresponding to logical partitions. This info
545;# is kept in sync by the OS/2 LVM Engine.
546;##############################################################################
547;# ACTION : Attempts to save the corresponding LVM sector for a partition
548;# ----------------------------------------------------------------------------
549;# EFFECTS : Modifies DAP structure and writes LVM sector to disk
550;# ----------------------------------------------------------------------------
551;# IN : MEM - Location info is in [CurPartition_Location]
552;# : SI - Pointer to sector buffer
553;# ----------------------------------------------------------------------------
554;# OUT : CF=1 - failure, no valid LVM sector was saved
555;##############################################################################
556DriveIO_SaveLVMSector Proc Near Uses ax bx cx dx di
557
558IFDEF AUX_DEBUG
559 IF 0
560 DBG_TEXT_OUT_AUX 'DriveIO_SaveLVMSector:'
561 PUSHRF
562 call DEBUG_DumpRegisters
563 ;~ call AuxIO_DumpParagraph
564 ;~ call AuxIO_TeletypeNL
565 POPRF
566 ENDIF
567ENDIF
568
569 ; Quit with CY if LVM is ignored in SETUP
570 test byte ptr [CFG_IgnoreLVM], 1 ; ZF=0 means ignore LVM
571 jnz DIOSLVMS_NoLVMSector ; Quit if so
572
573 ; Load the location of the current partition being acted upon.
574 ; Note that this is not the actual LBA of the partition, but the
575 ; sector that has the partition table that contains the entry
576 ; for the partition. In other words, for primary partitions the LBA
577 ; address points to the MBR while for extended partitions it points
578 ; to an EBR. In both cases the LVM sector is located LVM_SPT-1 above.
579 ; Also note that the BIOS CHS values (DH and CX) below are not used,
580 ; because we explicitly use LBA sector loading.
581 mov ax, wptr cs:[CurPartition_Location+0] ; LBA lo of MBR/EBR
582 mov bx, wptr cs:[CurPartition_Location+2] ; LBA hi of MBR/EBR
583 mov dx, wptr cs:[CurPartition_Location+4] ; BIOS disk num & head
584 mov cx, wptr cs:[CurPartition_Location+6] ; BIOS cyl & sec
585
586 ; Do the actual saving.
587 ; This is in a separate function so that LVM records can also be
588 ; saved using the MBR/EBR LBA addresses from IPT entries.
589 call DriveIO_SaveLVMSectorXBR
590 jc DIOSLVMS_NoLVMSector
591
592 ; We're done, indicate success and return
593 clc
594 jmp DIOSLVMS_Done
595
596 DIOSLVMS_NoLVMSector:
597 ; Indicate no valid LVM sector was saved
598 stc
599
600 DIOSLVMS_Done:
601 ret
602DriveIO_SaveLVMSector EndP
603
604
605;------------------------------------------------------------------------------
606; Attempts to save the corresponding LVM sector for a partition
607;------------------------------------------------------------------------------
608; IN : AX - LBA lo of MBR or EBR
609; : BX - LBA hi of MBR or EBR
610; ; DL - BIOS disk number
611; ; SI - Pointer to sector buffer (usually [LVMSec])
612; OUT : CF=0 - A valid LVM sector was saved
613; NOTE : LocIPT_AbsolutePartTable and LocIPT_Drive can provide LBA and DISK
614;------------------------------------------------------------------------------
615DriveIO_SaveLVMSectorXBR Proc Near
616
617IFDEF AUX_DEBUG
618 IF 0
619 DBG_TEXT_OUT_AUX 'DriveIO_SaveLVMSectorXBR:'
620 PUSHRF
621 call DEBUG_DumpRegisters
622 ;~ call AuxIO_DumpSector
623 ;~ call AuxIO_DumpParagraph
624 ;~ call AuxIO_TeletypeNL
625 POPRF
626 ENDIF
627ENDIF
628
629 ; Save all registers
630 pusha
631
632 ; Check the validity of the LVM sector, quit with CY if invalid
633 push ax ; Save LBA lo
634 call LVM_ValidateSector ; Check signature and CRC
635 pop ax ; Restore LBA lo
636 jnc DriveIO_SaveLVMSectorXBR_no_lvm ; Quit if not valid
637
638 ; Calculate the entry in the DISKINFO array for this disk,
639 ; and put the LVM_SPT in DI
640 push bx
641 call DriveIO_CalcDiskInfoPointer
642 mov di, [bx+LocDISKINFO_LVM_Secs]
643 pop bx
644
645 ; If the LVM_SPT is ZERO, no LVM info is present and we quit with CY
646 test di, di ; See if it is 0
647 jz DriveIO_SaveLVMSectorXBR_no_lvm ; Quit if so
648
649 ; Adjust the location to point to the LVM sector
650 add ax, di ; Add the LVM sectors-per-track
651 adc bx, 0 ; Propagate LBA lo overflow to LBA hi
652 sub ax, 1 ; LVM sector is located one sector below
653 sbb bx, 0 ; Propagate borrow to LBA hi
654
655 ; Save the LVM sector pointed to by SI
656 mov di, ds ; Segment of that buffer
657 call DriveIO_WriteSectorLBA ; Read the LVM sector
658
659IFDEF AUX_DEBUG
660 IF 0
661 DBG_TEXT_OUT_AUX 'LVMSecSaved'
662 PUSHRF
663 call DEBUG_DumpRegisters
664 call AuxIO_DumpSector
665 ;~ call AuxIO_DumpParagraph
666 ;~ call AuxIO_TeletypeNL
667 POPRF
668 ENDIF
669ENDIF
670
671 jc DriveIO_SaveLVMSectorXBR_no_lvm ; Quit on error
672
673 ; We're done, indicate success and return
674 clc
675 jmp DriveIO_SaveLVMSectorXBR_done
676
677 DriveIO_SaveLVMSectorXBR_no_lvm:
678 ; Indicate no valid LVM sector was loaded
679 stc
680
681 DriveIO_SaveLVMSectorXBR_done:
682 ; Restore all registers
683 popa
684
685 ret
686DriveIO_SaveLVMSectorXBR EndP
687
688
689
690; Special error message instead of "LOAD ERROR" during partition scanning,
691; so users will notice that something is bad with their partition table(s)
692DriveIO_GotLoadError Proc Near
693 test byte ptr cs:[CurIO_Scanning], 1 ; Must be CS:, cause DS!=CS maybe here
694 jnz InScanMode
695 jmp MBR_LoadError
696 InScanMode:
697 mov si, offset TXT_BrokenPartitionTable
698 push cs
699 pop ds
700 call MBR_Teletype
701 mov si, offset BrokenHDD
702 sub dl, 50h ; 80h -> '0'
703 cmp dl, 39h
704 jbe DIOGLE_BelowA
705 add dl, 7 ; 3Ah -> 'A'
706 DIOGLE_BelowA:
707 mov bptr [si+5], dl
708 call MBR_Teletype
709
710 ; JWasm: cannot jump to local label in other procedure.
711 ; Changed to halt here.
712 ;jmp MBRLE_Halt
713 DriveIO_GotLoadError_halt:
714 jmp DriveIO_GotLoadError_halt
715DriveIO_GotLoadError EndP
716
717; #########################################################################
718; Routine: Loads a specified sector to DS:DI
719; #########################################################################
720; Calling : bx:ax - Absolute sector
721; cx:dx - Cylinder/Sector, Side/Drive (hi/lo-byte)
722; ds:si - Destination-Adress
723; Returns : none
724; Preserve: all registers
725; #########################################################################
726DriveIO_LoadSector Proc Near Uses ax bx cx dx ds si es di
727
728IFDEF AUX_DEBUG
729 IF 0
730 DBG_TEXT_OUT_AUX 'DriveIO_LoadSector:'
731 PUSHRF
732 call DEBUG_DumpRegisters
733 ;~ call AuxIO_DumpParagraph
734 ;~ call AuxIO_TeletypeNL
735 POPRF
736 ENDIF
737ENDIF
738
739 ; Is the drive not a harddrive?
740 cmp dl, 80h
741 jb DIOLS_UseNormal
742
743 test byte ptr cs:[CurIO_UseExtension], 1
744 jz DIOLS_UseNormal
745 ; Are we forced do use LBA via Setting?
746 jnz DIOLS_UseExtension
747
748 ; Upper 8 bits of LBA-address set?
749 ; Then use LBA (maximum boundary is 16320x16x63 = FB0400h)
750 or bh, bh
751 jnz DIOLS_UseExtension
752 ; Compare Switch-Table value to bit 16-23 of LBA-address
753 mov di, dx
754 and di, 007Fh
755 cmp bptr cs:[LBASwitchTable+di], bl
756 jbe DIOLS_UseExtension
757
758 DIOLS_UseNormal:
759
760IFDEF AUX_DEBUG
761 IF 0
762 DBG_TEXT_OUT_AUX 'DriveIO_ReadSectorCHS:'
763 PUSHRF
764 call DEBUG_DumpRegisters
765 call AuxIO_DumpParagraph
766 call AuxIO_TeletypeNL
767 POPRF
768 ENDIF
769ENDIF
770
771 mov di, 3 ; retry count
772 DIOLS_ErrorLoop:
773 push ds
774 pop es
775 mov bx, si ; ES:BX - Destination
776 mov ax, 0201h ; Function 2 - Load Sector
777 int 13h
778 jnc DIOLS_Success
779 dec di ; decrement retry count
780 jnz DIOLS_ErrorLoop
781
782 ; Sector load failed...
783 jmp DriveIO_GotLoadError
784
785 DIOLS_UseExtension:
786
787 mov di, ds ; segment for transfer address
788 call DriveIO_ReadSectorLBA ; extended read
789 jc DriveIO_GotLoadError ; halt on error
790
791 ;~ push cx
792 ;~ mov cs:[INT13X_DAP_NumBlocks], 1 ; Copy ONE sector
793 ;~ mov wptr cs:[INT13X_DAP_Transfer+0], si
794 ;~ mov cx, ds
795 ;~ mov wptr cs:[INT13X_DAP_Transfer+2], cx ; Fill out Transfer Adress
796 ;~ mov wptr cs:[INT13X_DAP_Absolute+0], ax
797 ;~ mov wptr cs:[INT13X_DAP_Absolute+2], bx ; Fill out Absolute Sector
798 ;~ push cs
799 ;~ pop ds
800 ;~ mov si, offset [INT13X_DAP]
801 ;~ mov ah, 42h ; Extended Read
802 ;~ int 13h
803 ;~ pop cx
804 ;~ jnc DIOLS_Success
805
806 ; Sector load failed...
807 ;~ jmp DriveIO_GotLoadError
808
809 DIOLS_Success:
810
811IFDEF AUX_DEBUG
812 IF 0
813 DBG_TEXT_OUT_AUX 'sector loaded'
814 PUSHRF
815 ;~ call DEBUG_DumpRegisters
816 ;~ call AuxIO_DumpSector
817 mov cx, 32
818 @@:
819 call AuxIO_DumpParagraph
820 call AuxIO_TeletypeNL
821 add si, 16
822 loop @B
823 POPRF
824 ENDIF
825ENDIF
826 ret
827DriveIO_LoadSector EndP
828
829
830;##############################################################################
831;# ACTION : Loads the Master Boot Record from the specified drive into buffer
832;# ----------------------------------------------------------------------------
833;# EFFECTS : Modifies DAP structure and fills or clears transfer buffer
834;# ----------------------------------------------------------------------------
835;# IN : DL - BIOS disk number (80h,81h,etc)
836;# : SI - Pointer to transfer buffer
837;# ----------------------------------------------------------------------------
838;# OUT : CF=1 - failure
839;# : AL.0 - MBR signature present
840;# : AL.1 - Primary partitions present
841;# : AL.2 - Extended partitions present
842;# : AL.3 - AiR-BOOT signature present
843;# : AL.4:7 - Reserved, returned as 0
844;# : AH.0:7 - Reserved, returned as 0
845;##############################################################################
846DriveIO_LoadMBR Proc Near uses bx cx dx si di
847
848 ; Always clear the transfer buffer first
849 call ClearSectorBuffer
850
851 ; Assume an invalid MBR
852 xor ax, ax
853
854 ; Accept only valid harddisks
855 call DriveIO_IsValidHarddisk
856 jc DriveIO_LoadMBR_exit
857
858 ; Save the address of the transfer buffer
859 mov di, si
860
861 ; Read the MBR from disk
862 xor ax, ax ; LBA low
863 xor bx, bx ; LBA high
864 xor dh, dh ; Head 0
865 mov cx, 1 ; Sector 1
866 call DriveIO_LoadSector ; Read the sector from disk
867
868 ; Check the loaded MBR for a signature
869 xor ax, ax ; Assume an invalid MBR
870 mov dx, [si+LocBR_Magic] ; Get word from MBR signature location
871 cmp dx, 0aa55h ; Is it the magic value ?
872 jne DriveIO_LoadMBR_exit ; Nope, no need to test anything else
873
874 ; Indicate we have a MBR signature
875 or al, 01h
876
877 ; Advance to the partition table
878 add si, 01beh
879
880 ; Total of 4 entries to check
881 mov cx, 4
882
883 DriveIO_LoadMBR_next_entry:
884 mov dl, [si+LocBRPT_SystemID] ; Get partition-type / system-id
885 add si, 10h ; Point to next entry
886 test dl, dl ; Nothing in this one ?
887 loopz DriveIO_LoadMBR_next_entry ; Then check next entry
888
889 ; All entries checked and last one was also empty, we're done
890 jz DriveIO_LoadMBR_check_ab
891
892 ; Found a non-empty entry, set bits according to its type
893 cmp dl, 05h ; Old style extended container ?
894 jne @F ; Nope...
895 or al, 04h ; Yep, mark ext. container present
896 @@: cmp dl, 0fh ; New style extended container ?
897 jne @F ; Nope...
898 or al, 04h ; Yep, mark ext. container present
899 @@: or al, 02h ; Then is must be a primary
900 jcxz DriveIO_LoadMBR_check_ab ; CX=0? Then all entries processed,
901 jmp DriveIO_LoadMBR_next_entry ; otherwise check next entry
902
903 ; Check if an AiR-BOOT signature is present
904 DriveIO_LoadMBR_check_ab:
905 mov si, offset [MBR_ABSig] ; Offset of AiR-BOOT signature
906 inc di ; Advance buffer pointer
907 inc di ; to AiR-BOOT signature location
908 mov cx, 7 ; Length of AiR-BOOT signature
909 cld ; Direction upwards
910 repe cmpsb ; Compare 7 bytes
911 jne DriveIO_LoadMBR_exit ; Nope, no AiR-BOOT on this disk
912 or al, 08h ; Yep, AiR-BOOT is on this disk
913 ;~ jmp DriveIO_LoadMBR_exit
914
915 DriveIO_LoadMBR_exit:
916 ret
917DriveIO_LoadMBR EndP
918
919
920;##############################################################################
921;# ACTION : Reads a sector from disk using INT13 extensions
922;# ----------------------------------------------------------------------------
923;# EFFECTS : Modifies DAP structure and fills transfer buffer
924;# ----------------------------------------------------------------------------
925;# IN : BX:AX - LBA address of sector
926;# : DI:SI - SEG:OFF of transfer buffer
927;# ----------------------------------------------------------------------------
928;# OUT : CF=1 - failure
929;##############################################################################
930DriveIO_ReadSectorLBA Proc Near
931
932IFDEF AUX_DEBUG
933 IF 0
934 DBG_TEXT_OUT_AUX 'DriveIO_ReadSectorLBA:'
935 PUSHRF
936 call DEBUG_DumpRegisters
937 call AuxIO_DumpParagraph
938 call AuxIO_TeletypeNL
939 POPRF
940 ENDIF
941ENDIF
942
943 ; Push all registers
944 pusha
945 push ds
946 push es
947
948 ; One sector to read
949 mov cs:[INT13X_DAP_NumBlocks], 1
950
951 ; Setup transfer address
952 mov wptr cs:[INT13X_DAP_Transfer+0], si ; offset
953 mov wptr cs:[INT13X_DAP_Transfer+2], di ; segment
954
955 ; Setup LBA64 address of requested sector
956 mov wptr cs:[INT13X_DAP_Absolute+0], ax ; low word lower part
957 mov wptr cs:[INT13X_DAP_Absolute+2], bx ; high word lower part
958 mov wptr cs:[INT13X_DAP_Absolute+4], 0 ; low word upper part
959 mov wptr cs:[INT13X_DAP_Absolute+6], 0 ; high word upper part
960
961 ; Address of packet
962 mov si, offset [INT13X_DAP] ; disk address packet
963
964 ; Do the extended read
965 mov ah, 42h ; read function
966 int 13h ; transfer to bios
967
968 ; Error occured
969 jc DriveIO_ReadSectorLBA_exit
970
971 ; AH should also be zero
972 test ah, ah
973 stc
974 jnz DriveIO_ReadSectorLBA_exit
975
976 ; Disk read succeeded, clear CF
977 clc
978
979 DriveIO_ReadSectorLBA_exit:
980
981 ; Pop all registers
982 pop es
983 pop ds
984 popa
985
986 ret
987DriveIO_ReadSectorLBA EndP
988
989
990
991;##############################################################################
992;# ACTION : Writes a sector to disk using INT13 extensions
993;# ----------------------------------------------------------------------------
994;# EFFECTS : Modifies DAP structure and mofifies the disk
995;# ----------------------------------------------------------------------------
996;# IN : BX:AX - LBA address of sector
997;# : DI:SI - SEG:OFF of transfer buffer
998;# ----------------------------------------------------------------------------
999;# OUT : CF=1 - failure
1000;##############################################################################
1001DriveIO_WriteSectorLBA Proc Near
1002
1003IFDEF AUX_DEBUG
1004 IF 0
1005 DBG_TEXT_OUT_AUX 'DriveIO_WriteSectorLBA:'
1006 PUSHRF
1007 call DEBUG_DumpRegisters
1008 call AuxIO_DumpParagraph
1009 call AuxIO_TeletypeNL
1010 POPRF
1011 ENDIF
1012ENDIF
1013
1014 ; Push all registers
1015 pusha
1016 push ds
1017 push es
1018
1019 ; One sector to read
1020 mov cs:[INT13X_DAP_NumBlocks], 1
1021
1022 ; Setup transfer address
1023 mov wptr cs:[INT13X_DAP_Transfer+0], si ; offset
1024 mov wptr cs:[INT13X_DAP_Transfer+2], di ; segment
1025
1026 ; Setup LBA64 address of requested sector
1027 mov wptr cs:[INT13X_DAP_Absolute+0], ax ; low word lower part
1028 mov wptr cs:[INT13X_DAP_Absolute+2], bx ; high word lower part
1029 mov wptr cs:[INT13X_DAP_Absolute+4], 0 ; low word upper part
1030 mov wptr cs:[INT13X_DAP_Absolute+6], 0 ; high word upper part
1031
1032 ; Address of packet
1033 mov si, offset [INT13X_DAP] ; disk address packet
1034
1035 ; Do the extended write
1036 xor al, al ; no write verify
1037 mov ah, 43h ; write function
1038 int 13h ; transfer to bios
1039
1040 ; Error occured
1041 jc DriveIO_WriteSectorLBA_exit
1042
1043 ; AH should also be zero
1044 test ah, ah
1045 stc
1046 jnz DriveIO_WriteSectorLBA_exit
1047
1048 ; Disk write succeeded, clear CF
1049 clc
1050
1051 DriveIO_WriteSectorLBA_exit:
1052
1053 ; Skip the removable drive check on success
1054 jnc @F
1055
1056 ; Here, CF=1 because of a failure.
1057 ; This could be from a removable drive that is set to read-only,
1058 ; in which case we want to fake success. What this boils down to
1059 ; is that CY must be set to !IsRemovable.
1060 call DriveIO_CalcDiskInfoPointer ; Get DISKINFO pointer
1061 mov dx, [bx+LocDISKINFO_I13X_Flags] ; Get INT13X flags
1062 xor dl, 04h ; Invert 'removable' bit
1063 and dl, 04h ; Mask it out
1064 rcr dl, 3 ; Move it to CY
1065
1066 @@:
1067
1068 ; Pop all registers
1069 pop es
1070 pop ds
1071 popa
1072
1073 ret
1074DriveIO_WriteSectorLBA EndP
1075
1076
1077
1078
1079;##############################################################################
1080;# The Master LVM sector is *not* necessarily located at the end of the BIOS
1081;# view of TRACK0. Its location depends on the *OS/2 geometry* active when the
1082;# disk was partitioned. For disks < 502MiB this will most likely be LBA sector
1083;# 62, but for disks >502MiB, *extended* OS/2 geometry was used and DANIS506
1084;# uses SPT=127 for disks < 1TiB while IBMS506 uses SPT=255.
1085;# When a huge disk < 1TiB was partitioned with IBMS506, thus using SPT=255,
1086;# and the driver was later changed to DANIS506, DANI uses SPT=255, eventhough
1087;# the disk < 1TiB. Whether it is DANI that is LVM aware or something else
1088;# (maybe LVM itself) that makes DANI use the correct geometry has yet to be
1089;# investigated.
1090;#
1091;# Related geometry issues are also present with USB sticks, which can get
1092;# assigned a geometry by OS/2, which can depend if the stick was partitioned
1093;# on foreign systems or not, or even OS/2 manufacturing a geometry that is not
1094;# the same as the BIOS reports to us here. In both cases, fixed disks and
1095;# removable disks, the geometry recorded in the BPB of a partition can also
1096;# influence the geometry that OS/2 assigns. This is the case when 'preparing'
1097;# disks for LVM use, in which case BPB values could be incorporated.
1098;#
1099;# What this all boils down to, is that the geometry reported by the BIOS is
1100;# of no practical use, especially not when taking BIOS USB MSD emulation into
1101;# account. These are among the reasons why AirBoot needs to use LBA addressing
1102;# when handling LVM stuff and why LBA use cannot be disabled in the SETUP
1103;# anymore.
1104;#
1105;# So, a Master LVM sector can be present on any sector from LBA 254 downwards
1106;# and the only way to locate the correct one is to scan all the way down and,
1107;# if one is found, do proper validation on its values, because it may also be
1108;# a 'phantom' LVM sector left over from previous partition layouts.
1109;# Most of such 'phantoms' can be filtered out by verifying the location of
1110;# the found sector against the OS/2 geometry it specifies itself, which means
1111;# it must be located at the LBA of the SPT-1 it specifies.
1112;##############################################################################
1113;# ACTION : Locates the Master LVM sector on the specified disk
1114;# ----------------------------------------------------------------------------
1115;# EFFECTS : Leaves [Scratch] with last sector read or cleared
1116;# ----------------------------------------------------------------------------
1117;# IN : DL - BIOS disk number of drive to search
1118;# ----------------------------------------------------------------------------
1119;# OUT : CF=1 - found
1120;# : BX:AX - LBA address of LVM sector if found, 0 otherwise
1121;##############################################################################
1122DriveIO_LocateMasterLVMSector Proc Near uses cx dx si di ds es
1123
1124IFDEF AUX_DEBUG
1125 IF 0
1126 DBG_TEXT_OUT_AUX 'DriveIO_LocateMasterLVMSector:'
1127 PUSHRF
1128 call DEBUG_DumpRegisters
1129 ;~ call AuxIO_DumpSector
1130 ;~ call AuxIO_DumpParagraph
1131 ;~ call AuxIO_TeletypeNL
1132 POPRF
1133 ENDIF
1134ENDIF
1135
1136 ; LBA address to start scanning down from
1137 mov cx, 255
1138
1139 ; Make sure ES==DS
1140 push ds
1141 pop es
1142
1143 ; Because JCXZ is used, LBA sector 0 is never loaded and checked.
1144 ; This is of course no problem since it is the MBR.
1145 DriveIO_LocateMasterLVMSector_next:
1146 mov si, offset [Scratch] ; Use scratch area to load sectors
1147 call ClearSectorBuffer ; Clear the scratch area
1148 clc ; Indicate Master LVM sector not found
1149 jcxz DriveIO_LocateMasterLVMSector_done
1150
1151 ; Read the LBA sector specified in CX
1152 mov ax, cx ; LBA low
1153 xor bx, bx ; LBA high
1154 mov di, ds ; Segment of scratch buffer
1155 mov si, offset [Scratch] ; Offset of scratch buffer
1156 call DriveIO_ReadSectorLBA ; Read the sector
1157 lahf ; Save CF
1158 dec cx ; Prepare LBA of next sector to read
1159 sahf ; Restore CF
1160 ; No need to do any LVM sector validation when read error, read next
1161 jc DriveIO_LocateMasterLVMSector_next
1162
1163 ; See if the read sector has a valid signature and checksum
1164 call LVM_ValidateSector
1165
1166 ; NC indicates invalid or none-LVM sector, read next
1167 jnc DriveIO_LocateMasterLVMSector_next
1168
1169 ; We have found a valid LVM sector !
1170 ; So it contains the OS/2 geometry for the disk.
1171 ; That means this LVM sector itself must be located on the last sector
1172 ; of the SPT value its OS/2 geometery specifies, which, in LBA terms
1173 ; is LVM SPT-1 -- let's check that...
1174 mov bx, offset [Scratch] ; Offset of the loaded LVM sector
1175 mov al, [bx+LocLVM_Secs] ; Get the LVM SPT value (<=255)
1176 dec al ; Adjust to LVM LBA
1177 mov ah, cl ; Get next LVM LBA to search
1178 inc ah ; This one was found here
1179 cmp al, ah ; If same, LVM LBA location OK
1180 jne DriveIO_LocateMasterLVMSector_next
1181
1182 ; The LVM sector we found is at the location it should be on disk,
1183 ; so it's almost 99% sure this is the correct one.
1184 ; Now we should compare the start and sizes of the partitions in the
1185 ; MBR with the partitions specified in this LVM record.
1186 ; We'll implement that later after some more research.
1187 ; For now we assume this is the correct Master LVM sector for the disk.
1188 inc cx ; CX was prepared to read next, correct that
1189 stc ; Indicate we have found the Master LVM sector
1190
1191 DriveIO_LocateMasterLVMSector_done:
1192 mov bx, 0 ; A Master LVM sector always has high LBA=0
1193 mov ax, cx ; Low LBA of Master LVM sector
1194
1195 ; We leave it up to the caller to store the value in a proper place
1196 ret
1197DriveIO_LocateMasterLVMSector EndP
1198
1199
1200
1201;
1202; ############################################################
1203; # Check for a valid MBR-sector to be written to disk #
1204; ############################################################
1205;
1206; In
1207; --
1208; DL = Physical Disk
1209; BX:CX = LBA sector
1210; DI:SI = Source buffer
1211;
1212; Out
1213; ---
1214; CY = 1 if invalid MBR in source buffer, 0 if valid
1215;
1216; This routine is called when DriveIO_SaveSector attempts to write to the MBR.
1217; It checks if the sector to be written has some sensible values in certain
1218; places. In fact, if the sector is written to the boot-disk, the AiR-BOOT
1219; signature should be present and the partition table should be the same
1220; as the one at the start of the AiR-BOOT code in memory, except maybe for the
1221; active flags.
1222; For other disks, only the active flags are checked to be 00h or 80h and
1223; the AA55h MBR signature.
1224;
1225DriveIO_ProtectMBR Proc Near
1226 pusha ; Push all registers
1227 push es ; Push ES because we need it for string instructions
1228 push cs ; Make ES point...
1229 pop es ; to CS
1230
1231 ; Save the pointer to the sector to write in BX
1232 mov bx,si
1233
1234 ;
1235 ; If the sector to be written is not the boot-disk, then skip
1236 ; checking the AiR-BOOT MBR.
1237 ;
1238 cmp dl, [BIOS_BootDisk]
1239 jne DriveIO_ProtectMBR_is_not_bootdisk
1240
1241 ;
1242 ; The boot-disk is accessed so the sector to be written must be
1243 ; the AiR-BOOT MBR. This is the same as the first 512 bytes
1244 ; relocated to 8000:0000 and this the start of the AB-code.
1245 ;
1246 mov si,bx ; Get pointer to sector to write
1247 xor di,di ; Point DI to start of AB-code (MBR)
1248 mov cx, offset [MBR_PartTable] ; Bytes upto P-table must be same
1249 cld ; Compare upwards
1250 repe cmpsb ; Compare upto P-table
1251
1252 ; If not the same this is not the an AiR-BOOT boot-disk MBR !
1253 jne DriveIO_ProtectMBR_not_valid_MBR ; SEVERE ERROR !
1254
1255 ; Continue with signature check
1256 jmp DriveIO_ProtectMBR_check_signature
1257
1258
1259 ;
1260 ; The disk is not the boot-disk so we don't know what kind of MBR is on it.
1261 ; Some sanity checks should be here.
1262 ;
1263 DriveIO_ProtectMBR_is_not_bootdisk:
1264
1265 ;
1266 ; sanity checks...
1267 ;
1268
1269 ; Continue with signature check
1270 jmp DriveIO_ProtectMBR_check_signature
1271
1272
1273 DriveIO_ProtectMBR_check_signature:
1274 ; See if the sector to write contains a valid signature
1275 mov si,bx ; Get pointer to sector to write
1276 mov di, offset [MBR_Sig] ; Offset to MBR signature
1277 add si,di ; Make SI point to it in sec to write
1278 lodsw ; Load it
1279 cmp ax,0aa55h ; See if it is valid
1280
1281 ; If no signature this cannot be a valid MBR !
1282 jne DriveIO_ProtectMBR_not_valid_MBR ; SEVERE ERROR !
1283
1284
1285 ;
1286 ; The sector to be written seems to be valid.
1287 ; Set CY=0 to indicate a valid MBR.
1288 ;
1289 DriveIO_ProtectMBR_is_valid_MBR:
1290 clc
1291 jmp DriveIO_ProtectMBR_end
1292
1293 ;
1294 ; Something is terribly wrong; a non-MBR sector seems about to be written.
1295 ; Set CY=1 and let the calling code handle this situation.
1296 ;
1297 DriveIO_ProtectMBR_not_valid_MBR:
1298 stc
1299 jmp DriveIO_ProtectMBR_end
1300
1301 ;
1302 ; Return to the caller with no registers modyfied except FLAGS.
1303 ;
1304 DriveIO_ProtectMBR_end:
1305 pop es
1306 popa
1307 ret
1308DriveIO_ProtectMBR Endp
1309
1310
1311
1312; #########################################################################
1313; Routine: Checks if the MBR is addressed by either CHS or LBA
1314; #########################################################################
1315; Calling : bx:ax - Absolute sector
1316; cx:dx - Cylinder/Sector, Side/Drive (hi/lo-byte)
1317; Returns : ZF=1 if MBR is addressed, else ZF=0
1318; Preserve: all registers
1319; #########################################################################
1320DriveIO_MBR_Addressed Proc
1321 push ax
1322 push bx
1323
1324 or bx,ax ; Results in 0 in BX if MBR is addressed by LBA
1325 jz DriveIO_MBR_Addressed_done
1326
1327 mov ax,cx ; Results in 1 in AX if CYL 0, SEC 1 is addressed
1328 add al,dh ; Results in 1 in AX if HEAD 0 is addressed
1329 dec ax ; Results in 0 in AX if MBR is addressed by CHS
1330
1331 DriveIO_MBR_Addressed_done:
1332 pop bx
1333 pop ax
1334 ret
1335DriveIO_MBR_Addressed EndP
1336
1337
1338
1339
1340; #########################################################################
1341; Routine: Writes DS:SI to a specified sector
1342; #########################################################################
1343; Calling : bx:ax - Absolute sector
1344; cx:dx - Cylinder/Sector, Side/Drive (hi/lo-byte)
1345; ds:si - Source-Adress
1346; Returns : none
1347; Preserve: all registers
1348; #########################################################################
1349DriveIO_SaveSector Proc Near Uses ax bx cx dx ds si es di
1350
1351IFDEF AUX_DEBUG
1352 IF 0
1353 DBG_TEXT_OUT_AUX 'DriveIO_SaveSector:'
1354 PUSHRF
1355 call DEBUG_DumpRegisters
1356 ;~ call AuxIO_DumpParagraph
1357 ;~ call AuxIO_TeletypeNL
1358 POPRF
1359 ENDIF
1360ENDIF
1361
1362
1363;!
1364;! DEBUG_BLOCK
1365;! Force write to LBA0 to test interception routine.
1366;! Do *NOT* enable unless you are debugging, will overwrite MBR !
1367;!
1368IFDEF AUX_DEBUG
1369 IF 0
1370 pushf
1371 pusha
1372 xor ax,ax
1373 xor bx,bx
1374 xor cx,cx
1375 inc cx
1376 xor dh,dh
1377 popa
1378 popf
1379 ENDIF
1380ENDIF
1381
1382 ;
1383 ; Check if the MBR is the destination for the write.
1384 ; ZF=1 if so.
1385 ;
1386 call DriveIO_MBR_Addressed
1387 jnz DriveIO_SaveSector_continue_write
1388
1389
1390 ; MBR is addressed, check the sector that is requested to be written.
1391 ; For the bootdisk it should contain the AiR-BOOT signature, valid
1392 ; partition-table entries and the AA55h signature.
1393 ; If not, something is terribly wrong in some piece of the AB code.
1394 ; For any other disk (80h+) at least a valid partition table should
1395 ; be present together with the AA55h signature.
1396 call DriveIO_ProtectMBR
1397 jnc DriveIO_SaveSector_continue_write
1398
1399
1400 ;
1401 ; WE HAVE A SEVERE ERROR CONDITION !
1402 ; SOME AB CODE TRIES TO WRITE A NON-MBR TO THE DISK !
1403 ; ASK THE USER TO REPORT THIS !
1404 ; HALT THE SYSTEM !
1405 ;
1406
1407 ; Show error-box
1408 mov cx, 0C04h
1409 mov si, offset NonMBRwrite
1410 call SETUP_ShowErrorBox
1411 mov cx, 0C04h
1412 mov si, offset NonMBRwrite_rep
1413 call SETUP_ShowErrorBox
1414
1415
1416IFDEF AUX_DEBUG
1417 IF 0
1418 pushf
1419 pusha
1420 mov si, offset [NonMBRwrite]
1421 call AuxIO_TeletypeNL
1422 call AuxIO_Print
1423 call AuxIO_TeletypeNL
1424 popa
1425 popf
1426 ENDIF
1427ENDIF
1428
1429 ; Show popup and halt the system.
1430 jmp HaltSystem
1431
1432
1433
1434 ;
1435 ; Continue the write if not MBR sector or MBR to write is validated.
1436 ;
1437 DriveIO_SaveSector_continue_write:
1438 test byte ptr cs:[CurIO_UseExtension], 1
1439 jz DIOSS_UseNormal
1440 ; Are we forced do use LBA via Setting?
1441 ; Always use INT13X on v1.0.8+.
1442 ;~ test byte ptr cs:[CFG_ForceLBAUsage], 1
1443 ;~ jnz DIOSS_UseExtension
1444 jmp DIOSS_UseExtension
1445 ; Is the drive not a harddrive?
1446 cmp dl, 80h
1447 jb DIOSS_UseNormal
1448 ; Upper 8 bits of LBA-address set? -> Use LBA (maximum boundary is FB0400h)
1449 or bh, bh
1450 jnz DIOSS_UseExtension
1451 ; Compare Switch-Table value to bit 16-23 of LBA-address
1452 mov di, dx
1453 and di, 007Fh
1454 cmp bptr cs:[LBASwitchTable+di], bl
1455 jbe DIOSS_UseExtension
1456
1457 DIOSS_UseNormal:
1458
1459IFDEF AUX_DEBUG
1460 IF 0
1461 DBG_TEXT_OUT_AUX 'DriveIO_WriteSectorCHS:'
1462 PUSHRF
1463 call DEBUG_DumpRegisters
1464 call AuxIO_DumpParagraph
1465 call AuxIO_TeletypeNL
1466 POPRF
1467 ENDIF
1468ENDIF
1469
1470 mov di, 3 ; retry count
1471 DIOSS_ErrorLoop:
1472 push ds
1473 pop es
1474 mov bx, si ; ES:BX - Destination
1475 mov ax, 0301h ; Function 3 - Write Sector
1476 int 13h
1477 jnc DIOSS_Success
1478 dec di ; decrement retry count
1479 jnz DIOSS_ErrorLoop
1480 call MBR_SaveError
1481
1482 DIOSS_UseExtension:
1483
1484 mov di, ds ; segment for transfer address
1485 call DriveIO_WriteSectorLBA ; extended write
1486 jc MBR_SaveError ; halt on error
1487
1488 ;~ push cx
1489 ;~ mov cs:[INT13X_DAP_NumBlocks], 1 ; Copy ONE sector
1490 ;~ mov wptr cs:[INT13X_DAP_Transfer+0], si
1491 ;~ mov cx, ds
1492 ;~ mov wptr cs:[INT13X_DAP_Transfer+2], cx ; Fill out Transfer Adress
1493 ;~ mov wptr cs:[INT13X_DAP_Absolute+0], ax
1494 ;~ mov wptr cs:[INT13X_DAP_Absolute+2], bx ; Fill out Absolute Sector
1495 ;~ push cs
1496 ;~ pop ds
1497 ;~ mov si, offset [INT13X_DAP]
1498 ;~ mov ax, 4300h ; Extended Write (No Verify)
1499 ;~ int 13h
1500 ;~ pop cx
1501 ;~ jnc DIOSS_Success
1502 ;~ call MBR_SaveError
1503
1504 DIOSS_Success:
1505 ret
1506DriveIO_SaveSector EndP
1507
1508
1509
1510
1511;##############################################################################
1512;# When a disk has a Master LVM sector, it means it has been prepared for use
1513;# by OS/2 and contains important information about how OS/2 views its geometry
1514;# and other disk related properties. This function assumes the LBA address
1515;# of the Master LVM sector has already been located and simply loads the
1516;# sector into [LVMSector].
1517;#
1518;# Note that because this is an operation similar to the regular loading of
1519;# sectors, the disk I/O semantics are used here. This means CF=0 when an LVM
1520;# sector is successfully loaded and CF=1 otherwise.
1521;##############################################################################
1522;# ACTION : Loads the Master LVM sector if one exists
1523;# ----------------------------------------------------------------------------
1524;# EFFECTS : Modifies DAP structure and [LVMSector]
1525;# ----------------------------------------------------------------------------
1526;# IN : DL - BIOS disk number (80h,81h,etc)
1527;# ----------------------------------------------------------------------------
1528;# OUT : CF=0 - Valid Master LVM sector found and loaded
1529;##############################################################################
1530DriveIO_LoadMasterLVMSector Proc Near
1531
1532IFDEF AUX_DEBUG
1533 IF 0
1534 DBG_TEXT_OUT_AUX 'DriveIO_LoadMasterLVMSector:'
1535 PUSHRF
1536 ;~ call DEBUG_DumpRegisters
1537 ;~ call AuxIO_DumpParagraph
1538 ;~ call AuxIO_TeletypeNL
1539 POPRF
1540 ENDIF
1541ENDIF
1542
1543 ; Save all registers
1544 pusha
1545
1546 ; Check if BIOS disk number is valid
1547 call DriveIO_IsValidHarddisk
1548 jc DriveIO_LoadMasterLVMSector_error
1549
1550 ; Calculate the entry in the DISKINFO array for this disk
1551 call DriveIO_CalcDiskInfoPointer
1552
1553 ; Save the entry for later recalls
1554 mov bp, bx
1555
1556 ; Get the LBA address of the Master LVM sector
1557 mov ax, [bx+LocDISKINFO_LVM_MasterLBA+00h]
1558 mov bx, [bx+LocDISKINFO_LVM_MasterLBA+02h]
1559
1560 ; LBA of Master LVM sector cannot be 0, so none was found during
1561 ; the gathering of disk information.
1562 mov cx, ax
1563 or cx, bx
1564 jz DriveIO_LoadMasterLVMSector_error
1565
1566 ; Load it into [LVMSector]
1567 mov di, ds
1568 mov si, offset [LVMSector]
1569 call DriveIO_ReadSectorLBA
1570 jc DriveIO_LoadMasterLVMSector_error
1571
1572 ; Validate the Master LVM sector
1573 call LVM_ValidateSector
1574
1575 ; Complement success indicator to conform to semantics of this function
1576 cmc
1577
1578 ; Master LVM sector was valid and is now loaded in [LVMSector]
1579 jnc DriveIO_LoadMasterLVMSector_ret
1580
1581 DriveIO_LoadMasterLVMSector_error:
1582
1583 ; Clear the sector buffer for safety reasons
1584 mov si, offset [LVMSector]
1585 call ClearSectorBuffer
1586
1587 ; Indicate no Master LVM sector loaded
1588 stc
1589
1590 DriveIO_LoadMasterLVMSector_ret:
1591
1592 ; Restore all registers
1593 popa
1594
1595 ret
1596DriveIO_LoadMasterLVMSector Endp
1597
1598
1599
1600
1601;##############################################################################
1602;# There is much information to know about the connected disks.
1603;# We also want this information clustered per disk and available before
1604;# further disk and partition scanning takes place.
1605;# This function gathers such information like INT13, INT13X, MBR, LVM, more.
1606;# Especially important is the LVM information, because that contains the
1607;# geometry OS/2 uses to access the disk. Other important information is the
1608;# presence of valid MBRs, logical partitions and whatnot.
1609;# This function gathers such information and stores it in a DISKINFO structure
1610;# for which an instance exists for every disk found.
1611;##############################################################################
1612;# ACTION : Gather disk information and store this in the BSS
1613;# ----------------------------------------------------------------------------
1614;# EFFECTS : Modifies DAP structure and the buffers it uses, fills DISKINFO[n]
1615;# ----------------------------------------------------------------------------
1616;# IN : DL - BIOS disk number (80h,81h,etc)
1617;# ----------------------------------------------------------------------------
1618;# OUT : CF=1 - failure
1619;##############################################################################
1620DriveIO_GatherDiskInfo Proc Near
1621
1622IFDEF AUX_DEBUG
1623 IF 0
1624 DBG_TEXT_OUT_AUX 'DriveIO_GatherDiskInfo:'
1625 PUSHRF
1626 call DEBUG_DumpRegisters
1627 ;~ call AuxIO_DumpParagraph
1628 ;~ call AuxIO_TeletypeNL
1629 POPRF
1630 ENDIF
1631ENDIF
1632
1633 ; Push all registers we use
1634 pusha
1635 push ds
1636 push es
1637
1638 ; Make sure ES=DS
1639 push ds
1640 pop es
1641
1642 ; Check if BIOS disk number is valid
1643 call DriveIO_IsValidHarddisk
1644 jc DriveIO_GatherDiskInfo_error
1645
1646 ; Calculate the entry in the DISKINFO array for this disk
1647 call DriveIO_CalcDiskInfoPointer
1648
1649 ; Save the entry for later recalls
1650 mov bp, bx
1651
1652 ; Store the BIOS disk number in the structure
1653 mov [bx+LocDISKINFO_DiskNum], dl
1654
1655; ------------------------------------------------------------------- [ INT13 ]
1656
1657 ; Get BIOS Disk Parameters (legacy method)
1658 mov ah, 08h ; Get Disk Parameters
1659 int 13h ; Call BIOS
1660
1661 ; CF=1 or AH!=0 indicates error
1662 jc DriveIO_GatherDiskInfo_error
1663 test ah, ah
1664 jnz DriveIO_GatherDiskInfo_error
1665
1666 ; Recall DISKINFO entry
1667 mov bx, bp
1668
1669 ; Store SPT (WORD)
1670 xor ah, ah ; Zero extend SPT to 16 bits
1671 mov al, cl ; Hi 2 bits max cyl and max sec
1672 and al, 3fh ; Mask max sec (1-based)
1673 mov [bx+LocDISKINFO_I13_Secs], ax ; Store SPT
1674
1675 ; Store HEADS (WORD)
1676 xor dl, dl ; Zero extend HEADS to 16 bits
1677 xchg dl, dh ; Get max head (0-based)
1678 inc dx ; Head count
1679 mov [bx+LocDISKINFO_I13_Heads], dx ; Store HEADS
1680
1681 ; Store CYLS (WORD)
1682 shr cl, 6 ; Hi 2 bits of max cyl to 1:0
1683 xchg cl, ch ; Max cyl (0-based)
1684 inc cx ; Cyl count
1685 mov [bx+LocDISKINFO_I13_Cyls], cx ; Store CYLS
1686
1687 ; Recall BIOS disk number
1688 mov dl, [bx+LocDISKINFO_DiskNum]
1689
1690; ------------------------------------------------------------------ [ INT13X ]
1691
1692 ; Get BIOS Disk Parameters (extended method)
1693 mov si, offset [Scratch] ; Buffer to return disk info
1694 mov ax, 80h ; Size of buffer
1695 mov [si], ax ; Store it in first word
1696 mov ah, 48h ; Get Extended Disk Parameters
1697 int 13h ; Call BIOS
1698
1699 ; CF=1 or AH!=0 indicates error
1700 jc DriveIO_GatherDiskInfo_error
1701 test ah, ah
1702 jnz DriveIO_GatherDiskInfo_error
1703
1704 ; Store flags (WORD)
1705 cld ; Direction up
1706 lodsw ; Buffersize, discard
1707 lodsw ; Flags (CHS valid etc)
1708 mov [bx+LocDISKINFO_I13X_Flags], ax ; Store them
1709
1710 ; Store CYLS (DWORD)
1711 lodsw ; Cyl count low
1712 mov [bx+LocDISKINFO_I13X_Cyls+00h], ax ; Store CYLS low
1713 lodsw ; Cyl count high
1714 mov [bx+LocDISKINFO_I13X_Cyls+02h], ax ; Store CYLS high
1715
1716 ; Store HEADS (DWORD)
1717 lodsw ; Head count low
1718 mov [bx+LocDISKINFO_I13X_Heads+00h], ax ; Store HEADS low
1719 lodsw ; Head count high
1720 mov [bx+LocDISKINFO_I13X_Heads+02h], ax ; Store HEADS high
1721
1722 ; Store SPT (DWORD)
1723 lodsw ; Secs per track low
1724 mov [bx+LocDISKINFO_I13X_Secs+00h], ax ; Store SPT low
1725 lodsw ; Secs per track high
1726 mov [bx+LocDISKINFO_I13X_Secs+02h], ax ; Store SPT high
1727
1728 ; Store total LBA sectors (QWORD)
1729 lea di, [bx+LocDISKINFO_I13X_SecsLBA]
1730 mov cx, 4
1731 rep movsw
1732
1733 ; Store sector size (WORD)
1734 lodsw
1735 mov [bx+LocDISKINFO_I13X_SecSize], ax
1736
1737 ; Store bus name (4 bytes, space padded, v3.0+)
1738 lea si, [Scratch+24h]
1739 lea di, [bx+LocDISKINFO_I13X_HostBus]
1740 movsw
1741 movsw
1742
1743 ; Store interface name (8 bytes, space padded, v3.0+)
1744 lea di, [bx+LocDISKINFO_I13X_Interface]
1745 mov cx, 4
1746 rep movsw
1747
1748 ; Should gather some more INT13X info here,
1749 ; like maybe Advanced Format stuff or so.
1750 ; We'll investigate that at a later time.
1751
1752; --------------------------------------------------------------------- [ MBR ]
1753
1754 ; Load the MBR
1755 mov si, offset [TmpSector]
1756 call DriveIO_LoadMBR
1757
1758 ; Store MBR flags (valid sig, partitions present, airboot installed)
1759 mov [bx+LocDISKINFO_MbrFlags], al
1760
1761 ; Recall BIOS disk number
1762 mov dl, [bx+LocDISKINFO_DiskNum]
1763
1764; --------------------------------------------------------------------- [ LVM ]
1765
1766 ; Locate the Master LVM sector, if any
1767 call DriveIO_LocateMasterLVMSector
1768
1769 ; Save Master LVM sector LBA high
1770 mov cx, bx
1771
1772 ; Recall DISKINFO entry
1773 mov bx, bp
1774
1775 ; Store Master LVM sector LBA
1776 mov [bx+LocDISKINFO_LVM_MasterLBA+00h], ax
1777 mov [bx+LocDISKINFO_LVM_MasterLBA+02h], cx
1778
1779 ; No Master LVM sector found, so skip storing LVM info for this disk
1780 jnc DriveIO_GatherDiskInfo_no_master_lvm
1781
1782 ; Load the Master LVM sector into [LVMSector]
1783 call DriveIO_LoadMasterLVMSector
1784
1785 ; No valid Master LVM sector, so skip storing LVM info for this disk
1786 jc DriveIO_GatherDiskInfo_no_master_lvm
1787
1788 ; A valid Master LVM sector has been loaded into [LVMSector]
1789 mov si, offset [LVMSector]
1790
1791 ; Get the number of sectors per track (OS/2 geometry)
1792 mov ax, [si+LocLVM_Secs+00h]
1793 mov cx, [si+LocLVM_Secs+02h]
1794
1795 ; Store it
1796 mov [bx+LocDISKINFO_LVM_Secs+00h], ax
1797 mov [bx+LocDISKINFO_LVM_Secs+02h], cx
1798
1799 ; Get the number of heads (OS/2 geometry)
1800 mov ax, [si+LocLVM_Heads+00h]
1801 mov cx, [si+LocLVM_Heads+02h]
1802
1803 ; Store it
1804 mov [bx+LocDISKINFO_LVM_Heads+00h], ax
1805 mov [bx+LocDISKINFO_LVM_Heads+02h], cx
1806
1807 ; Should gather some more LVM info here,
1808 ; like OS/2 extended geometry and other flags.
1809 ; We'll implement that at a later time.
1810
1811 DriveIO_GatherDiskInfo_no_master_lvm:
1812
1813 ; When no Master LVM sector was found,
1814 ; the LVM info in the DISKINFO structure for the disk
1815 ; will be ZERO because the area was cleared in PRECRAP.
1816
1817 ; Indicate success
1818 clc
1819
1820 jmp DriveIO_GatherDiskInfo_ret
1821
1822 DriveIO_GatherDiskInfo_error:
1823 stc
1824 DriveIO_GatherDiskInfo_ret:
1825
1826
1827IFDEF AUX_DEBUG
1828 IF 0
1829 DBG_TEXT_OUT_AUX '[DISKINFO]'
1830 PUSHRF
1831 call DEBUG_DumpRegisters
1832 ;~ call AuxIO_DumpParagraph
1833 ;~ call AuxIO_TeletypeNL
1834 mov si, bp
1835 mov cx, 4
1836 @@:
1837 call AuxIO_DumpParagraph
1838 call AuxIO_TeletypeNL
1839 add si, 16
1840 loop @B
1841 mov si, offset [Scratch]
1842 mov cx, 4
1843 @@:
1844 call AuxIO_DumpParagraph
1845 call AuxIO_TeletypeNL
1846 add si, 16
1847 loop @B
1848 mov si, offset [LVMSector]
1849 mov cx, 7
1850 @@:
1851 call AuxIO_DumpParagraph
1852 call AuxIO_TeletypeNL
1853 add si, 16
1854 loop @B
1855 POPRF
1856 ENDIF
1857ENDIF
1858
1859 ; Restore registers
1860 pop es
1861 pop ds
1862 popa
1863
1864 ret
1865DriveIO_GatherDiskInfo EndP
1866
1867;------------------------------------------------------------------------------
1868; Scan all disks to gather information
1869;------------------------------------------------------------------------------
1870; IN : None
1871; OUT : CF=1 - some failure occured
1872; : ZF=1 - no harddisks
1873; NOTE : This does the preliminary gathering of disk information
1874;------------------------------------------------------------------------------
1875DriveIO_ScanDisks Proc Near
1876
1877IFDEF AUX_DEBUG
1878 IF 0
1879 DBG_TEXT_OUT_AUX 'DriveIO_ScanDisks:'
1880 PUSHRF
1881 call DEBUG_DumpRegisters
1882 ;~ call AuxIO_DumpParagraph
1883 ;~ call AuxIO_TeletypeNL
1884 POPRF
1885 ENDIF
1886ENDIF
1887
1888 ; Save all registers
1889 pusha
1890
1891 ; Get number of disks in DH
1892 call DriveIO_GetHardDriveCount
1893
1894 ; Check if there are any disks to scan
1895 xor cx, cx ; Prepare 16-bit counter
1896 mov cl, dh ; Number of disks now in CX
1897 jcxz DriveIO_ScanDisks_end ; Quit if no disks
1898
1899 ; Scan disks from 80h upward
1900 mov dl, 80h ; BIOS number of first disk
1901 DriveIO_ScanDisks_next:
1902 call DriveIO_GatherDiskInfo ; Gather info for this disk
1903 jc DriveIO_ScanDisks_end ; Quit if some error occured
1904 inc dl ; Advance to next disk
1905 loop DriveIO_ScanDisks_next ; Scan next disk if there is one
1906 test dl, dl ; Set ZF=0
1907 clc ; Indicate success
1908
1909 DriveIO_ScanDisks_end:
1910 ; Restore all registers
1911 popa
1912
1913 ret
1914DriveIO_ScanDisks EndP
1915
1916;------------------------------------------------------------------------------
1917; Calculate pointer to entry in DISKINFO structure
1918;------------------------------------------------------------------------------
1919; IN : DL BIOS disk number (80h etc)
1920; OUT : BX Pointer to entry
1921; NOTE : BIOS disk number must be valid
1922;------------------------------------------------------------------------------
1923DriveIO_CalcDiskInfoPointer Proc Near
1924 xchg bx, ax ; AX is used for calculation
1925 mov al, DISKINFO_Size ; Size of DISKINFO structure
1926 mov ah, dl ; BIOS disk number
1927 sub ah, 80h ; Now 0-based index
1928 mul ah ; Now offset into DISKINFO array
1929 add ax, offset [DiskInformation] ; Base of DISKINFO array
1930 xchg bx, ax ; BX now points to entry for disk
1931 ret
1932DriveIO_CalcDiskInfoPointer EndP
1933
1934;------------------------------------------------------------------------------
1935; Check if the BIOS disk number in DL is a harddisk and in range
1936;------------------------------------------------------------------------------
1937; IN : DL BIOS disk number (80h etc)
1938; OUT : CF=1 if invalid disk number or out of range
1939; NOTE : Only modifies flags
1940;------------------------------------------------------------------------------
1941DriveIO_IsValidHarddisk Proc Near Uses dx
1942 cmp dl, 80h ; BIOS disk number must be at least 80h
1943 jb @F ; Not a harddisk, exit with CY
1944 mov dh, dl ; Save to do compare
1945 sub dh, 80h ; Now 0 based disk number
1946 inc dh ; Now 1 based disk number
1947 cmp [TotalHarddiscs], dh ; Out of range, exit with CY
1948 @@: ret
1949DriveIO_IsValidHarddisk EndP
1950
1951
1952; Values for sectors per track table corresponding to DriveIO_IsHugeDrive return value.
1953;~ secs_per_track_table db 63,127,255,255,255,255
1954
1955;~ db_lmlvm db 'Load Master LVM -- disk: ',0
Note: See TracBrowser for help on using the repository browser.