source: trunk/src/qt.pro@ 189

Last change on this file since 189 was 183, checked in by dmik, 17 years ago

kernel: Don't touch the static library name (should always be qt[-mt].lib).
File size: 7.3 KB
Line 
1# Qt project file
2#
3# :mode=makefile:tabSize=8:indentSize=4:noTabs=false:
4
5TEMPLATE = lib
6TARGET = qt
7embedded:TARGET = qte
8VERSION = 3.3.1
9os2:VERSION = $${VERSION}.0.7a
10DESTDIR = $$QMAKE_LIBDIR_QT
11DLLDESTDIR = ../bin
12
13os2:CONFIG += build_qt
14
15debug:os2 {
16 DESTDIR = $$QMAKE_LIBDIR_QT_DEBUG
17 DLLDESTDIR = ../bin/debug
18}
19
20CONFIG += qt warn_on depend_includepath
21CONFIG += qmake_cache
22
23win32:!shared:CONFIG += staticlib
24os2:!shared:CONFIG += staticlib
25
26win32-borland {
27 mng:QMAKE_CFLAGS_WARN_ON += -w-par
28 mng:QMAKE_CXXFLAGS_WARN_ON += -w-par
29 # Keep the size of the .tds file for the Qt library smaller than
30 # 34 Mbytes to avoid linking problems
31 QMAKE_CFLAGS_DEBUG += -vi -y-
32 QMAKE_CXXFLAGS_DEBUG += -vi -y-
33}
34
35linux-*:version_script {
36 QMAKE_LFLAGS += -Wl,--version-script=libqt.map
37 TARGETDEPS += libqt.map
38}
39
40KERNEL_CPP = kernel
41CANVAS_CPP = canvas
42WIDGETS_CPP = widgets
43SQL_CPP = sql
44TABLE_CPP = table
45DIALOGS_CPP = dialogs
46ICONVIEW_CPP = iconview
47NETWORK_CPP = network
48OPENGL_CPP = opengl
49TOOLS_CPP = tools
50CODECS_CPP = codecs
51WORKSPACE_CPP = workspace
52XML_CPP = xml
53STYLES_CPP = styles
54EMBEDDED_CPP = embedded
55
56win32 {
57 contains(QT_PRODUCT,qt-internal) {
58 SQL_H = $$SQL_CPP
59 KERNEL_H = $$KERNEL_CPP
60 WIDGETS_H = $$WIDGETS_CPP
61 TABLE_H = $$TABLE_CPP
62 DIALOGS_H = $$DIALOGS_CPP
63 ICONVIEW_H = $$ICONVIEW_CPP
64 NETWORK_H = $$NETWORK_CPP
65 OPENGL_H = $$OPENGL_CPP
66 TOOLS_H = $$TOOLS_CPP
67 CODECS_H = $$CODECS_CPP
68 WORKSPACE_H = $$WORKSPACE_CPP
69 XML_H = $$XML_CPP
70 CANVAS_H = $$CANVAS_CPP
71 STYLES_H = $$STYLES_CPP
72 } else {
73 WIN_ALL_H = ../include
74 SQL_H = $$WIN_ALL_H
75 KERNEL_H = $$WIN_ALL_H
76 WIDGETS_H = $$WIN_ALL_H
77 TABLE_H = $$WIN_ALL_H
78 DIALOGS_H = $$WIN_ALL_H
79 ICONVIEW_H = $$WIN_ALL_H
80 NETWORK_H = $$WIN_ALL_H
81 OPENGL_H = $$WIN_ALL_H
82 TOOLS_H = $$WIN_ALL_H
83 CODECS_H = $$WIN_ALL_H
84 WORKSPACE_H = $$WIN_ALL_H
85 XML_H = $$WIN_ALL_H
86 CANVAS_H = $$WIN_ALL_H
87 STYLES_H = $$WIN_ALL_H
88 CONFIG -= incremental
89 }
90
91 CONFIG += zlib
92 INCLUDEPATH += tmp
93 !staticlib {
94 DEFINES+=QT_MAKEDLL
95 exists(qt.rc):RC_FILE = qt.rc
96 }
97}
98win32-borland:INCLUDEPATH += kernel
99
100os2 {
101 OS2_ALL_H = ../include
102 SQL_H = $$OS2_ALL_H
103 KERNEL_H = $$OS2_ALL_H
104 WIDGETS_H = $$OS2_ALL_H
105 TABLE_H = $$OS2_ALL_H
106 DIALOGS_H = $$OS2_ALL_H
107 ICONVIEW_H = $$OS2_ALL_H
108 NETWORK_H = $$OS2_ALL_H
109 OPENGL_H = $$OS2_ALL_H
110 TOOLS_H = $$OS2_ALL_H
111 CODECS_H = $$OS2_ALL_H
112 WORKSPACE_H = $$OS2_ALL_H
113 XML_H = $$OS2_ALL_H
114 CANVAS_H = $$OS2_ALL_H
115 STYLES_H = $$OS2_ALL_H
116 CONFIG -= incremental
117
118 CONFIG += zlib
119 INCLUDEPATH += tmp
120 !staticlib {
121 DEFINES += QT_MAKEDLL
122 exists(qt.rc):RC_FILE = qt.rc
123 exists(qt.def.tpl.$$QMAKESPEC):DEF_FILE_TEMPLATE = qt.def.tpl.$$QMAKESPEC
124 exists(qt.def.map.$$QMAKESPEC) {
125 DEF_FILE_MAP = qt.def.map.$$QMAKESPEC
126 debug {
127 qt_def_map_debug.target = $(DEF_FILE_MAP)
128 qt_def_map_debug.depends = $$DEF_FILE_MAP
129 qt_def_map_debug.commands = $(COPY_FILE) "$$DEF_FILE_MAP" "$$qt_def_map_debug.target"
130 QMAKE_EXTRA_TARGETS += qt_def_map_debug
131 DEF_FILE_MAP = qt.def.map.$$(QMAKESPEC).debug
132 }
133 }
134 }
135}
136
137unix {
138 CANVAS_H = $$CANVAS_CPP
139 KERNEL_H = $$KERNEL_CPP
140 WIDGETS_H = $$WIDGETS_CPP
141 SQL_H = $$SQL_CPP
142 TABLE_H = $$TABLE_CPP
143 DIALOGS_H = $$DIALOGS_CPP
144 ICONVIEW_H = $$ICONVIEW_CPP
145 NETWORK_H = $$NETWORK_CPP
146 OPENGL_H = $$OPENGL_CPP
147 TOOLS_H = $$TOOLS_CPP
148 CODECS_H = $$CODECS_CPP
149 WORKSPACE_H = $$WORKSPACE_CPP
150 XML_H = $$XML_CPP
151 STYLES_H = $$STYLES_CPP
152 !embedded:!mac:CONFIG += x11 x11inc
153}
154
155aix-g++ {
156 QMAKE_CFLAGS += -mminimal-toc
157 QMAKE_CXXFLAGS += -mminimal-toc
158}
159
160embedded {
161 EMBEDDED_H = $$EMBEDDED_CPP
162}
163
164DEPENDPATH += ;$$NETWORK_H;$$KERNEL_H;$$WIDGETS_H;$$SQL_H;$$TABLE_H;$$DIALOGS_H;
165DEPENDPATH += $$ICONVIEW_H;$$OPENGL_H;$$TOOLS_H;$$CODECS_H;$$WORKSPACE_H;$$XML_H;
166DEPENDPATH += $$CANVAS_H;$$STYLES_H
167embedded:DEPENDPATH += ;$$EMBEDDED_H
168
169thread {
170 !os2 {
171 !win32-borland:TARGET = qt-mt
172 win32-borland:TARGET = qtmt
173 embedded:TARGET = qte-mt
174 }
175 DEFINES += QT_THREAD_SUPPORT
176}
177
178shared:os2 {
179 qt_official_build {
180 TARGET = qt$$split(VERSION,.,)
181 system( echo QMAKE_QT_DLL_TARGET = $$TARGET > ..\.qtbuild )
182 } else {
183 TARGET = $$QMAKE_QT_DLL_TARGET
184 }
185}
186
187!cups:DEFINES += QT_NO_CUPS
188
189!nis:DEFINES += QT_NO_NIS
190
191largefile {
192 unix:!darwin:DEFINES += _LARGEFILE_SOURCE _LARGE_FILES _FILE_OFFSET_BITS=64
193}
194
195#here for compatability, should go away ####
196include($$KERNEL_CPP/qt_compat.pri)
197
198#platforms
199x11:include($$KERNEL_CPP/qt_x11.pri)
200mac:include($$KERNEL_CPP/qt_mac.pri)
201win32:include($$KERNEL_CPP/qt_win.pri)
202embedded:include($$KERNEL_CPP/qt_qws.pri)
203
204#modules
205os2 {
206 # this section should be removed one day
207 # when an OS/2 version of every module is ready
208 include($$KERNEL_CPP/qt_kernel.pri)
209 include($$WIDGETS_CPP/qt_widgets.pri)
210 include($$DIALOGS_CPP/qt_dialogs.pri)
211 include($$ICONVIEW_CPP/qt_iconview.pri)
212 include($$WORKSPACE_CPP/qt_workspace.pri)
213 include($$NETWORK_CPP/qt_network.pri)
214 include($$CANVAS_CPP/qt_canvas.pri)
215 include($$TABLE_CPP/qt_table.pri)
216 include($$XML_CPP/qt_xml.pri)
217 include($$KERNEL_CPP/qt_gfx.pri)
218 include($$TOOLS_CPP/qt_tools.pri)
219 include($$CODECS_CPP/qt_codecs.pri)
220 include($$STYLES_CPP/qt_styles.pri)
221} else {
222 include($$KERNEL_CPP/qt_kernel.pri)
223 include($$WIDGETS_CPP/qt_widgets.pri)
224 include($$DIALOGS_CPP/qt_dialogs.pri)
225 include($$ICONVIEW_CPP/qt_iconview.pri)
226 include($$WORKSPACE_CPP/qt_workspace.pri)
227 include($$NETWORK_CPP/qt_network.pri)
228 include($$CANVAS_CPP/qt_canvas.pri)
229 include($$TABLE_CPP/qt_table.pri)
230 include($$XML_CPP/qt_xml.pri)
231 include($$OPENGL_CPP/qt_opengl.pri)
232 include($$SQL_CPP/qt_sql.pri)
233 include($$KERNEL_CPP/qt_gfx.pri)
234 include($$TOOLS_CPP/qt_tools.pri)
235 include($$CODECS_CPP/qt_codecs.pri)
236 include($$STYLES_CPP/qt_styles.pri)
237}
238embedded:include($$EMBEDDED_CPP/qt_embedded.pri)
239
240# qconfig.cpp
241exists($$QT_BUILD_TREE/src/tools/qconfig.cpp) {
242 SOURCES += $$QT_BUILD_TREE/src/tools/qconfig.cpp
243}
244
245#install directives
246!os2:include(qt_install.pri)
247!staticlib:PRL_EXPORT_DEFINES += QT_SHARED
248
249unix {
250 CONFIG += create_libtool create_pc
251 QMAKE_PKGCONFIG_LIBDIR = $$target.path
252 QMAKE_PKGCONFIG_INCDIR = $$headers.path
253}
254
255wince-* {
256 CONFIG -= incremental
257 message( ...removing plugin stuff... (not permanent) )
258 HEADERS -= $$TOOLS_CPP/qcomlibrary.h \
259 $$KERNEL_CPP/qgplugin.h \
260 $$KERNEL_CPP/qimageformatplugin.h \
261 $$STYLES_CPP/qstyleplugin.h \
262 $$CODECS_CPP/qtextcodecplugin.h \
263 $$WIDGETS_CPP/qwidgetplugin.h
264
265 SOURCES -= $$TOOLS_CPP/qcomlibrary.cpp \
266 $$KERNEL_CPP/qgplugin.cpp \
267 $$KERNEL_CPP/qimageformatplugin.cpp \
268 $$STYLES_CPP/qstyleplugin.cpp \
269 $$CODECS_CPP/qtextcodecplugin.cpp \
270 $$WIDGETS_CPP/qwidgetplugin.cpp
271}
272
273os2 {
274 # targets and commands to sync private headers
275 private_headers.target = ..\.private_headers
276 private_headers.depends = do_private_headers
277 do_private_headers.target = do_private_headers
278 do_private_headers.commands = cd .. && $(MAKE) private_headers
279 QMAKE_EXTRA_TARGETS += do_private_headers private_headers
280 PRE_TARGETDEPS += $$do_private_headers.target
281 QMAKE_INTERNAL_INCLUDED_FILES += $$private_headers.target
282}
Note: See TracBrowser for help on using the repository browser.