source: branches/guitools-2.0/shared/smbtree.vrs@ 325

/* Routines to handle smbtree output */

/*:VRX */
_RefreshTree: 
    say "_RefreshTree() started"
    FirstRun = 0

    ok = SysFileDelete(samba.!msg)

    if UserCred = 'USERCRED' | UserCred = '' | UserCred = '--user=%' then do
        UserCred = '-N'
    end

    if ShowHidden = 'SHOWHIDDEN' | ShowHidden = '' then ShowHidden = 1

    say 'detach 'samba.!smbtreeexe' 'debuglevel' 'UserCred' >'samba.!msg
    address cmd 'detach 'samba.!smbtreeexe' 'debuglevel' 'UserCred' >'samba.!msg

    if UserCred = '-N' then UserCred = ''

    ok = VRMethod("CN_smbtree", "RemoveRecord", "ALL")

    ok = VRSet("CN_smbtree","Enabled", 0)
    ok = VRset("TM_RefreshTreeDisplay","Enabled",1)

    say "_RefreshTree() done"
return

/*:VRX */
_RefreshTreeDisplay: 
    stat = stream(samba.!msg,'c','open read')
    if stat <> "READY:" then return

    ok = VRset("TM_RefreshTreeDisplay","Enabled",0)
/*  ok = VRSet("Main", "StatusText", NLVGetMessage(50)) */
    ok = VRSet("CN_smbtree", 'Enabled', 0 )
/*  ok = VRSet("Main", 'Pointer', 'Wait' ) */

    ok = VRSet( "CN_smbtree", "Painting", 0  )
    ok = VRMethod("CN_smbtree", "RemoveRecord", "ALL")

    drop smbtree.
    drop smbtreeline.

    sl = 0

    do until lines(samba.!msg) = 0
        sl = sl + 1
        smbtreeline.sl = linein(samba.!msg)
    end
    smbtreeline.0 = sl
    ok = stream(samba.!msg,'c','close')

    do sl = 1 to smbtreeline.0
        Header = c2x(left(smbtreeline.sl,3))
        select
            when Header = "09095C" then do /* share */
                smbtreeline.sl = strip(smbtreeline.sl,,'09'x)
                parse var smbtreeline.sl '\\'machine'\'share '09'x comment
                machine = strip(machine)
                share   = left(strip(share),10)
                comment = strip(comment)
                text = translate(share' 'comment)
                res = _GuessIcon(text)
                if VRGet("CN_smbtree","View") = "IconTree" then do
                    parent = smbtree.!machine
                    smbtree.!share = VRMethod( "CN_smbtree", "AddRecord",parent,, share||'0D0A'x||comment, res)
                    ok = VRMethod( "CN_smbtree", "SetRecordAttr", smbtree.!share, "ReadOnly", 1)
                    if pos("$", share) > 0 then ok = VRMethod( "CN_smbtree", "SetRecordAttr", smbtree.!share, "Visible", ShowHidden)
                end
            end
            when Header = "095C5C" then do /* Machine */
                smbtreeline.sl = strip(smbtreeline.sl,,'09'x)
                parse var smbtreeline.sl '\\'machine '0909'x comment
                machine = left(strip(machine),13)
                comment = strip(comment)
                if VRGet("CN_smbtree","View") = "IconTree" then parent = smbtree.!workgroup; else parent = ""
                smbtree.!machine = VRMethod( "CN_smbtree", "AddRecord",parent,, machine||'0D0A'x||comment,"#35:PMWP.DLL")
                ok = VRMethod( "CN_smbtree", "SetRecordAttr", smbtree.!machine, "ReadOnly", 1)
                ok = VRMethod( "CN_smbtree", "SetFieldData", smbtree.!machine, NBFH, machine, CommentFH, Comment, WorkGroupFH, CurWG)
                if VRGet("CN_smbtree","View") = "Detail" then do
                    address cmd samba.!nmblookupexe' 'machine' 'debuglevel' -N >'samba.!msg
                    ipstr = ""
                    ip = ""
                    do until lines(samba.!msg) = 0
                        nmblookupline = linein(samba.!msg)
                        if pos(strip(machine)'<',nmblookupline) > 0 then do
                            parse var nmblookupline ip .
                            if pos(strip(ip), ipstr) = 0 then do
                                ipstr = ipstr||ip','
                            end
                        end
                    end
                    ipstr = strip(ipstr,,',')
                    ok = VRMethod( "CN_smbtree", "SetFieldData", smbtree.!machine, IPFH, IPStr)
                    ok = stream(samba.!msg,'c','close')
                    if ip <> "" then do
                        address cmd samba.!smbclientexe' -L "'strip(machine)'" -I "'ip'" -N 'debuglevel' 2>'samba.!msg' 1>NUL'
                        smbline = linein(samba.!msg)
                        ok = stream(samba.!msg,'c','close')
                        parse var smbline "Domain=["WorkGroup"] OS=["OS"] Server=["Server"]"Rest
                        ok = VRMethod( "CN_smbtree", "SetFieldData", smbtree.!machine, OSFH, OS)
                        /* WorkGroupFH, Workgroup */
                        address cmd samba.!nmblookupexe' -A 'machine' 'debuglevel' -N >'samba.!msg
                        Master = ""
                        do until lines(samba.!msg) = 0
                            nmblookupline = linein(samba.!msg)
                            if pos('<1b>', nmblookupline) > 0 then Master = Master||"LMB," /* + */
                            if pos('<1d>', nmblookupline) > 0 then Master = Master||"DMB," /* * */
                            if pos('MAC',nmblookupline) > 0 then do
                                parse var nmblookupline . '=' MAC
                                MAC = strip(MAC)
                            end
                        end
                        Master= strip(Master,,',')
                        ok = stream(samba.!msg,'c','close')
                        ok = VRMethod( "CN_smbtree", "SetFieldData", smbtree.!machine, MBFH, Master,MacFH,MAC)
                    end
                end
                ok = VRSet( "CN_smbtree", "Painting", 1  )
                ok = VRSet( "CN_smbtree", "Painting", 0  )
            end
            otherwise do
                say "Workgroup: "smbtreeline.sl
                if pos("RECEIVING",translate(smbtreeline.sl)) > 0 then do
                    Msg.Type = "W"
                    Msg.Text = smbtreeline.sl
                    call _ShowMsg
                end
                else do
                    if VRGet("CN_smbtree","View") = "IconTree" then do
                        smbtree.!workgroup = VRMethod( "CN_smbtree", "AddRecord",,, smbtreeline.sl,"#62:PMWP.DLL")
                        ok = VRMethod( "CN_smbtree", "SetFieldData", smbtree.!workgroup, WorkGroupFH, smbtreeline.sl)
                        ok = VRMethod( "CN_smbtree", "SetRecordAttr", smbtree.!workgroup, "Collapsed", 0)
                        ok = VRMethod( "CN_smbtree", "SetRecordAttr", smbtree.!workgroup, "ReadOnly", 1)
                    end
                    CurWG = smbtreeline.sl
                end
            end
        end 
    end

    ok = VRSet( "CN_smbtree", "Painting", 1  )

