leanback/leanback/build.gradle

import static androidx.build.dependencies.DependenciesKt.*
import androidx.build.LibraryGroups
import androidx.build.LibraryVersions
import androidx.build.Publish

plugins {
    id("AndroidXPlugin")
    id("com.android.library")
}

dependencies {
    api("androidx.annotation:annotation:1.1.0")
    api("androidx.interpolator:interpolator:1.0.0")
    api("androidx.core:core:1.1.0")
    implementation("androidx.collection:collection:1.0.0")
    api("androidx.media:media:1.0.0")
    api("androidx.fragment:fragment:1.0.0")
    api("androidx.recyclerview:recyclerview:1.2.0-rc01")
    api("androidx.appcompat:appcompat:1.0.0")

    androidTestImplementation(KOTLIN_STDLIB)
    androidTestImplementation(ANDROIDX_TEST_EXT_JUNIT)
    androidTestImplementation(ANDROIDX_TEST_CORE)
    androidTestImplementation(ANDROIDX_TEST_RUNNER)
    androidTestImplementation(ANDROIDX_TEST_RULES)
    androidTestImplementation(ESPRESSO_CORE, excludes.espresso)
    androidTestImplementation(MOCKITO_CORE, excludes.bytebuddy) // DexMaker has it"s own MockMaker
    androidTestImplementation(DEXMAKER_MOCKITO, excludes.bytebuddy) // DexMaker has it"s own MockMaker
    androidTestImplementation(project(":internal-testutils-espresso"))
    androidTestImplementation(project(":internal-testutils-runtime"))
    androidTestImplementation(project(":internal-testutils-common"))
}

android {
    defaultConfig {
        minSdkVersion 17
    }

    sourceSets {
        main.java.srcDirs += [
                "common",
                "kitkat",
                "api21",
        ]
    }
}

androidx {
    name = "Android Support Leanback v17"
    publish = Publish.SNAPSHOT_AND_RELEASE
    mavenVersion = LibraryVersions.LEANBACK
    mavenGroup = LibraryGroups.LEANBACK
    inceptionYear = "2014"
    description = "Android Support Leanback v17"
    failOnDeprecationWarnings = false
}