source: smplayer/vendor/current/src/smplayer.pro

Last change on this file was 186, checked in by Silvan Scherrer, 8 years ago

SMPlayer: update vendor to 17.1.0
File size: 15.9 KB
Line 
1TEMPLATE = app
2LANGUAGE = C++
3
4CONFIG += qt warn_on
5CONFIG += release
6#CONFIG += debug
7
8QT += network xml
9
10RESOURCES = icons.qrc
11
12#DEFINES += EXPERIMENTAL
13DEFINES += SINGLE_INSTANCE
14DEFINES += FIND_SUBTITLES
15DEFINES += VIDEOPREVIEW
16DEFINES += YOUTUBE_SUPPORT
17DEFINES += BLURAY_SUPPORT
18DEFINES += TV_SUPPORT
19DEFINES += GUI_CHANGE_ON_RUNTIME
20DEFINES += LOG_MPLAYER
21DEFINES += LOG_SMPLAYER
22DEFINES += DEFAULTGUI
23DEFINES += MINIGUI
24DEFINES += MPCGUI
25DEFINES += SKINS
26DEFINES += MPRIS2
27DEFINES += UPDATE_CHECKER
28DEFINES += CHECK_UPGRADED
29DEFINES += AUTO_SHUTDOWN_PC
30DEFINES += CAPTURE_STREAM
31DEFINES += BOOKMARKS
32DEFINES += MOUSE_GESTURES
33DEFINES += GLOBALSHORTCUTS
34DEFINES += ADD_BLACKBORDERS_FS
35DEFINES += INITIAL_BLACKBORDERS
36DEFINES += CHROMECAST_SUPPORT
37
38DEFINES += MPV_SUPPORT
39DEFINES += MPLAYER_SUPPORT
40
41# Whether to include support for the obsolete mplayer2 or not
42# (requires MPLAYER_SUPPORT)
43DEFINES += MPLAYER2_SUPPORT
44
45# Note to distro maintainers:
46# By disabling SHARE_ACTIONS or SHARE_WIDGET
47# you're preventing SMPlayer to receive donations and thus
48# SERIOUSLY HURTING THE DEVELOPMENT AND PUTTING
49# AT RISK THE CONTINUATION OF THIS PROJECT
50# Please don't.
51
52#DEFINES += SHARE_ACTIONS
53#DEFINES += SHARE_WIDGET
54
55# If Qt >= 5.4
56greaterThan(QT_MAJOR_VERSION, 4):greaterThan(QT_MINOR_VERSION, 3) {
57 DEFINES += HDPI_SUPPORT
58}
59
60#DEFINES += SIMPLE_BUILD
61#DEFINES += IDOPT_BUILD
62
63contains( DEFINES, SIMPLE_BUILD ) {
64 DEFINES -= SINGLE_INSTANCE
65 DEFINES -= FIND_SUBTITLES
66 DEFINES -= VIDEOPREVIEW
67 DEFINES -= LOG_MPLAYER
68 DEFINES -= LOG_SMPLAYER
69 DEFINES -= MINIGUI
70 DEFINES -= MPCGUI
71 DEFINES -= SKINS
72 DEFINES -= MPRIS2
73 DEFINES -= UPDATE_CHECKER
74 DEFINES -= CHECK_UPGRADED
75 DEFINES -= SHARE_ACTIONS
76 DEFINES -= SHARE_WIDGET
77 DEFINES -= AUTO_SHUTDOWN_PC
78 DEFINES -= BOOKMARKS
79 DEFINES -= TV_SUPPORT
80 DEFINES -= CHROMECAST_SUPPORT
81}
82
83contains( DEFINES, IDOPT_BUILD ) {
84 DEFINES -= MPCGUI
85 DEFINES -= SKINS
86 DEFINES -= CAPTURE_STREAM
87 DEFINES -= TV_SUPPORT
88 DEFINES -= MPLAYER_SUPPORT
89 DEFINES -= MPLAYER2_SUPPORT
90}
91
92isEqual(QT_MAJOR_VERSION, 5) {
93 QT += widgets gui
94 #DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x040000
95 win32 {
96 DEFINES -= MPRIS2
97 }
98}
99
100contains(QT_VERSION, ^4\\.[0-3]\\..*) {
101 message("Some features requires Qt > 4.3.")
102
103 contains( DEFINES, SINGLE_INSTANCE ) {
104 DEFINES -= SINGLE_INSTANCE
105 message("SINGLE_INSTANCE disabled.")
106 }
107
108 contains( DEFINES, YOUTUBE_SUPPORT ) {
109 DEFINES -= YOUTUBE_SUPPORT
110 message("YOUTUBE_SUPPORT disabled.")
111 }
112
113 contains( DEFINES, SKINS ) {
114 DEFINES -= SKINS
115 message("SKINS disabled.")
116 }
117
118 contains( DEFINES, FIND_SUBTITLES ) {
119 DEFINES -= FIND_SUBTITLES
120 message("FIND_SUBTITLES disabled.")
121 }
122
123 contains( DEFINES, UPDATE_CHECKER ) {
124 DEFINES -= UPDATE_CHECKER
125 message("UPDATE_CHECKER disabled.")
126 }
127}
128
129contains( DEFINES, GLOBALSHORTCUTS ) {
130 lessThan(QT_MAJOR_VERSION, 5) {
131 DEFINES -= GLOBALSHORTCUTS
132 message("GLOBALSHORTCUTS requires Qt 5. Disabled.")
133 }
134}
135
136HEADERS += guiconfig.h \
137 config.h \
138 constants.h \
139 links.h \
140 svn_revision.h \
141 version.h \
142 chapters.h \
143 global.h \
144 paths.h \
145 helper.h \
146 colorutils.h \
147 translator.h \
148 subtracks.h \
149 tracks.h \
150 titletracks.h \
151 discname.h \
152 extensions.h \
153 desktopinfo.h \
154 myprocess.h \
155 mplayerversion.h \
156 playerid.h \
157 playerprocess.h \
158 infoprovider.h \
159 mplayerwindow.h \
160 mediadata.h \
161 audioequalizerlist.h \
162 mediasettings.h \
163 assstyles.h \
164 filters.h \
165 preferences.h \
166 filesettingsbase.h \
167 filesettings.h \
168 filesettingshash.h \
169 filehash.h \
170 images.h \
171 inforeader.h \
172 deviceinfo.h \
173 recents.h \
174 urlhistory.h \
175 core.h \
176 myscroller.h \
177 logwindow.h \
178 infowindow.h \
179 infofile.h \
180 seekwidget.h \
181 mytablewidget.h \
182 shortcutgetter.h \
183 actionseditor.h \
184 filechooser.h \
185 vdpauproperties.h \
186 preferencesdialog.h \
187 lineedit_with_icon.h \
188 mylineedit.h \
189 mycombobox.h \
190 tristatecombo.h \
191 languages.h \
192 selectcolorbutton.h \
193 prefwidget.h \
194 prefgeneral.h \
195 prefdrives.h \
196 prefinterface.h \
197 prefperformance.h \
198 prefinput.h \
199 prefsubtitles.h \
200 prefadvanced.h \
201 prefplaylist.h \
202 prefupdates.h \
203 prefnetwork.h \
204 filepropertiesdialog.h \
205 multilineinputdialog.h \
206 playlist.h \
207 playlistdock.h \
208 verticaltext.h \
209 eqslider.h \
210 videoequalizer.h \
211 audioequalizer.h \
212 myslider.h \
213 timeslider.h \
214 inputdvddirectory.h \
215 inputurl.h \
216 stereo3ddialog.h \
217 myaction.h \
218 myactiongroup.h \
219 filedialog.h \
220 inputmplayerversion.h \
221 about.h \
222 errordialog.h \
223 timedialog.h \
224 favorites.h \
225 favoriteeditor.h \
226 statewidget.h \
227 basegui.h \
228 baseguiplus.h \
229 autohidewidget.h \
230 widgetactions.h \
231 toolbareditor.h \
232 editabletoolbar.h \
233 clhelp.h \
234 cleanconfig.h \
235 smplayer.h \
236 myapplication.h
237
238
239SOURCES += version.cpp \
240 global.cpp \
241 paths.cpp \
242 chapters.cpp \
243 helper.cpp \
244 colorutils.cpp \
245 translator.cpp \
246 subtracks.cpp \
247 tracks.cpp \
248 titletracks.cpp \
249 discname.cpp \
250 extensions.cpp \
251 desktopinfo.cpp \
252 myprocess.cpp \
253 mplayerversion.cpp \
254 playerid.cpp \
255 playerprocess.cpp \
256 infoprovider.cpp \
257 mplayerwindow.cpp \
258 mediadata.cpp \
259 mediasettings.cpp \
260 assstyles.cpp \
261 filters.cpp \
262 preferences.cpp \
263 filesettingsbase.cpp \
264 filesettings.cpp \
265 filesettingshash.cpp \
266 filehash.cpp \
267 images.cpp \
268 inforeader.cpp \
269 deviceinfo.cpp \
270 recents.cpp \
271 urlhistory.cpp \
272 core.cpp \
273 myscroller.cpp \
274 logwindow.cpp \
275 infowindow.cpp \
276 infofile.cpp \
277 seekwidget.cpp \
278 mytablewidget.cpp \
279 shortcutgetter.cpp \
280 actionseditor.cpp \
281 filechooser.cpp \
282 vdpauproperties.cpp \
283 preferencesdialog.cpp \
284 lineedit_with_icon.cpp \
285 mylineedit.cpp \
286 mycombobox.cpp \
287 tristatecombo.cpp \
288 languages.cpp \
289 selectcolorbutton.cpp \
290 prefwidget.cpp \
291 prefgeneral.cpp \
292 prefdrives.cpp \
293 prefinterface.cpp \
294 prefperformance.cpp \
295 prefinput.cpp \
296 prefsubtitles.cpp \
297 prefadvanced.cpp \
298 prefplaylist.cpp \
299 prefupdates.cpp \
300 prefnetwork.cpp \
301 filepropertiesdialog.cpp \
302 multilineinputdialog.cpp \
303 playlist.cpp \
304 playlistdock.cpp \
305 verticaltext.cpp \
306 eqslider.cpp \
307 videoequalizer.cpp \
308 audioequalizer.cpp \
309 myslider.cpp \
310 timeslider.cpp \
311 inputdvddirectory.cpp \
312 inputurl.cpp \
313 stereo3ddialog.cpp \
314 myaction.cpp \
315 myactiongroup.cpp \
316 filedialog.cpp \
317 inputmplayerversion.cpp \
318 about.cpp \
319 errordialog.cpp \
320 timedialog.cpp \
321 favorites.cpp \
322 favoriteeditor.cpp \
323 statewidget.cpp \
324 basegui.cpp \
325 baseguiplus.cpp \
326 autohidewidget.cpp \
327 widgetactions.cpp \
328 toolbareditor.cpp \
329 editabletoolbar.cpp \
330 clhelp.cpp \
331 cleanconfig.cpp \
332 smplayer.cpp \
333 myapplication.cpp \
334 main.cpp
335
336FORMS = inputdvddirectory.ui logwindow.ui infowindow.ui filepropertiesdialog.ui \
337 eqslider.ui seekwidget.ui inputurl.ui videoequalizer.ui vdpauproperties.ui \
338 preferencesdialog.ui prefgeneral.ui prefdrives.ui prefinterface.ui \
339 prefperformance.ui prefinput.ui prefsubtitles.ui prefadvanced.ui \
340 prefplaylist.ui prefupdates.ui prefnetwork.ui favoriteeditor.ui \
341 about.ui inputmplayerversion.ui errordialog.ui timedialog.ui stereo3ddialog.ui \
342 toolbareditor.ui multilineinputdialog.ui
343
344contains( DEFINES, TV_SUPPORT ) {
345 HEADERS += tvlist.h preftv.h tvsettings.h
346 SOURCES += tvlist.cpp preftv.cpp tvsettings.cpp
347 FORMS += preftv.ui
348}
349
350contains( DEFINES, MPV_SUPPORT ) {
351 HEADERS += mpvprocess.h inforeadermpv.h
352 SOURCES += mpvprocess.cpp inforeadermpv.cpp
353}
354
355contains( DEFINES, MPLAYER_SUPPORT ) {
356 HEADERS += mplayerprocess.h inforeadermplayer.h
357 SOURCES += mplayerprocess.cpp inforeadermplayer.cpp
358}
359
360# qtsingleapplication
361contains( DEFINES, SINGLE_INSTANCE ) {
362 INCLUDEPATH += qtsingleapplication
363 DEPENDPATH += qtsingleapplication
364
365 SOURCES += qtsingleapplication/qtsingleapplication.cpp qtsingleapplication/qtlocalpeer.cpp
366 HEADERS += qtsingleapplication/qtsingleapplication.h qtsingleapplication/qtlocalpeer.h
367}
368
369# Find subtitles dialog
370contains( DEFINES, FIND_SUBTITLES ) {
371 DEFINES += DOWNLOAD_SUBS
372 DEFINES += OS_SEARCH_WORKAROUND
373 #DEFINES += USE_QUAZIP
374
375 INCLUDEPATH += findsubtitles
376 DEPENDPATH += findsubtitles
377
378 INCLUDEPATH += findsubtitles/maia
379 DEPENDPATH += findsubtitles/maia
380
381 HEADERS += findsubtitles/findsubtitlesconfigdialog.h findsubtitles/findsubtitleswindow.h
382 SOURCES += findsubtitles/findsubtitlesconfigdialog.cpp findsubtitles/findsubtitleswindow.cpp
383 FORMS += findsubtitles/findsubtitleswindow.ui findsubtitles/findsubtitlesconfigdialog.ui
384
385 # xmlrpc client code to connect to opensubtitles.org
386 HEADERS += findsubtitles/maia/maiaObject.h findsubtitles/maia/maiaFault.h findsubtitles/maia/maiaXmlRpcClient.h findsubtitles/osclient.h
387 SOURCES += findsubtitles/maia/maiaObject.cpp findsubtitles/maia/maiaFault.cpp findsubtitles/maia/maiaXmlRpcClient.cpp findsubtitles/osclient.cpp
388}
389
390# Download subtitles
391contains( DEFINES, DOWNLOAD_SUBS ) {
392 INCLUDEPATH += findsubtitles/filedownloader
393 DEPENDPATH += findsubtitles/filedownloader
394
395 HEADERS += findsubtitles/filedownloader/filedownloader.h findsubtitles/subchooserdialog.h findsubtitles/fixsubs.h
396 SOURCES += findsubtitles/filedownloader/filedownloader.cpp findsubtitles/subchooserdialog.cpp findsubtitles/fixsubs.cpp
397
398 FORMS += findsubtitles/subchooserdialog.ui
399
400 contains( DEFINES, USE_QUAZIP ) {
401 INCLUDEPATH += findsubtitles/quazip
402 DEPENDPATH += findsubtitles/quazip
403
404 HEADERS += crypt.h \
405 ioapi.h \
406 quazip.h \
407 quazipfile.h \
408 quazipfileinfo.h \
409 quazipnewinfo.h \
410 unzip.h \
411 zip.h
412
413 SOURCES += ioapi.c \
414 quazip.cpp \
415 quazipfile.cpp \
416 quazipnewinfo.cpp \
417 unzip.c \
418 zip.c
419}
420
421 LIBS += -lz
422
423 win32 {
424 INCLUDEPATH += ..\\zlib
425 LIBS += -L..\\zlib
426 }
427}
428
429# Youtube support
430contains( DEFINES, YOUTUBE_SUPPORT ) {
431 DEFINES += YT_USE_SCRIPT
432 INCLUDEPATH += youtube
433 DEPENDPATH += youtube
434
435 HEADERS += youtube/retrieveyoutubeurl.h youtube/loadpage.h
436 SOURCES += youtube/retrieveyoutubeurl.cpp youtube/loadpage.cpp
437
438 contains( DEFINES, YT_USE_SCRIPT ) {
439 DEFINES += YT_USE_SIG
440 DEFINES += YT_USE_YTSIG
441 QT += script
442 }
443
444 contains( DEFINES, YT_USE_SIG ) {
445 HEADERS += youtube/sig.h
446 SOURCES += youtube/sig.cpp
447 }
448
449 contains( DEFINES, YT_USE_YTSIG ) {
450 HEADERS += youtube/ytsig.h youtube/codedownloader.h
451 SOURCES += youtube/ytsig.cpp youtube/codedownloader.cpp
452 }
453}
454
455# defaultgui
456contains( DEFINES, DEFAULTGUI ) {
457 HEADERS += defaultgui.h
458 SOURCES += defaultgui.cpp
459}
460
461# minigui
462contains( DEFINES, MINIGUI ) {
463 HEADERS += minigui.h
464 SOURCES += minigui.cpp
465}
466
467# mpcgui
468contains( DEFINES, MPCGUI ) {
469 INCLUDEPATH += mpcgui
470 DEPENDPATH += mpcgui
471
472 HEADERS += mpcgui/mpcgui.h mpcgui/mpcstyles.h
473 SOURCES += mpcgui/mpcgui.cpp mpcgui/mpcstyles.cpp
474}
475
476# Skins support
477contains( DEFINES, SKINS ) {
478 INCLUDEPATH += skingui
479 DEPENDPATH += skingui
480
481 HEADERS += skingui/myicon.h skingui/mybutton.h skingui/panelseeker.h skingui/playcontrol.h \
482 skingui/mediapanel.h skingui/volumecontrolpanel.h skingui/mediabarpanel.h \
483 skingui/qpropertysetter.h skingui/actiontools.h skingui/skingui.h
484 SOURCES += skingui/myicon.cpp skingui/mybutton.cpp skingui/panelseeker.cpp skingui/playcontrol.cpp \
485 skingui/mediapanel.cpp skingui/volumecontrolpanel.cpp skingui/mediabarpanel.cpp \
486 skingui/qpropertysetter.cpp skingui/actiontools.cpp skingui/skingui.cpp
487 FORMS += skingui/mediapanel.ui skingui/mediabarpanel.ui
488}
489
490contains( DEFINES, MPRIS2 ) {
491 INCLUDEPATH += mpris2
492 DEPENDPATH += mpris2
493
494 HEADERS += mpris2/mediaplayer2.h mpris2/mediaplayer2player.h mpris2/mpris2.h
495 SOURCES += mpris2/mediaplayer2.cpp mpris2/mediaplayer2player.cpp mpris2/mpris2.cpp
496
497 QT += dbus
498}
499
500# Update checker
501contains( DEFINES, UPDATE_CHECKER ) {
502 HEADERS += updatechecker.h updatecheckerdata.h
503 SOURCES += updatechecker.cpp updatecheckerdata.cpp
504}
505
506# Videopreview
507contains( DEFINES, VIDEOPREVIEW ) {
508 INCLUDEPATH += videopreview
509 DEPENDPATH += videopreview
510
511 HEADERS += videopreview/videopreview.h videopreview/videopreviewconfigdialog.h
512 SOURCES += videopreview/videopreview.cpp videopreview/videopreviewconfigdialog.cpp
513
514 FORMS += videopreview/videopreviewconfigdialog.ui
515}
516
517
518contains( DEFINES, SHARE_ACTIONS ) {
519 HEADERS += sharedialog.h
520 SOURCES += sharedialog.cpp
521 FORMS += sharedialog.ui
522}
523
524contains( DEFINES, SHARE_WIDGET|SHARE_ACTIONS ) {
525 HEADERS += sharewidget.h sharedata.h
526 SOURCES += sharewidget.cpp sharedata.cpp
527}
528
529contains( DEFINES, AUTO_SHUTDOWN_PC ) {
530 HEADERS += shutdowndialog.h shutdown.h
531 SOURCES += shutdowndialog.cpp shutdown.cpp
532 FORMS += shutdowndialog.ui
533
534 unix { QT += dbus }
535}
536
537contains( DEFINES, BOOKMARKS ) {
538 HEADERS += inputbookmark.h bookmarkdialog.h
539 SOURCES += inputbookmark.cpp bookmarkdialog.cpp
540 FORMS += inputbookmark.ui bookmarkdialog.ui
541}
542
543contains( DEFINES, GLOBALSHORTCUTS ) {
544 HEADERS += globalshortcuts/globalshortcuts.h
545 SOURCES += globalshortcuts/globalshortcuts.cpp
546 unix {
547 QT += gui-private
548 LIBS += $${QMAKE_LIBS_X11}
549 }
550}
551
552contains( DEFINES, HDPI_SUPPORT ) {
553 HEADERS += hdpisupport.h
554 SOURCES += hdpisupport.cpp
555}
556
557contains( DEFINES, CHROMECAST_SUPPORT ) {
558 HEADERS += chromecast.h
559 SOURCES += chromecast.cpp
560}
561
562unix {
563 UI_DIR = .ui
564 MOC_DIR = .moc
565 OBJECTS_DIR = .obj
566
567 DEFINES += DATA_PATH=$(DATA_PATH)
568 DEFINES += DOC_PATH=$(DOC_PATH)
569 DEFINES += TRANSLATION_PATH=$(TRANSLATION_PATH)
570 DEFINES += THEMES_PATH=$(THEMES_PATH)
571 DEFINES += SHORTCUTS_PATH=$(SHORTCUTS_PATH)
572 #DEFINES += NO_DEBUG_ON_CONSOLE
573
574 ### PulseAudio
575 #CONFIG += link_pkgconfig
576 #PKGCONFIG += libpulse-mainloop-glib
577}
578
579win32 {
580 DEFINES += SCREENSAVER_OFF
581 DEFINES += AVOID_SCREENSAVER
582 #DEFINES += FONTCACHE_DIALOG
583 #DEFINES += FONTS_HACK
584
585 contains( DEFINES, SCREENSAVER_OFF ) {
586 HEADERS += screensaver.h
587 SOURCES += screensaver.cpp
588 }
589
590 contains( DEFINES, FONTCACHE_DIALOG ) {
591 HEADERS += fontcache.h
592 SOURCES += fontcache.cpp
593 }
594
595 !contains( DEFINES, PORTABLE_APP ) {
596 DEFINES += USE_ASSOCIATIONS
597 } else {
598 DEFINES -= HDPI_SUPPORT
599 }
600
601 contains( DEFINES, USE_ASSOCIATIONS ) {
602 HEADERS += prefassociations.h winfileassoc.h
603 SOURCES += prefassociations.cpp winfileassoc.cpp
604 FORMS += prefassociations.ui
605 }
606
607 contains(TEMPLATE,vcapp) {
608 LIBS += ole32.lib user32.lib
609 } else {
610 LIBS += libole32
611 }
612
613 LIBS += -ldsound -lddraw
614
615 RC_FILE = smplayer.rc
616 DEFINES += NO_DEBUG_ON_CONSOLE
617 #debug {
618 # CONFIG += console
619 #}
620}
621
622os2 {
623 DEFINES += SCREENSAVER_OFF
624 INCLUDEPATH += .
625 contains( DEFINES, SCREENSAVER_OFF ) {
626 HEADERS += screensaver.h
627 SOURCES += screensaver.cpp
628 }
629 RC_FILE = smplayer_os2.rc
630}
631
632
633TRANSLATIONS = translations/smplayer_es.ts translations/smplayer_de.ts \
634 translations/smplayer_sk.ts translations/smplayer_it.ts \
635 translations/smplayer_fr.ts translations/smplayer_zh_CN.ts \
636 translations/smplayer_ru_RU.ts translations/smplayer_hu.ts \
637 translations/smplayer_en.ts translations/smplayer_pl.ts \
638 translations/smplayer_ja.ts translations/smplayer_nl.ts \
639 translations/smplayer_uk_UA.ts translations/smplayer_pt_BR.ts \
640 translations/smplayer_ka.ts translations/smplayer_cs.ts \
641 translations/smplayer_bg.ts translations/smplayer_tr.ts \
642 translations/smplayer_sv.ts translations/smplayer_sr.ts \
643 translations/smplayer_zh_TW.ts translations/smplayer_ro_RO.ts \
644 translations/smplayer_pt.ts translations/smplayer_el.ts \
645 translations/smplayer_fi.ts translations/smplayer_ko.ts \
646 translations/smplayer_mk.ts translations/smplayer_eu.ts \
647 translations/smplayer_ca.ts translations/smplayer_sl_SI.ts \
648 translations/smplayer_ar_SY.ts translations/smplayer_ku.ts \
649 translations/smplayer_gl.ts translations/smplayer_vi_VN.ts \
650 translations/smplayer_et.ts translations/smplayer_lt.ts \
651 translations/smplayer_da.ts translations/smplayer_hr.ts \
652 translations/smplayer_he_IL.ts translations/smplayer_th.ts \
653 translations/smplayer_ms_MY.ts translations/smplayer_uz.ts \
654 translations/smplayer_nn_NO.ts translations/smplayer_id.ts \
655 translations/smplayer_ar.ts translations/smplayer_en_GB.ts \
656 translations/smplayer_sq_AL.ts translations/smplayer_am.ts \
657 translations/smplayer_fa.ts translations/smplayer_en_US.ts
658
Note: See TracBrowser for help on using the repository browser.