| 1 | #####################################################################
|
|---|
| 2 | # Qt documentation build
|
|---|
| 3 | #####################################################################
|
|---|
| 4 |
|
|---|
| 5 | DOCS_GENERATION_DEFINES =
|
|---|
| 6 | GENERATOR = $$QT_BUILD_TREE/bin/qhelpgenerator
|
|---|
| 7 |
|
|---|
| 8 | win32:!win32-g++* {
|
|---|
| 9 | unixstyle = false
|
|---|
| 10 | } else :win32-g++*:isEmpty(QMAKE_SH) {
|
|---|
| 11 | unixstyle = false
|
|---|
| 12 | } else :os2:isEmpty(QMAKE_SH) {
|
|---|
| 13 | unixstyle = false
|
|---|
| 14 | } else {
|
|---|
| 15 | unixstyle = true
|
|---|
| 16 | }
|
|---|
| 17 |
|
|---|
| 18 | $$unixstyle {
|
|---|
| 19 | QDOC = cd $$QT_SOURCE_TREE/tools/qdoc3/test && QT_BUILD_TREE=$$QT_BUILD_TREE QT_SOURCE_TREE=$$QT_SOURCE_TREE $$QT_BUILD_TREE/bin/qdoc3 $$DOCS_GENERATION_DEFINES
|
|---|
| 20 | } else {
|
|---|
| 21 | QDOC = cd $$QT_SOURCE_TREE/tools/qdoc3/test && set QT_BUILD_TREE=$$QT_BUILD_TREE&& set QT_SOURCE_TREE=$$QT_SOURCE_TREE&& $$QT_BUILD_TREE/bin/qdoc3.exe $$DOCS_GENERATION_DEFINES
|
|---|
| 22 | QDOC = $$replace(QDOC, "/", "\\")
|
|---|
| 23 | }
|
|---|
| 24 |
|
|---|
| 25 | # overcome OS/2 1024 command line length limitation
|
|---|
| 26 | os2:isEmpty(QMAKE_SH) {
|
|---|
| 27 | qdoc_cmd.target = $$QT_BUILD_TREE/qdoc.cmd
|
|---|
| 28 | qdoc_cmd.commands = echo "@echo off" > $${qdoc_cmd.target}$$escape_expand(\\n\\t)
|
|---|
| 29 | qdoc_cmd.commands += echo $$replace(QDOC, "&&", ">> $${qdoc_cmd.target}"$$escape_expand(\\n\\t)" echo") %1 %2 %3 %4 %5 %6 %7 %8 %9 ">> $${qdoc_cmd.target}"
|
|---|
| 30 | QDOC = cmd /c $$QT_BUILD_TREE/qdoc.cmd
|
|---|
| 31 | adp_docs.depends += qdoc_cmd
|
|---|
| 32 | QMAKE_EXTRA_TARGETS += qdoc_cmd
|
|---|
| 33 | }
|
|---|
| 34 |
|
|---|
| 35 | ADP_DOCS_QDOCCONF_FILE = -online qt-build-docs.qdocconf
|
|---|
| 36 | QT_DOCUMENTATION = ($$QDOC -creator qt-api-only.qdocconf assistant.qdocconf designer.qdocconf \
|
|---|
| 37 | linguist.qdocconf qmake.qdocconf qdeclarative.qdocconf) && \
|
|---|
| 38 | (cd $$QT_BUILD_TREE && \
|
|---|
| 39 | $$GENERATOR doc-build/html-qt/qt.qhp -o doc/qch/qt.qch && \
|
|---|
| 40 | $$GENERATOR doc-build/html-assistant/assistant.qhp -o doc/qch/assistant.qch && \
|
|---|
| 41 | $$GENERATOR doc-build/html-designer/designer.qhp -o doc/qch/designer.qch && \
|
|---|
| 42 | $$GENERATOR doc-build/html-linguist/linguist.qhp -o doc/qch/linguist.qch && \
|
|---|
| 43 | $$GENERATOR doc-build/html-qmake/qmake.qhp -o doc/qch/qmake.qch && \
|
|---|
| 44 | $$GENERATOR doc-build/html-qml/qml.qhp -o doc/qch/qml.qch \
|
|---|
| 45 | )
|
|---|
| 46 |
|
|---|
| 47 | # overcome OS/2 1024 command line length limitation
|
|---|
| 48 | os2:isEmpty(QMAKE_SH) {
|
|---|
| 49 | qt_documentation_cmd.target = $$QT_BUILD_TREE/qt_documentation.cmd
|
|---|
| 50 | qt_documentation_cmd.depends += qdoc_cmd
|
|---|
| 51 | qt_documentation_cmd.commands = echo "@echo off" > $${qt_documentation_cmd.target}$$escape_expand(\\n\\t)
|
|---|
| 52 | qt_documentation_cmd.tmp = $$replace(QT_DOCUMENTATION,"[\\x0028\\x0029]","")
|
|---|
| 53 | qt_documentation_cmd.commands += echo $$replace(qt_documentation_cmd.tmp, "&&", ">> $${qt_documentation_cmd.target}"$$escape_expand(\\n\\t)" echo") ">> $${qt_documentation_cmd.target}"
|
|---|
| 54 | QT_DOCUMENTATION = $$QT_BUILD_TREE/qt_documentation.cmd
|
|---|
| 55 | qch_docs.depends += qt_documentation_cmd
|
|---|
| 56 | QMAKE_EXTRA_TARGETS += qt_documentation_cmd
|
|---|
| 57 | }
|
|---|
| 58 |
|
|---|
| 59 | QT_ZH_CN_DOCUMENTATION = ($$QDOC qt-api-only_zh_CN.qdocconf) && \
|
|---|
| 60 | (cd $$QT_BUILD_TREE && \
|
|---|
| 61 | $$GENERATOR doc-build/html-qt_zh_CN/qt.qhp -o doc/qch/qt_zh_CN.qch \
|
|---|
| 62 | )
|
|---|
| 63 |
|
|---|
| 64 | QT_JA_JP_DOCUMENTATION = ($$QDOC qt-api-only_ja_JP.qdocconf) && \
|
|---|
| 65 | (cd $$QT_BUILD_TREE && \
|
|---|
| 66 | $$GENERATOR doc-build/html-qt_ja_JP/qt.qhp -o doc/qch/qt_ja_JP.qch \
|
|---|
| 67 | )
|
|---|
| 68 |
|
|---|
| 69 | win32-g++*:isEmpty(QMAKE_SH) {
|
|---|
| 70 | QT_DOCUMENTATION = $$replace(QT_DOCUMENTATION, "/", "\\\\")
|
|---|
| 71 | QT_ZH_CN_DOCUMENTATION = $$replace(QT_ZH_CN_DOCUMENTATION, "/", "\\\\")
|
|---|
| 72 | QT_JA_JP_DOCUMENTATION = $$replace(QT_JA_JP_DOCUMENTATION, "/", "\\\\")
|
|---|
| 73 | }
|
|---|
| 74 |
|
|---|
| 75 | # Build rules:
|
|---|
| 76 | adp_docs.commands = ($$QDOC $$ADP_DOCS_QDOCCONF_FILE)
|
|---|
| 77 | adp_docs.depends += sub-qdoc3 # qdoc3
|
|---|
| 78 | qch_docs.commands = $$QT_DOCUMENTATION
|
|---|
| 79 | qch_docs.depends += sub-qdoc3
|
|---|
| 80 |
|
|---|
| 81 | docs.depends = sub-qdoc3 adp_docs qch_docs
|
|---|
| 82 |
|
|---|
| 83 | docs_zh_CN.depends = docs
|
|---|
| 84 | docs_zh_CN.commands = $$QT_ZH_CN_DOCUMENTATION
|
|---|
| 85 |
|
|---|
| 86 | docs_ja_JP.depends = docs
|
|---|
| 87 | docs_ja_JP.commands = $$QT_JA_JP_DOCUMENTATION
|
|---|
| 88 |
|
|---|
| 89 | # Install rules
|
|---|
| 90 | htmldocs.files = $$QT_BUILD_TREE/doc/html
|
|---|
| 91 | htmldocs.path = $$[QT_INSTALL_DOCS]
|
|---|
| 92 | htmldocs.CONFIG += no_check_exist directory
|
|---|
| 93 |
|
|---|
| 94 | qchdocs.files= $$QT_BUILD_TREE/doc/qch
|
|---|
| 95 | qchdocs.path = $$[QT_INSTALL_DOCS]
|
|---|
| 96 | qchdocs.CONFIG += no_check_exist directory
|
|---|
| 97 |
|
|---|
| 98 | docimages.files = $$QT_BUILD_TREE/doc/src/images
|
|---|
| 99 | docimages.path = $$[QT_INSTALL_DOCS]/src
|
|---|
| 100 |
|
|---|
| 101 | sub-qdoc3.depends = sub-corelib sub-xml
|
|---|
| 102 | $$unixstyle:sub-qdoc3.commands += (cd tools/qdoc3 && $(MAKE))
|
|---|
| 103 | else:sub-qdoc3.commands += (cd tools\\qdoc3 && $(MAKE))
|
|---|
| 104 |
|
|---|
| 105 | QMAKE_EXTRA_TARGETS += sub-qdoc3 adp_docs qch_docs docs docs_zh_CN docs_ja_JP
|
|---|
| 106 | INSTALLS += htmldocs qchdocs docimages
|
|---|
