source: trunk/src/qt.pro@ 84

Last change on this file since 84 was 84, checked in by dmik, 19 years ago

Preparations to change the build process of Qt on OS/2:

  • OS2/GNUMAKE Backend: when CONFIG contains 'qt' (i.e. the app using Qt is being built), the Qt library defined in qmake.spec is used instead of some tricky procedure to find the highest version at runtime.
  • OS2/GNUMAKE Backend: the VERSION variable is no more used to define a suffix of the DLL being built.
  • 'build_qt' is used to tell QMAKE the Qt library is being built.
  • '-mt' is no more in the Qt library name to indicate a multi-threaded version.
File size: 6.9 KB
Line 
1# Qt project file
2#
3# :mode=makefile:tabSize=8:indentSize=4:noTabs=false:
4
5TEMPLATE = lib
6TARGET = qt
7embedded:TARGET = qte
8VERSION = 3.3.1
9os2:VERSION = $${VERSION}.0.6
10DESTDIR = $$QMAKE_LIBDIR_QT
11DLLDESTDIR = ../bin
12
13CONFIG += qt warn_on depend_includepath
14CONFIG += qmake_cache
15
16win32:!shared:CONFIG += staticlib
17os2:!shared:CONFIG += staticlib
18
19win32-borland {
20 mng:QMAKE_CFLAGS_WARN_ON += -w-par
21 mng:QMAKE_CXXFLAGS_WARN_ON += -w-par
22 # Keep the size of the .tds file for the Qt library smaller than
23 # 34 Mbytes to avoid linking problems
24 QMAKE_CFLAGS_DEBUG += -vi -y-
25 QMAKE_CXXFLAGS_DEBUG += -vi -y-
26}
27
28linux-*:version_script {
29 QMAKE_LFLAGS += -Wl,--version-script=libqt.map
30 TARGETDEPS += libqt.map
31}
32
33KERNEL_CPP = kernel
34CANVAS_CPP = canvas
35WIDGETS_CPP = widgets
36SQL_CPP = sql
37TABLE_CPP = table
38DIALOGS_CPP = dialogs
39ICONVIEW_CPP = iconview
40NETWORK_CPP = network
41OPENGL_CPP = opengl
42TOOLS_CPP = tools
43CODECS_CPP = codecs
44WORKSPACE_CPP = workspace
45XML_CPP = xml
46STYLES_CPP = styles
47EMBEDDED_CPP = embedded
48
49win32 {
50 contains(QT_PRODUCT,qt-internal) {
51 SQL_H = $$SQL_CPP
52 KERNEL_H = $$KERNEL_CPP
53 WIDGETS_H = $$WIDGETS_CPP
54 TABLE_H = $$TABLE_CPP
55 DIALOGS_H = $$DIALOGS_CPP
56 ICONVIEW_H = $$ICONVIEW_CPP
57 NETWORK_H = $$NETWORK_CPP
58 OPENGL_H = $$OPENGL_CPP
59 TOOLS_H = $$TOOLS_CPP
60 CODECS_H = $$CODECS_CPP
61 WORKSPACE_H = $$WORKSPACE_CPP
62 XML_H = $$XML_CPP
63 CANVAS_H = $$CANVAS_CPP
64 STYLES_H = $$STYLES_CPP
65 } else {
66 WIN_ALL_H = ../include
67 SQL_H = $$WIN_ALL_H
68 KERNEL_H = $$WIN_ALL_H
69 WIDGETS_H = $$WIN_ALL_H
70 TABLE_H = $$WIN_ALL_H
71 DIALOGS_H = $$WIN_ALL_H
72 ICONVIEW_H = $$WIN_ALL_H
73 NETWORK_H = $$WIN_ALL_H
74 OPENGL_H = $$WIN_ALL_H
75 TOOLS_H = $$WIN_ALL_H
76 CODECS_H = $$WIN_ALL_H
77 WORKSPACE_H = $$WIN_ALL_H
78 XML_H = $$WIN_ALL_H
79 CANVAS_H = $$WIN_ALL_H
80 STYLES_H = $$WIN_ALL_H
81 CONFIG -= incremental
82 }
83
84 CONFIG += zlib
85 INCLUDEPATH += tmp
86 !staticlib {
87 DEFINES+=QT_MAKEDLL
88 exists(qt.rc):RC_FILE = qt.rc
89 }
90}
91win32-borland:INCLUDEPATH += kernel
92
93os2 {
94 OS2_ALL_H = ../include
95 SQL_H = $$OS2_ALL_H
96 KERNEL_H = $$OS2_ALL_H
97 WIDGETS_H = $$OS2_ALL_H
98 TABLE_H = $$OS2_ALL_H
99 DIALOGS_H = $$OS2_ALL_H
100 ICONVIEW_H = $$OS2_ALL_H
101 NETWORK_H = $$OS2_ALL_H
102 OPENGL_H = $$OS2_ALL_H
103 TOOLS_H = $$OS2_ALL_H
104 CODECS_H = $$OS2_ALL_H
105 WORKSPACE_H = $$OS2_ALL_H
106 XML_H = $$OS2_ALL_H
107 CANVAS_H = $$OS2_ALL_H
108 STYLES_H = $$OS2_ALL_H
109 CONFIG -= incremental
110
111 CONFIG += zlib
112 INCLUDEPATH += tmp
113 !staticlib {
114 DEFINES += QT_MAKEDLL
115 exists(qt.rc):RC_FILE = qt.rc
116 exists(qt.def.tpl.$$QMAKESPEC):DEF_FILE_TEMPLATE = qt.def.tpl.$$QMAKESPEC
117 exists(qt.def.map.$$QMAKESPEC) {
118 DEF_FILE_MAP = qt.def.map.$$QMAKESPEC
119 debug {
120 qt_def_map_debug.target = $(DEF_FILE_MAP)
121 qt_def_map_debug.depends = $$DEF_FILE_MAP
122 qt_def_map_debug.commands = $(COPY_FILE) "$$DEF_FILE_MAP" "$$qt_def_map_debug.target"
123 QMAKE_EXTRA_TARGETS += qt_def_map_debug
124 DEF_FILE_MAP = qt.def.map.$$(QMAKESPEC).debug
125 }
126 }
127 }
128}
129
130unix {
131 CANVAS_H = $$CANVAS_CPP
132 KERNEL_H = $$KERNEL_CPP
133 WIDGETS_H = $$WIDGETS_CPP
134 SQL_H = $$SQL_CPP
135 TABLE_H = $$TABLE_CPP
136 DIALOGS_H = $$DIALOGS_CPP
137 ICONVIEW_H = $$ICONVIEW_CPP
138 NETWORK_H = $$NETWORK_CPP
139 OPENGL_H = $$OPENGL_CPP
140 TOOLS_H = $$TOOLS_CPP
141 CODECS_H = $$CODECS_CPP
142 WORKSPACE_H = $$WORKSPACE_CPP
143 XML_H = $$XML_CPP
144 STYLES_H = $$STYLES_CPP
145 !embedded:!mac:CONFIG += x11 x11inc
146}
147
148aix-g++ {
149 QMAKE_CFLAGS += -mminimal-toc
150 QMAKE_CXXFLAGS += -mminimal-toc
151}
152
153embedded {
154 EMBEDDED_H = $$EMBEDDED_CPP
155}
156
157DEPENDPATH += ;$$NETWORK_H;$$KERNEL_H;$$WIDGETS_H;$$SQL_H;$$TABLE_H;$$DIALOGS_H;
158DEPENDPATH += $$ICONVIEW_H;$$OPENGL_H;$$TOOLS_H;$$CODECS_H;$$WORKSPACE_H;$$XML_H;
159DEPENDPATH += $$CANVAS_H;$$STYLES_H
160embedded:DEPENDPATH += ;$$EMBEDDED_H
161
162thread {
163 !os2 {
164 !win32-borland:TARGET = qt-mt
165 win32-borland:TARGET = qtmt
166 embedded:TARGET = qte-mt
167 }
168 DEFINES += QT_THREAD_SUPPORT
169}
170
171!cups:DEFINES += QT_NO_CUPS
172
173!nis:DEFINES += QT_NO_NIS
174
175largefile {
176 unix:!darwin:DEFINES += _LARGEFILE_SOURCE _LARGE_FILES _FILE_OFFSET_BITS=64
177}
178
179#here for compatability, should go away ####
180include($$KERNEL_CPP/qt_compat.pri)
181
182#platforms
183x11:include($$KERNEL_CPP/qt_x11.pri)
184mac:include($$KERNEL_CPP/qt_mac.pri)
185win32:include($$KERNEL_CPP/qt_win.pri)
186embedded:include($$KERNEL_CPP/qt_qws.pri)
187
188#modules
189os2 {
190 # this section should be removed one day
191 # when an OS/2 version of every module is ready
192 include($$KERNEL_CPP/qt_kernel.pri)
193 include($$WIDGETS_CPP/qt_widgets.pri)
194 include($$DIALOGS_CPP/qt_dialogs.pri)
195 include($$WORKSPACE_CPP/qt_workspace.pri)
196 include($$NETWORK_CPP/qt_network.pri)
197 include($$CANVAS_CPP/qt_canvas.pri)
198 include($$XML_CPP/qt_xml.pri)
199 include($$KERNEL_CPP/qt_gfx.pri)
200 include($$TOOLS_CPP/qt_tools.pri)
201 include($$CODECS_CPP/qt_codecs.pri)
202 include($$STYLES_CPP/qt_styles.pri)
203} else {
204 include($$KERNEL_CPP/qt_kernel.pri)
205 include($$WIDGETS_CPP/qt_widgets.pri)
206 include($$DIALOGS_CPP/qt_dialogs.pri)
207 include($$ICONVIEW_CPP/qt_iconview.pri)
208 include($$WORKSPACE_CPP/qt_workspace.pri)
209 include($$NETWORK_CPP/qt_network.pri)
210 include($$CANVAS_CPP/qt_canvas.pri)
211 include($$TABLE_CPP/qt_table.pri)
212 include($$XML_CPP/qt_xml.pri)
213 include($$OPENGL_CPP/qt_opengl.pri)
214 include($$SQL_CPP/qt_sql.pri)
215 include($$KERNEL_CPP/qt_gfx.pri)
216 include($$TOOLS_CPP/qt_tools.pri)
217 include($$CODECS_CPP/qt_codecs.pri)
218 include($$STYLES_CPP/qt_styles.pri)
219}
220embedded:include($$EMBEDDED_CPP/qt_embedded.pri)
221
222# qconfig.cpp
223exists($$QT_BUILD_TREE/src/tools/qconfig.cpp) {
224 SOURCES += $$QT_BUILD_TREE/src/tools/qconfig.cpp
225}
226
227#install directives
228#@@todo(dmik): need this on OS/2?
229!os2:include(qt_install.pri)
230!staticlib:PRL_EXPORT_DEFINES += QT_SHARED
231
232unix {
233 CONFIG += create_libtool create_pc
234 QMAKE_PKGCONFIG_LIBDIR = $$target.path
235 QMAKE_PKGCONFIG_INCDIR = $$headers.path
236}
237
238wince-* {
239 CONFIG -= incremental
240 message( ...removing plugin stuff... (not permanent) )
241 HEADERS -= $$TOOLS_CPP/qcomlibrary.h \
242 $$KERNEL_CPP/qgplugin.h \
243 $$KERNEL_CPP/qimageformatplugin.h \
244 $$STYLES_CPP/qstyleplugin.h \
245 $$CODECS_CPP/qtextcodecplugin.h \
246 $$WIDGETS_CPP/qwidgetplugin.h
247
248 SOURCES -= $$TOOLS_CPP/qcomlibrary.cpp \
249 $$KERNEL_CPP/qgplugin.cpp \
250 $$KERNEL_CPP/qimageformatplugin.cpp \
251 $$STYLES_CPP/qstyleplugin.cpp \
252 $$CODECS_CPP/qtextcodecplugin.cpp \
253 $$WIDGETS_CPP/qwidgetplugin.cpp
254}
255
256os2 {
257 # targets and commands to sync private headers
258 private_headers.target = ..\.private_headers
259 private_headers.depends = do_private_headers
260 do_private_headers.target = do_private_headers
261 do_private_headers.commands = cd .. && $(MAKE) private_headers
262 QMAKE_EXTRA_TARGETS += do_private_headers private_headers
263 PRE_TARGETDEPS += $$do_private_headers.target
264 QMAKE_INTERNAL_INCLUDED_FILES += $$private_headers.target
265}
Note: See TracBrowser for help on using the repository browser.