source: trunk/src/qt.pro@ 85

Last change on this file since 85 was 85, checked in by dmik, 19 years ago
  • Added QMAKE_LIBDIR_QT_DEBUG internal QMAKE variable that is used to define a directory used to store and locate the debug version of the Qt dll
  • When 'qt' is present in CONFIG, the GNUMAKE backend places the values of QMAKE_LIBDIR_QT_DEBUG followed by the value of QMAKE_LIBDIR_QT to the library search path if 'debug' is also present there, otherwise these values are placed in the opposite order.
File size: 7.0 KB
Line 
1# Qt project file
2#
3# :mode=makefile:tabSize=8:indentSize=4:noTabs=false:
4
5TEMPLATE = lib
6TARGET = qt
7embedded:TARGET = qte
8VERSION = 3.3.1
9os2:VERSION = $${VERSION}.0.6
10DESTDIR = $$QMAKE_LIBDIR_QT
11DLLDESTDIR = ../bin
12
13os2:CONFIG += build_qt
14
15debug:os2 {
16 DESTDIR = $$QMAKE_LIBDIR_QT_DEBUG
17 DLLDESTDIR = ../bin/debug
18}
19
20CONFIG += qt warn_on depend_includepath
21CONFIG += qmake_cache
22
23win32:!shared:CONFIG += staticlib
24os2:!shared:CONFIG += staticlib
25
26win32-borland {
27 mng:QMAKE_CFLAGS_WARN_ON += -w-par
28 mng:QMAKE_CXXFLAGS_WARN_ON += -w-par
29 # Keep the size of the .tds file for the Qt library smaller than
30 # 34 Mbytes to avoid linking problems
31 QMAKE_CFLAGS_DEBUG += -vi -y-
32 QMAKE_CXXFLAGS_DEBUG += -vi -y-
33}
34
35linux-*:version_script {
36 QMAKE_LFLAGS += -Wl,--version-script=libqt.map
37 TARGETDEPS += libqt.map
38}
39
40KERNEL_CPP = kernel
41CANVAS_CPP = canvas
42WIDGETS_CPP = widgets
43SQL_CPP = sql
44TABLE_CPP = table
45DIALOGS_CPP = dialogs
46ICONVIEW_CPP = iconview
47NETWORK_CPP = network
48OPENGL_CPP = opengl
49TOOLS_CPP = tools
50CODECS_CPP = codecs
51WORKSPACE_CPP = workspace
52XML_CPP = xml
53STYLES_CPP = styles
54EMBEDDED_CPP = embedded
55
56win32 {
57 contains(QT_PRODUCT,qt-internal) {
58 SQL_H = $$SQL_CPP
59 KERNEL_H = $$KERNEL_CPP
60 WIDGETS_H = $$WIDGETS_CPP
61 TABLE_H = $$TABLE_CPP
62 DIALOGS_H = $$DIALOGS_CPP
63 ICONVIEW_H = $$ICONVIEW_CPP
64 NETWORK_H = $$NETWORK_CPP
65 OPENGL_H = $$OPENGL_CPP
66 TOOLS_H = $$TOOLS_CPP
67 CODECS_H = $$CODECS_CPP
68 WORKSPACE_H = $$WORKSPACE_CPP
69 XML_H = $$XML_CPP
70 CANVAS_H = $$CANVAS_CPP
71 STYLES_H = $$STYLES_CPP
72 } else {
73 WIN_ALL_H = ../include
74 SQL_H = $$WIN_ALL_H
75 KERNEL_H = $$WIN_ALL_H
76 WIDGETS_H = $$WIN_ALL_H
77 TABLE_H = $$WIN_ALL_H
78 DIALOGS_H = $$WIN_ALL_H
79 ICONVIEW_H = $$WIN_ALL_H
80 NETWORK_H = $$WIN_ALL_H
81 OPENGL_H = $$WIN_ALL_H
82 TOOLS_H = $$WIN_ALL_H
83 CODECS_H = $$WIN_ALL_H
84 WORKSPACE_H = $$WIN_ALL_H
85 XML_H = $$WIN_ALL_H
86 CANVAS_H = $$WIN_ALL_H
87 STYLES_H = $$WIN_ALL_H
88 CONFIG -= incremental
89 }
90
91 CONFIG += zlib
92 INCLUDEPATH += tmp
93 !staticlib {
94 DEFINES+=QT_MAKEDLL
95 exists(qt.rc):RC_FILE = qt.rc
96 }
97}
98win32-borland:INCLUDEPATH += kernel
99
100os2 {
101 OS2_ALL_H = ../include
102 SQL_H = $$OS2_ALL_H
103 KERNEL_H = $$OS2_ALL_H
104 WIDGETS_H = $$OS2_ALL_H
105 TABLE_H = $$OS2_ALL_H
106 DIALOGS_H = $$OS2_ALL_H
107 ICONVIEW_H = $$OS2_ALL_H
108 NETWORK_H = $$OS2_ALL_H
109 OPENGL_H = $$OS2_ALL_H
110 TOOLS_H = $$OS2_ALL_H
111 CODECS_H = $$OS2_ALL_H
112 WORKSPACE_H = $$OS2_ALL_H
113 XML_H = $$OS2_ALL_H
114 CANVAS_H = $$OS2_ALL_H
115 STYLES_H = $$OS2_ALL_H
116 CONFIG -= incremental
117
118 CONFIG += zlib
119 INCLUDEPATH += tmp
120 !staticlib {
121 DEFINES += QT_MAKEDLL
122 exists(qt.rc):RC_FILE = qt.rc
123 exists(qt.def.tpl.$$QMAKESPEC):DEF_FILE_TEMPLATE = qt.def.tpl.$$QMAKESPEC
124 exists(qt.def.map.$$QMAKESPEC) {
125 DEF_FILE_MAP = qt.def.map.$$QMAKESPEC
126 debug {
127 qt_def_map_debug.target = $(DEF_FILE_MAP)
128 qt_def_map_debug.depends = $$DEF_FILE_MAP
129 qt_def_map_debug.commands = $(COPY_FILE) "$$DEF_FILE_MAP" "$$qt_def_map_debug.target"
130 QMAKE_EXTRA_TARGETS += qt_def_map_debug
131 DEF_FILE_MAP = qt.def.map.$$(QMAKESPEC).debug
132 }
133 }
134 }
135}
136
137unix {
138 CANVAS_H = $$CANVAS_CPP
139 KERNEL_H = $$KERNEL_CPP
140 WIDGETS_H = $$WIDGETS_CPP
141 SQL_H = $$SQL_CPP
142 TABLE_H = $$TABLE_CPP
143 DIALOGS_H = $$DIALOGS_CPP
144 ICONVIEW_H = $$ICONVIEW_CPP
145 NETWORK_H = $$NETWORK_CPP
146 OPENGL_H = $$OPENGL_CPP
147 TOOLS_H = $$TOOLS_CPP
148 CODECS_H = $$CODECS_CPP
149 WORKSPACE_H = $$WORKSPACE_CPP
150 XML_H = $$XML_CPP
151 STYLES_H = $$STYLES_CPP
152 !embedded:!mac:CONFIG += x11 x11inc
153}
154
155aix-g++ {
156 QMAKE_CFLAGS += -mminimal-toc
157 QMAKE_CXXFLAGS += -mminimal-toc
158}
159
160embedded {
161 EMBEDDED_H = $$EMBEDDED_CPP
162}
163
164DEPENDPATH += ;$$NETWORK_H;$$KERNEL_H;$$WIDGETS_H;$$SQL_H;$$TABLE_H;$$DIALOGS_H;
165DEPENDPATH += $$ICONVIEW_H;$$OPENGL_H;$$TOOLS_H;$$CODECS_H;$$WORKSPACE_H;$$XML_H;
166DEPENDPATH += $$CANVAS_H;$$STYLES_H
167embedded:DEPENDPATH += ;$$EMBEDDED_H
168
169thread {
170 !os2 {
171 !win32-borland:TARGET = qt-mt
172 win32-borland:TARGET = qtmt
173 embedded:TARGET = qte-mt
174 }
175 DEFINES += QT_THREAD_SUPPORT
176}
177
178!cups:DEFINES += QT_NO_CUPS
179
180!nis:DEFINES += QT_NO_NIS
181
182largefile {
183 unix:!darwin:DEFINES += _LARGEFILE_SOURCE _LARGE_FILES _FILE_OFFSET_BITS=64
184}
185
186#here for compatability, should go away ####
187include($$KERNEL_CPP/qt_compat.pri)
188
189#platforms
190x11:include($$KERNEL_CPP/qt_x11.pri)
191mac:include($$KERNEL_CPP/qt_mac.pri)
192win32:include($$KERNEL_CPP/qt_win.pri)
193embedded:include($$KERNEL_CPP/qt_qws.pri)
194
195#modules
196os2 {
197 # this section should be removed one day
198 # when an OS/2 version of every module is ready
199 include($$KERNEL_CPP/qt_kernel.pri)
200 include($$WIDGETS_CPP/qt_widgets.pri)
201 include($$DIALOGS_CPP/qt_dialogs.pri)
202 include($$WORKSPACE_CPP/qt_workspace.pri)
203 include($$NETWORK_CPP/qt_network.pri)
204 include($$CANVAS_CPP/qt_canvas.pri)
205 include($$XML_CPP/qt_xml.pri)
206 include($$KERNEL_CPP/qt_gfx.pri)
207 include($$TOOLS_CPP/qt_tools.pri)
208 include($$CODECS_CPP/qt_codecs.pri)
209 include($$STYLES_CPP/qt_styles.pri)
210} else {
211 include($$KERNEL_CPP/qt_kernel.pri)
212 include($$WIDGETS_CPP/qt_widgets.pri)
213 include($$DIALOGS_CPP/qt_dialogs.pri)
214 include($$ICONVIEW_CPP/qt_iconview.pri)
215 include($$WORKSPACE_CPP/qt_workspace.pri)
216 include($$NETWORK_CPP/qt_network.pri)
217 include($$CANVAS_CPP/qt_canvas.pri)
218 include($$TABLE_CPP/qt_table.pri)
219 include($$XML_CPP/qt_xml.pri)
220 include($$OPENGL_CPP/qt_opengl.pri)
221 include($$SQL_CPP/qt_sql.pri)
222 include($$KERNEL_CPP/qt_gfx.pri)
223 include($$TOOLS_CPP/qt_tools.pri)
224 include($$CODECS_CPP/qt_codecs.pri)
225 include($$STYLES_CPP/qt_styles.pri)
226}
227embedded:include($$EMBEDDED_CPP/qt_embedded.pri)
228
229# qconfig.cpp
230exists($$QT_BUILD_TREE/src/tools/qconfig.cpp) {
231 SOURCES += $$QT_BUILD_TREE/src/tools/qconfig.cpp
232}
233
234#install directives
235#@@todo(dmik): need this on OS/2?
236!os2:include(qt_install.pri)
237!staticlib:PRL_EXPORT_DEFINES += QT_SHARED
238
239unix {
240 CONFIG += create_libtool create_pc
241 QMAKE_PKGCONFIG_LIBDIR = $$target.path
242 QMAKE_PKGCONFIG_INCDIR = $$headers.path
243}
244
245wince-* {
246 CONFIG -= incremental
247 message( ...removing plugin stuff... (not permanent) )
248 HEADERS -= $$TOOLS_CPP/qcomlibrary.h \
249 $$KERNEL_CPP/qgplugin.h \
250 $$KERNEL_CPP/qimageformatplugin.h \
251 $$STYLES_CPP/qstyleplugin.h \
252 $$CODECS_CPP/qtextcodecplugin.h \
253 $$WIDGETS_CPP/qwidgetplugin.h
254
255 SOURCES -= $$TOOLS_CPP/qcomlibrary.cpp \
256 $$KERNEL_CPP/qgplugin.cpp \
257 $$KERNEL_CPP/qimageformatplugin.cpp \
258 $$STYLES_CPP/qstyleplugin.cpp \
259 $$CODECS_CPP/qtextcodecplugin.cpp \
260 $$WIDGETS_CPP/qwidgetplugin.cpp
261}
262
263os2 {
264 # targets and commands to sync private headers
265 private_headers.target = ..\.private_headers
266 private_headers.depends = do_private_headers
267 do_private_headers.target = do_private_headers
268 do_private_headers.commands = cd .. && $(MAKE) private_headers
269 QMAKE_EXTRA_TARGETS += do_private_headers private_headers
270 PRE_TARGETDEPS += $$do_private_headers.target
271 QMAKE_INTERNAL_INCLUDED_FILES += $$private_headers.target
272}
Note: See TracBrowser for help on using the repository browser.