room/compiler-processing/build.gradle

/*
 * Copyright (C) 2020 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

import androidx.build.LibraryGroups
import androidx.build.LibraryType
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

import static androidx.build.dependencies.DependenciesKt.*

plugins {
    id("AndroidXPlugin")
    id("kotlin")
}

dependencies {
    api(KOTLIN_STDLIB)
    api(JAVAPOET)
    implementation("androidx.annotation:annotation:1.1.0")
    implementation(GUAVA)
    implementation(AUTO_COMMON)
    implementation(AUTO_VALUE_ANNOTATIONS)

    implementation(KOTLIN_METADATA_JVM)
    implementation(INTELLIJ_ANNOTATIONS)
    implementation(KOTLIN_KSP_API)
    implementation(KOTLIN_STDLIB_JDK8) // KSP defines older version as dependency, force update.

    testImplementation(GOOGLE_COMPILE_TESTING)
    testImplementation(JUNIT)
    testImplementation(JSR250)
    testImplementation(KOTLIN_COMPILE_TESTING_KSP)
    testImplementation(KOTLIN_KSP)
    testImplementation(project(":room:room-compiler-processing-testing"))
}

tasks.withType(KotlinCompile).configureEach {
    kotlinOptions {
        freeCompilerArgs += ["-Xopt-in=kotlin.RequiresOptIn",
                             "-Xopt-in=kotlin.contracts.ExperimentalContracts"]
    }
}

tasks.withType(Test).configureEach {
    // TODO: re-enable once b/177660733 is fixed.
   it.systemProperty("androidx.room.compiler.processing.strict", "false")
}

androidx {
    name = "AndroidX Room XProcessor"
    type = LibraryType.ANNOTATION_PROCESSOR
    mavenGroup = LibraryGroups.ROOM
    inceptionYear = "2020"
    description = "Processing Environment Abstraction for AndroidX Room"
}