/*  ok = VRSet("Main", 'Pointer', '<default>' ) */
    ok = VRSet("CN_smbtree","Enabled", 1)
    ok = VRSet("TM_Throbber","Enabled", 0)
    ok = VRSet("Pict_Throbber","Visible", 0)
return

/*:VRX         _GuessIcon
*/
_GuessIcon: procedure
    text = translate(arg(1))
    select /* Printer guessing */
        when pos('LJ',text)      > 0 then res = '#65:PMWP.DLL'
        when pos('LASER',text)   > 0 then res = '#65:PMWP.DLL'
        when pos('EPSON',text)   > 0 then res = '#65:PMWP.DLL'
        when pos('PRINT',text)   > 0 then res = '#65:PMWP.DLL'
        when pos('PRT',text)     > 0 then res = '#65:PMWP.DLL'
        when pos('CANON',text)   > 0 then res = '#65:PMWP.DLL'
        when pos('MINOLTA',text) > 0 then res = '#65:PMWP.DLL'
        when pos('FAX',text)     > 0 then res = '#65:PMWP.DLL'
        when pos('LEXMARK',text) > 0 then res = '#65:PMWP.DLL'
        when pos('IPC$',text)    > 0 then res = '#59:PMWP.DLL'
        when pos('GHOSTPDF',text)> 0 then res = '#65:PMWP.DLL'
        when pos('PDF',text)     > 0 & ,
             pos('WRI',text)     > 0 then res = '#65:PMWP.DLL'
        otherwise res = "#34:PMWP.DLL"
    end
return res