source: psi/trunk/src/src.pro@ 162

Last change on this file since 162 was 56, checked in by dmik, 19 years ago

Psi: General: All output directories are made OS-specific (by adding the OS name to the path), to make it possible to build Psi for different platforms from a single source tree.
File size: 6.9 KB
Line 
1#
2# Psi qmake profile
3#
4
5# Configuration
6TEMPLATE = app
7CONFIG += qt thread x11
8
9#CONFIG += use_crash
10#DEFINES += GPG_DEBUG
11
12os2:DEFINES += MAP_NDNS_TO_QDNS
13
14# Executable name
15TARGET = psi
16
17OS = unknown
18os2:OS = os2
19win32:OS = win
20unix:OS = nix
21mac:OS = mac
22
23DESTDIR = ../psi$$OS
24
25debug: {
26 MOC_DIR = .debug/.$$OS/.moc
27 OBJECTS_DIR = .debug/.$$OS/.obj
28 UI_DIR = .debug/.$$OS/.ui
29} else {
30 MOC_DIR = .$$OS/.moc
31 OBJECTS_DIR = .$$OS/.obj
32 UI_DIR = .$$OS/.ui
33}
34
35# qconf
36exists(../conf.pri) {
37 include(../conf.pri)
38
39 # Shared files
40 sharedfiles.path = $$DATADIR
41 sharedfiles.files = ../README ../COPYING ../iconsets ../sound ../certs
42 INSTALLS += sharedfiles
43
44 # Widgets
45 #widgets.path = $$DATADIR/designer
46 #widgets.files = ../libpsi/psiwidgets/libpsiwidgets.so
47 #INSTALLS += widgets
48
49 # icons and desktop files
50 dt.path=$$PREFIX/share/applications/
51 dt.files = ../psi.desktop
52 icon1.path=$$PREFIX/share/icons/hicolor/16x16/apps
53 icon1.extra = cp -f ../iconsets/system/default/icon_16.png $(INSTALL_ROOT)$$icon1.path/psi.png
54 icon2.path=$$PREFIX/share/icons/hicolor/32x32/apps
55 icon2.extra = cp -f ../iconsets/system/default/icon_32.png $(INSTALL_ROOT)$$icon2.path/psi.png
56 icon3.path=$$PREFIX/share/icons/hicolor/48x48/apps
57 icon3.extra = cp -f ../iconsets/system/default/icon_48.png $(INSTALL_ROOT)$$icon3.path/psi.png
58 INSTALLS += dt icon1 icon2 icon3
59}
60
61win32: {
62 include(../conf_win32.pri)
63}
64os2: {
65 include(../conf_os2.pri)
66}
67
68# qxml
69!isEmpty(QXML_STATIC) {
70 unix: {
71 INCLUDEPATH += tools/qxml
72 HEADERS += tools/qxml/qxml.h tools/qxml/qdom.h
73 SOURCES += tools/qxml/qxml.cpp tools/qxml/qdom.cpp
74 }
75}
76
77# IPv6 ?
78#DEFINES += NO_NDNS
79
80# include some of cutestuff
81CONFIG += psics
82IRISCS_CPP = ../../cutestuff
83exists(../cutestuff) {
84 IRISCS_CPP = ../cutestuff
85}
86PSICS_CPP = tools
87include(../psics.pri)
88
89# qca
90#DEFINES += QCA_STATIC
91#QCA_PREFIX = ../qca
92#!exists(../qca) {
93# QCA_PREFIX = ../../qca/src
94#}
95#INCLUDEPATH += $$QCA_PREFIX
96#HEADERS += $$QCA_PREFIX/qca.h $$QCA_PREFIX/qcaprovider.h
97#SOURCES += $$QCA_PREFIX/qca.cpp
98
99# libxmpp
100#CONFIG += xmpp
101#XMPP_BASE = ../../xmpp
102#exists(../xmpp) {
103# XMPP_BASE = ../xmpp
104#}
105#include($$XMPP_BASE/xmpp.pri)
106
107# include Iris XMPP library
108#CONFIG += iris
109IRIS_BASE = ../../iris
110exists(../iris) {
111 IRIS_BASE = ../iris
112}
113include(../iris.pri)
114
115# include Psi library
116CONFIG += libpsi
117LIBPSI_CPP = ../../libpsi
118exists(../libpsi) {
119 LIBPSI_CPP = ../libpsi
120}
121include(../libpsi.pri)
122
123# Psi sources
124PSI_CPP = .
125
126# Header files
127HEADERS += \
128 $$PSI_CPP/varlist.h \
129 $$PSI_CPP/showtextdlg.h \
130 $$PSI_CPP/profiles.h \
131 $$PSI_CPP/profiledlg.h \
132 $$PSI_CPP/main.h \
133 $$PSI_CPP/psiaccount.h \
134 $$PSI_CPP/psicon.h \
135 $$PSI_CPP/psievent.h \
136 $$PSI_CPP/xmlconsole.h \
137 $$PSI_CPP/contactview.h \
138 $$PSI_CPP/psiiconset.h \
139 $$PSI_CPP/userlist.h \
140 $$PSI_CPP/mainwin.h \
141 $$PSI_CPP/mainwin_p.h \
142 $$PSI_CPP/rtparse.h \
143 $$PSI_CPP/common.h \
144 $$PSI_CPP/proxy.h \
145 $$PSI_CPP/accountdlg.h \
146 $$PSI_CPP/changepwdlg.h \
147 $$PSI_CPP/msgmle.h \
148 $$PSI_CPP/statusdlg.h \
149 $$PSI_CPP/eventdlg.h \
150 $$PSI_CPP/chatdlg.h \
151 $$PSI_CPP/tabdlg.h \
152 $$PSI_CPP/adduserdlg.h \
153 $$PSI_CPP/groupchatdlg.h \
154 $$PSI_CPP/infodlg.h \
155 $$PSI_CPP/eventdb.h \
156 $$PSI_CPP/historydlg.h \
157 $$PSI_CPP/servicesdlg.h \
158 $$PSI_CPP/jltest.h \
159# $$PSI_CPP/browserdlg.h \
160 $$PSI_CPP/psitoolbar.h \
161 $$PSI_CPP/passphrasedlg.h \
162 $$PSI_CPP/vcardfactory.h \
163 $$PSI_CPP/sslcertdlg.h \
164 $$PSI_CPP/qwextend.h \
165 $$PSI_CPP/tasklist.h \
166 $$PSI_CPP/discodlg.h \
167 $$PSI_CPP/alerticon.h \
168 $$PSI_CPP/psipopup.h \
169 $$PSI_CPP/psiapplication.h \
170 $$PSI_CPP/filetransdlg.h \
171 $$PSI_CPP/avatars.h \
172 $$PSI_CPP/actionlist.h \
173 $$PSI_CPP/psiactionlist.h \
174 $$PSI_CPP/xdata_widget.h \
175 $$PSI_CPP/xmpp_xdata.h
176
177# Source files
178SOURCES += \
179 $$PSI_CPP/varlist.cpp \
180 $$PSI_CPP/showtextdlg.cpp \
181 $$PSI_CPP/psi_profiles.cpp \
182 $$PSI_CPP/profiledlg.cpp \
183 $$PSI_CPP/main.cpp \
184 $$PSI_CPP/psiaccount.cpp \
185 $$PSI_CPP/psicon.cpp \
186 $$PSI_CPP/psievent.cpp \
187 $$PSI_CPP/xmlconsole.cpp \
188 $$PSI_CPP/contactview.cpp \
189 $$PSI_CPP/psiiconset.cpp \
190 $$PSI_CPP/userlist.cpp \
191 $$PSI_CPP/mainwin.cpp \
192 $$PSI_CPP/mainwin_p.cpp \
193 $$PSI_CPP/rtparse.cpp \
194 $$PSI_CPP/common.cpp \
195 $$PSI_CPP/proxy.cpp \
196 $$PSI_CPP/accountdlg.cpp \
197 $$PSI_CPP/changepwdlg.cpp \
198 $$PSI_CPP/msgmle.cpp \
199 $$PSI_CPP/statusdlg.cpp \
200 $$PSI_CPP/eventdlg.cpp \
201 $$PSI_CPP/chatdlg.cpp \
202 $$PSI_CPP/tabdlg.cpp \
203 $$PSI_CPP/adduserdlg.cpp \
204 $$PSI_CPP/groupchatdlg.cpp \
205 $$PSI_CPP/infodlg.cpp \
206 $$PSI_CPP/eventdb.cpp \
207 $$PSI_CPP/historydlg.cpp \
208 $$PSI_CPP/servicesdlg.cpp \
209 $$PSI_CPP/jltest.cpp \
210# $$PSI_CPP/browserdlg.cpp \
211 $$PSI_CPP/psitoolbar.cpp \
212 $$PSI_CPP/passphrasedlg.cpp \
213 $$PSI_CPP/vcardfactory.cpp \
214 $$PSI_CPP/sslcertdlg.cpp \
215 $$PSI_CPP/qwextend.cpp \
216 $$PSI_CPP/discodlg.cpp \
217 $$PSI_CPP/alerticon.cpp \
218 $$PSI_CPP/psipopup.cpp \
219 $$PSI_CPP/psiapplication.cpp \
220 $$PSI_CPP/filetransdlg.cpp \
221 $$PSI_CPP/avatars.cpp \
222 $$PSI_CPP/actionlist.cpp \
223 $$PSI_CPP/psiactionlist.cpp \
224 $$PSI_CPP/xdata_widget.cpp \
225 $$PSI_CPP/xmpp_xdata.cpp
226mac {
227 contains( DEFINES, HAVE_GROWL ) {
228 HEADERS += $$PSI_CPP/psigrowlnotifier.h
229 SOURCES += $$PSI_CPP/psigrowlnotifier.cpp
230 }
231}
232
233# Qt Designer interfaces
234INTERFACES = \
235 $$PSI_CPP/ui_profileopen.ui \
236 $$PSI_CPP/ui_profilemanage.ui \
237 $$PSI_CPP/ui_profilenew.ui \
238 $$PSI_CPP/ui_proxy.ui \
239 $$PSI_CPP/ui_pgpkey.ui \
240 $$PSI_CPP/ui_accountmanage.ui \
241 $$PSI_CPP/ui_accountadd.ui \
242 $$PSI_CPP/ui_accountreg.ui \
243 $$PSI_CPP/ui_accountremove.ui \
244 $$PSI_CPP/ui_accountmodify.ui \
245 $$PSI_CPP/ui_changepw.ui \
246 $$PSI_CPP/ui_addurl.ui \
247 $$PSI_CPP/ui_adduser.ui \
248 $$PSI_CPP/ui_gcjoin.ui \
249 $$PSI_CPP/ui_info.ui \
250 $$PSI_CPP/ui_search.ui \
251 $$PSI_CPP/ui_about.ui \
252# $$PSI_CPP/ui_browser.ui \
253 $$PSI_CPP/ui_passphrase.ui \
254 $$PSI_CPP/ui_sslcert.ui \
255 $$PSI_CPP/ui_disco.ui \
256 $$PSI_CPP/ui_tip.ui \
257 $$PSI_CPP/ui_filetrans.ui
258
259# options dialog
260include(options/options.pri)
261
262LANG_PATH = ../lang
263
264# Translations
265TRANSLATIONS = \
266 $$LANG_PATH/psi_ar.ts \
267 $$LANG_PATH/psi_ca.ts \
268 $$LANG_PATH/psi_cs.ts \
269 $$LANG_PATH/psi_da.ts \
270 $$LANG_PATH/psi_de.ts \
271 $$LANG_PATH/psi_el.ts \
272 $$LANG_PATH/psi_eo.ts \
273 $$LANG_PATH/psi_es.ts \
274 $$LANG_PATH/psi_fi.ts \
275 $$LANG_PATH/psi_fr.ts \
276 $$LANG_PATH/psi_it.ts \
277 $$LANG_PATH/psi_jp.ts \
278 $$LANG_PATH/psi_mk.ts \
279 $$LANG_PATH/psi_nl.ts \
280 $$LANG_PATH/psi_pl.ts \
281 $$LANG_PATH/psi_pt.ts \
282 $$LANG_PATH/psi_ptbr.ts \
283 $$LANG_PATH/psi_ru.ts \
284 $$LANG_PATH/psi_se.ts \
285 $$LANG_PATH/psi_sk.ts \
286 $$LANG_PATH/psi_sr.ts \
287 $$LANG_PATH/psi_zh.ts
288
289# Platform specifics
290unix:!mac {
291 QMAKE_POST_LINK = rm -f ../psi ; ln -s src/psi ../psi
292}
293win32: {
294 RC_FILE = ../win32/psi_win32.rc
295
296 # buggy MSVC workaround
297 contains(MAKEFILE_GENERATOR, MSVC): QMAKE_LFLAGS += /FORCE:MULTIPLE
298 contains(MAKEFILE_GENERATOR, MSVC.NET): QMAKE_LFLAGS += /FORCE:MULTIPLE
299}
300os2: {
301 RC_FILE = ../os2/psi_os2.rc
302}
303mac: {
304 QMAKE_LFLAGS += -framework Carbon -framework IOKit
305 QMAKE_INFO_PLIST = ../mac/Info.plist
306 RC_FILE = ../mac/application.icns
307 QMAKE_POST_LINK = cp -R ../COPYING ../README ../certs ../iconsets ../sound $(DESTDIR)../Resources ; echo "APPLpsi " > $(DESTDIR)../PkgInfo
308}
Note: See TracBrowser for help on using the repository browser.