| 1 | #####################################################################
|
|---|
| 2 | # Main projectfile
|
|---|
| 3 | #####################################################################
|
|---|
| 4 |
|
|---|
| 5 | CONFIG += ordered
|
|---|
| 6 | TEMPLATE = subdirs
|
|---|
| 7 |
|
|---|
| 8 | cross_compile: CONFIG += nostrip
|
|---|
| 9 |
|
|---|
| 10 | isEmpty(QT_BUILD_PARTS) { #defaults
|
|---|
| 11 | QT_BUILD_PARTS = libs tools examples demos docs translations
|
|---|
| 12 | } else { #make sure the order makes sense
|
|---|
| 13 | contains(QT_BUILD_PARTS, tools) {
|
|---|
| 14 | QT_BUILD_PARTS -= tools
|
|---|
| 15 | QT_BUILD_PARTS = tools $$QT_BUILD_PARTS
|
|---|
| 16 | }
|
|---|
| 17 | os2:contains(QT_BUILD_PARTS, qmake) {
|
|---|
| 18 | # non-bootstrapped qmake needs libs so don't put it before
|
|---|
| 19 | QT_BUILD_PARTS -= qmake
|
|---|
| 20 | QT_BUILD_PARTS = qmake $$QT_BUILD_PARTS
|
|---|
| 21 | }
|
|---|
| 22 | contains(QT_BUILD_PARTS, libs) {
|
|---|
| 23 | QT_BUILD_PARTS -= libs
|
|---|
| 24 | QT_BUILD_PARTS = libs $$QT_BUILD_PARTS
|
|---|
| 25 | }
|
|---|
| 26 | !os2:contains(QT_BUILD_PARTS, qmake) {
|
|---|
| 27 | QT_BUILD_PARTS -= qmake
|
|---|
| 28 | QT_BUILD_PARTS = qmake $$QT_BUILD_PARTS
|
|---|
| 29 | }
|
|---|
| 30 | }
|
|---|
| 31 |
|
|---|
| 32 | #process the projects
|
|---|
| 33 | for(PROJECT, $$list($$lower($$unique(QT_BUILD_PARTS)))) {
|
|---|
| 34 | isEqual(PROJECT, tools) {
|
|---|
| 35 | SUBDIRS += tools
|
|---|
| 36 | } else:isEqual(PROJECT, examples) {
|
|---|
| 37 | SUBDIRS += examples
|
|---|
| 38 | } else:isEqual(PROJECT, demos) {
|
|---|
| 39 | SUBDIRS += demos
|
|---|
| 40 | } else:isEqual(PROJECT, libs) {
|
|---|
| 41 | include(src/src.pro)
|
|---|
| 42 | } else:isEqual(PROJECT, docs) {
|
|---|
| 43 | contains(QT_BUILD_PARTS, tools):include(doc/doc.pri)
|
|---|
| 44 | } else:isEqual(PROJECT, translations) {
|
|---|
| 45 | contains(QT_BUILD_PARTS, tools):include(translations/translations.pri)
|
|---|
| 46 | } else:isEqual(PROJECT, qmake) {
|
|---|
| 47 | os2:SUBDIRS += qmake
|
|---|
| 48 | } else {
|
|---|
| 49 | message(Unknown PROJECT: $$PROJECT)
|
|---|
| 50 | }
|
|---|
| 51 | }
|
|---|
| 52 |
|
|---|
| 53 | confclean.depends += clean
|
|---|
| 54 | confclean.commands =
|
|---|
| 55 | unix {
|
|---|
| 56 | confclean.commands += (cd config.tests/unix/stl && $(MAKE) distclean); \
|
|---|
| 57 | (cd config.tests/unix/endian && $(MAKE) distclean); \
|
|---|
| 58 | (cd config.tests/unix/ipv6 && $(MAKE) distclean); \
|
|---|
| 59 | (cd config.tests/unix/largefile && $(MAKE) distclean); \
|
|---|
| 60 | (cd config.tests/unix/ptrsize && $(MAKE) distclean); \
|
|---|
| 61 | (cd config.tests/x11/notype && $(MAKE) distclean); \
|
|---|
| 62 | (cd config.tests/unix/getaddrinfo && $(MAKE) distclean); \
|
|---|
| 63 | (cd config.tests/unix/cups && $(MAKE) distclean); \
|
|---|
| 64 | (cd config.tests/unix/psql && $(MAKE) distclean); \
|
|---|
| 65 | (cd config.tests/unix/mysql && $(MAKE) distclean); \
|
|---|
| 66 | (cd config.tests/unix/mysql_r && $(MAKE) distclean); \
|
|---|
| 67 | (cd config.tests/unix/nis && $(MAKE) distclean); \
|
|---|
| 68 | (cd config.tests/unix/nix && $(MAKE) distclean); \
|
|---|
| 69 | (cd config.tests/unix/odbc && $(MAKE) distclean); \
|
|---|
| 70 | (cd config.tests/unix/oci && $(MAKE) distclean); \
|
|---|
| 71 | (cd config.tests/unix/tds && $(MAKE) distclean); \
|
|---|
| 72 | (cd config.tests/unix/db2 && $(MAKE) distclean); \
|
|---|
| 73 | (cd config.tests/unix/ibase && $(MAKE) distclean); \
|
|---|
| 74 | (cd config.tests/unix/ipv6ifname && $(MAKE) distclean); \
|
|---|
| 75 | (cd config.tests/unix/zlib && $(MAKE) distclean); \
|
|---|
| 76 | (cd config.tests/unix/libmng && $(MAKE) distclean); \
|
|---|
| 77 | (cd config.tests/unix/sqlite2 && $(MAKE) distclean); \
|
|---|
| 78 | (cd config.tests/unix/libjpeg && $(MAKE) distclean); \
|
|---|
| 79 | (cd config.tests/unix/libpng && $(MAKE) distclean); \
|
|---|
| 80 | (cd config.tests/x11/xcursor && $(MAKE) distclean); \
|
|---|
| 81 | (cd config.tests/x11/xrender && $(MAKE) distclean); \
|
|---|
| 82 | (cd config.tests/x11/xrandr && $(MAKE) distclean); \
|
|---|
| 83 | (cd config.tests/x11/xkb && $(MAKE) distclean); \
|
|---|
| 84 | (cd config.tests/x11/xinput && $(MAKE) distclean); \
|
|---|
| 85 | (cd config.tests/x11/fontconfig && $(MAKE) distclean); \
|
|---|
| 86 | (cd config.tests/x11/xinerama && $(MAKE) distclean); \
|
|---|
| 87 | (cd config.tests/x11/sm && $(MAKE) distclean); \
|
|---|
| 88 | (cd config.tests/x11/xshape && $(MAKE) distclean); \
|
|---|
| 89 | (cd config.tests/x11/opengl && $(MAKE) distclean); \
|
|---|
| 90 | $(DEL_FILE) config.tests/.qmake.cache; \
|
|---|
| 91 | $(DEL_FILE) src/core/global/qconfig.h; \
|
|---|
| 92 | $(DEL_FILE) src/core/global/qconfig.cpp; \
|
|---|
| 93 | $(DEL_FILE) mkspecs/qconfig.pri; \
|
|---|
| 94 | $(DEL_FILE) .qmake.cache; \
|
|---|
| 95 | (cd qmake && $(MAKE) distclean);
|
|---|
| 96 | }
|
|---|
| 97 | win32|os2 {
|
|---|
| 98 | confclean.commands += -$(DEL_FILE) src\core\global\qconfig.h $$escape_expand(\n\t) \
|
|---|
| 99 | -$(DEL_FILE) src\core\global\qconfig.cpp $$escape_expand(\n\t) \
|
|---|
| 100 | -$(DEL_FILE) mkspecs\qconfig.pri $$escape_expand(\n\t) \
|
|---|
| 101 | -$(DEL_FILE) .qmake.cache $$escape_expand(\n\t) \
|
|---|
| 102 | (cd qmake && $(MAKE) distclean)
|
|---|
| 103 | }
|
|---|
| 104 | QMAKE_EXTRA_TARGETS += confclean
|
|---|
| 105 | qmakeclean.commands += (cd qmake && $(MAKE) clean)
|
|---|
| 106 | QMAKE_EXTRA_TARGETS += qmakeclean
|
|---|
| 107 | CLEAN_DEPS += qmakeclean
|
|---|
| 108 |
|
|---|
| 109 | CONFIG -= qt
|
|---|
| 110 |
|
|---|
| 111 | ### installations ####
|
|---|
| 112 |
|
|---|
| 113 | #translations
|
|---|
| 114 | translations.path=$$[QT_INSTALL_TRANSLATIONS]
|
|---|
| 115 | translations.files = $$QT_SOURCE_TREE/translations/*.qm
|
|---|
| 116 | INSTALLS += translations
|
|---|
| 117 |
|
|---|
| 118 | #qmake
|
|---|
| 119 | qmake.path=$$[QT_INSTALL_BINS]
|
|---|
| 120 | win32|os2 {
|
|---|
| 121 | qmake.files=$$QT_BUILD_TREE/bin/qmake.exe
|
|---|
| 122 | } else {
|
|---|
| 123 | qmake.files=$$QT_BUILD_TREE/bin/qmake
|
|---|
| 124 | }
|
|---|
| 125 | INSTALLS += qmake
|
|---|
| 126 |
|
|---|
| 127 | #mkspecs
|
|---|
| 128 | mkspecs.path=$$[QT_INSTALL_DATA]/mkspecs
|
|---|
| 129 | mkspecs.files=$$QT_BUILD_TREE/mkspecs/qconfig.pri $$QT_SOURCE_TREE/mkspecs/*
|
|---|
| 130 | unix {
|
|---|
| 131 | DEFAULT_QMAKESPEC = $$QMAKESPEC
|
|---|
| 132 | DEFAULT_QMAKESPEC ~= s,^.*mkspecs/,,g
|
|---|
| 133 | mkspecs.commands += $(DEL_FILE) $(INSTALL_ROOT)$$mkspecs.path/default; $(SYMLINK) $$DEFAULT_QMAKESPEC $(INSTALL_ROOT)$$mkspecs.path/default
|
|---|
| 134 | }
|
|---|
| 135 | INSTALLS += mkspecs
|
|---|
| 136 |
|
|---|
| 137 | false:macx { #mac install location
|
|---|
| 138 | macdocs.files = $$htmldocs.files
|
|---|
| 139 | macdocs.path = /Developer/Documentation/Qt
|
|---|
| 140 | INSTALLS += macdocs
|
|---|
| 141 | }
|
|---|
| 142 |
|
|---|
| 143 | !win32:contains(QT_CONFIG, qtusagereporter) {
|
|---|
| 144 | usagereporter.path=$$[QT_INSTALL_BINS]
|
|---|
| 145 | usagereporter.files=$$QT_BUILD_TREE/bin/qtusagereporter
|
|---|
| 146 | INSTALLS += usagereporter
|
|---|
| 147 | }
|
|---|
