source: trunk/src/src.pro@ 819

Last change on this file since 819 was 769, checked in by Dmitry A. Kuminov, 15 years ago

trunk: Merged in qt 4.6.3 sources from branches/vendor/nokia/qt.
File size: 7.7 KB
Line 
1TEMPLATE = subdirs
2
3# this order is important
4unset(SRC_SUBDIRS)
5win32:SRC_SUBDIRS += src_winmain
6wince*:{
7 SRC_SUBDIRS += src_corelib src_xml src_gui src_sql src_network src_testlib
8} else:symbian {
9 SRC_SUBDIRS += src_s60main src_corelib src_xml src_gui src_network src_sql src_testlib src_s60installs
10} else {
11 SRC_SUBDIRS += src_corelib src_xml src_network src_gui src_sql src_testlib
12 !vxworks:contains(QT_CONFIG, qt3support): SRC_SUBDIRS += src_qt3support
13 include(tools/tools.pro)
14 contains(QT_CONFIG, dbus):SRC_SUBDIRS += src_dbus
15}
16win32:SRC_SUBDIRS += src_activeqt
17
18contains(QT_CONFIG, opengl)|contains(QT_CONFIG, opengles1)|contains(QT_CONFIG, opengles2): SRC_SUBDIRS += src_opengl
19contains(QT_CONFIG, openvg): SRC_SUBDIRS += src_openvg
20contains(QT_CONFIG, xmlpatterns): SRC_SUBDIRS += src_xmlpatterns
21contains(QT_CONFIG, phonon): SRC_SUBDIRS += src_phonon
22contains(QT_CONFIG, multimedia): SRC_SUBDIRS += src_multimedia
23contains(QT_CONFIG, svg): SRC_SUBDIRS += src_svg
24contains(QT_CONFIG, webkit) {
25 #exists($$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore/JavaScriptCore.pro): SRC_SUBDIRS += src_javascriptcore
26 SRC_SUBDIRS += src_webkit
27}
28contains(QT_CONFIG, script): SRC_SUBDIRS += src_script
29contains(QT_CONFIG, scripttools): SRC_SUBDIRS += src_scripttools
30contains(QT_CONFIG, declarative): SRC_SUBDIRS += src_declarative
31SRC_SUBDIRS += src_plugins
32
33os2:SRC_SUBDIRS += src_xsystray
34
35src_s60main.subdir = $$QT_SOURCE_TREE/src/s60main
36src_s60main.target = sub-s60main
37src_s60installs.subdir = $$QT_SOURCE_TREE/src/s60installs
38src_s60installs.target = sub-s60installs
39src_winmain.subdir = $$QT_SOURCE_TREE/src/winmain
40src_winmain.target = sub-winmain
41src_corelib.subdir = $$QT_SOURCE_TREE/src/corelib
42src_corelib.target = sub-corelib
43src_xml.subdir = $$QT_SOURCE_TREE/src/xml
44src_xml.target = sub-xml
45src_xmlpatterns.subdir = $$QT_SOURCE_TREE/src/xmlpatterns
46src_xmlpatterns.target = sub-xmlpatterns
47src_dbus.subdir = $$QT_SOURCE_TREE/src/dbus
48src_dbus.target = sub-dbus
49src_gui.subdir = $$QT_SOURCE_TREE/src/gui
50src_gui.target = sub-gui
51src_sql.subdir = $$QT_SOURCE_TREE/src/sql
52src_sql.target = sub-sql
53src_network.subdir = $$QT_SOURCE_TREE/src/network
54src_network.target = sub-network
55src_svg.subdir = $$QT_SOURCE_TREE/src/svg
56src_svg.target = sub-svg
57src_script.subdir = $$QT_SOURCE_TREE/src/script
58src_script.target = sub-script
59src_scripttools.subdir = $$QT_SOURCE_TREE/src/scripttools
60src_scripttools.target = sub-scripttools
61src_opengl.subdir = $$QT_SOURCE_TREE/src/opengl
62src_opengl.target = sub-opengl
63src_openvg.subdir = $$QT_SOURCE_TREE/src/openvg
64src_openvg.target = sub-openvg
65src_qt3support.subdir = $$QT_SOURCE_TREE/src/qt3support
66src_qt3support.target = sub-qt3support
67src_phonon.subdir = $$QT_SOURCE_TREE/src/phonon
68src_phonon.target = sub-phonon
69src_multimedia.subdir = $$QT_SOURCE_TREE/src/multimedia
70src_multimedia.target = sub-multimedia
71src_activeqt.subdir = $$QT_SOURCE_TREE/src/activeqt
72src_activeqt.target = sub-activeqt
73src_plugins.subdir = $$QT_SOURCE_TREE/src/plugins
74src_plugins.target = sub-plugins
75src_testlib.subdir = $$QT_SOURCE_TREE/src/testlib
76src_testlib.target = sub-testlib
77src_javascriptcore.subdir = $$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore
78src_javascriptcore.target = sub-javascriptcore
79src_webkit.subdir = $$QT_SOURCE_TREE/src/3rdparty/webkit/WebCore
80src_webkit.target = sub-webkit
81src_declarative.subdir = $$QT_SOURCE_TREE/src/declarative
82src_declarative.target = sub-declarative
83src_xsystray.subdir = $$QT_SOURCE_TREE/src/3rdparty/os2/xsystray
84src_xsystray.target = sub-xsystray
85
86#CONFIG += ordered
87!wince*:!symbian:!ordered {
88 src_corelib.depends = src_tools_moc src_tools_rcc
89 src_gui.depends = src_corelib src_tools_uic
90 embedded: src_gui.depends += src_network
91 src_xml.depends = src_corelib
92 src_xmlpatterns.depends = src_corelib src_network
93 src_dbus.depends = src_corelib src_xml
94 src_svg.depends = src_xml src_gui
95 src_script.depends = src_corelib
96 src_scripttools.depends = src_script src_gui src_network
97 src_network.depends = src_corelib
98 src_opengl.depends = src_gui
99 src_openvg.depends = src_gui
100 src_sql.depends = src_corelib
101 src_testlib.depends = src_corelib
102 src_qt3support.depends = src_gui src_xml src_network src_sql
103 src_tools_idc.depends = src_corelib # target defined in tools.pro
104 src_tools_uic3.depends = src_qt3support src_xml # target defined in tools.pro
105 src_phonon.depends = src_gui
106 src_multimedia.depends = src_gui
107 src_tools_activeqt.depends = src_tools_idc src_gui
108 src_declarative.depends = src_xml src_gui src_script src_network src_svg
109 src_plugins.depends = src_gui src_sql src_svg
110 contains(QT_CONFIG, webkit) {
111 src_webkit.depends = src_gui src_sql src_network src_xml
112 contains(QT_CONFIG, phonon):src_webkit.depends += src_phonon
113 contains(QT_CONFIG, xmlpatterns): src_webkit.depends += src_xmlpatterns
114 contains(QT_CONFIG, declarative):src_declarative.depends += src_webkit
115 #exists($$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore/JavaScriptCore.pro): src_webkit.depends += src_javascriptcore
116 }
117 contains(QT_CONFIG, qt3support): src_plugins.depends += src_qt3support
118 contains(QT_CONFIG, dbus):{
119 src_plugins.depends += src_dbus
120 src_phonon.depends += src_dbus
121 }
122 contains(QT_CONFIG, opengl)|contains(QT_CONFIG, opengles1)|contains(QT_CONFIG, opengles2): src_plugins.depends += src_opengl
123}
124
125!symbian {
126# This creates a sub-src rule
127sub_src_target.CONFIG = recursive
128sub_src_target.recurse = $$TOOLS_SUBDIRS $$SRC_SUBDIRS
129sub_src_target.target = sub-src
130sub_src_target.recurse_target =
131QMAKE_EXTRA_TARGETS += sub_src_target
132
133# This gives us a top level debug/release
134for(subname, SRC_SUBDIRS) {
135 subdir = $$subname
136 !isEmpty($${subname}.subdir):subdir = $$eval($${subname}.subdir)
137 subpro = $$subdir/$${basename(subdir)}.pro
138 !exists($$subpro):next()
139 subtarget = $$replace(subdir, [^A-Za-z0-9], _)
140 reg_src = $$replace(QT_SOURCE_TREE, \\\\, \\\\)
141 subdir = $$replace(subdir, $$reg_src, $$QT_BUILD_TREE)
142 subdir = $$replace(subdir, /, $$QMAKE_DIR_SEP)
143 subdir = $$replace(subdir, \\\\, $$QMAKE_DIR_SEP)
144 SUB_TEMPLATE = $$list($$fromfile($$subpro, TEMPLATE))
145 !isEqual(subname, src_tools_bootstrap):if(isEqual($$SUB_TEMPLATE, lib) | isEqual($$SUB_TEMPLATE, subdirs) | isEqual(subname, src_tools_idc) | isEqual(subname, src_tools_uic3)):!separate_debug_info {
146 #debug
147 eval(debug-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_DEBUG_TARGETS)
148 eval(debug-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) debug))
149 EXTRA_DEBUG_TARGETS += debug-$${subtarget}
150 QMAKE_EXTRA_TARGETS += debug-$${subtarget}
151 #release
152 eval(release-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_RELEASE_TARGETS)
153 eval(release-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) release))
154 EXTRA_RELEASE_TARGETS += release-$${subtarget}
155 QMAKE_EXTRA_TARGETS += release-$${subtarget}
156 } else { #do not have a real debug target/release
157 #debug
158 eval(debug-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_DEBUG_TARGETS)
159 eval(debug-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) first))
160 EXTRA_DEBUG_TARGETS += debug-$${subtarget}
161 QMAKE_EXTRA_TARGETS += debug-$${subtarget}
162 #release
163 eval(release-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_RELEASE_TARGETS)
164 eval(release-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) first))
165 EXTRA_RELEASE_TARGETS += release-$${subtarget}
166 QMAKE_EXTRA_TARGETS += release-$${subtarget}
167 }
168}
169debug.depends = $$EXTRA_DEBUG_TARGETS
170release.depends = $$EXTRA_RELEASE_TARGETS
171QMAKE_EXTRA_TARGETS += debug release
172}
173
174SUBDIRS += $$SRC_SUBDIRS
Note: See TracBrowser for help on using the repository browser.