| 1 | dnl Template file for GNU Autoconf
|
|---|
| 2 | dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
|
|---|
| 3 |
|
|---|
| 4 | dnl This program is free software; you can redistribute it and/or modify
|
|---|
| 5 | dnl it under the terms of the GNU General Public License as published by
|
|---|
| 6 | dnl the Free Software Foundation; either version 2 of the License, or
|
|---|
| 7 | dnl (at your option) any later version.
|
|---|
| 8 |
|
|---|
| 9 | dnl This program is distributed in the hope that it will be useful,
|
|---|
| 10 | dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|---|
| 11 | dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|---|
| 12 | dnl GNU General Public License for more details.
|
|---|
| 13 |
|
|---|
| 14 | dnl You should have received a copy of the GNU General Public License
|
|---|
| 15 | dnl along with this program; if not, write to the Free Software
|
|---|
| 16 | dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
|
|---|
| 17 |
|
|---|
| 18 | dnl In addition, as a special exception, the Free Software Foundation
|
|---|
| 19 | dnl gives permission to link the code of its release of Wget with the
|
|---|
| 20 | dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
|
|---|
| 21 | dnl that use the same license as the "OpenSSL" library), and distribute
|
|---|
| 22 | dnl the linked executables. You must obey the GNU General Public License
|
|---|
| 23 | dnl in all respects for all of the code used other than "OpenSSL". If you
|
|---|
| 24 | dnl modify this file, you may extend this exception to your version of the
|
|---|
| 25 | dnl file, but you are not obligated to do so. If you do not wish to do
|
|---|
| 26 | dnl so, delete this exception statement from your version.
|
|---|
| 27 |
|
|---|
| 28 | dnl
|
|---|
| 29 | dnl Process this file with autoconf to produce a configure script.
|
|---|
| 30 | dnl
|
|---|
| 31 |
|
|---|
| 32 | AC_INIT([src/version.c])
|
|---|
| 33 | AC_PREREQ(2.59)
|
|---|
| 34 |
|
|---|
| 35 | dnl Include the M4 macros we use.
|
|---|
| 36 | builtin(include, [m4/wget.m4])dnl
|
|---|
| 37 | builtin(include, [m4/lib-ld.m4])dnl
|
|---|
| 38 | builtin(include, [m4/lib-link.m4])dnl
|
|---|
| 39 | builtin(include, [m4/lib-prefix.m4])dnl
|
|---|
| 40 |
|
|---|
| 41 | dnl
|
|---|
| 42 | dnl What version of Wget are we building?
|
|---|
| 43 | dnl
|
|---|
| 44 | VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
|
|---|
| 45 | AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
|
|---|
| 46 | AC_SUBST(VERSION)
|
|---|
| 47 | PACKAGE=wget
|
|---|
| 48 | AC_SUBST(PACKAGE)
|
|---|
| 49 |
|
|---|
| 50 | dnl
|
|---|
| 51 | dnl Get cannonical host
|
|---|
| 52 | dnl
|
|---|
| 53 | AC_CANONICAL_HOST
|
|---|
| 54 | AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
|
|---|
| 55 | [Define to be the name of the operating system.])
|
|---|
| 56 |
|
|---|
| 57 | dnl
|
|---|
| 58 | dnl Process features.
|
|---|
| 59 | dnl
|
|---|
| 60 |
|
|---|
| 61 | AC_ARG_WITH(ssl,
|
|---|
| 62 | [[ --without-ssl disable SSL autodetection]])
|
|---|
| 63 |
|
|---|
| 64 | AC_ARG_ENABLE(opie,
|
|---|
| 65 | [ --disable-opie disable support for opie or s/key FTP login],
|
|---|
| 66 | ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
|
|---|
| 67 | test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
|
|---|
| 68 | [Define if you want the Opie support for FTP compiled in.])
|
|---|
| 69 |
|
|---|
| 70 | AC_ARG_ENABLE(digest,
|
|---|
| 71 | [ --disable-digest disable support for HTTP digest authorization],
|
|---|
| 72 | ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
|
|---|
| 73 | test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
|
|---|
| 74 | [Define if you want the HTTP Digest Authorization compiled in.])
|
|---|
| 75 |
|
|---|
| 76 | AC_ARG_ENABLE(ntlm,
|
|---|
| 77 | [ --disable-ntlm disable support for NTLM authorization],
|
|---|
| 78 | [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
|
|---|
| 79 |
|
|---|
| 80 | AC_ARG_ENABLE(debug,
|
|---|
| 81 | [ --disable-debug disable support for debugging output],
|
|---|
| 82 | ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
|
|---|
| 83 | test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
|
|---|
| 84 | [Define if you want the debug output support compiled in.])
|
|---|
| 85 |
|
|---|
| 86 | wget_need_md5=no
|
|---|
| 87 |
|
|---|
| 88 | case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
|
|---|
| 89 | *yes*)
|
|---|
| 90 | wget_need_md5=yes
|
|---|
| 91 | esac
|
|---|
| 92 | if test x"$ENABLE_OPIE" = xyes; then
|
|---|
| 93 | OPIE_OBJ='ftp-opie$o'
|
|---|
| 94 | fi
|
|---|
| 95 | AC_SUBST(OPIE_OBJ)
|
|---|
| 96 |
|
|---|
| 97 | dnl
|
|---|
| 98 | dnl Whether make sets $(MAKE)...
|
|---|
| 99 | dnl
|
|---|
| 100 | AC_PROG_MAKE_SET
|
|---|
| 101 |
|
|---|
| 102 | dnl
|
|---|
| 103 | dnl Find a good install
|
|---|
| 104 | dnl
|
|---|
| 105 | AC_PROG_INSTALL
|
|---|
| 106 |
|
|---|
| 107 | dnl
|
|---|
| 108 | dnl Find the compiler
|
|---|
| 109 | dnl
|
|---|
| 110 |
|
|---|
| 111 | dnl We want these before the checks, so the checks can modify their values.
|
|---|
| 112 | test -z "$CFLAGS" && CFLAGS= auto_cflags=1
|
|---|
| 113 | test -z "$CC" && cc_specified=yes
|
|---|
| 114 |
|
|---|
| 115 | AC_PROG_CC
|
|---|
| 116 | AC_AIX
|
|---|
| 117 | AM_PROG_CC_STDC
|
|---|
| 118 |
|
|---|
| 119 | dnl Turn on optimization by default. Specifically:
|
|---|
| 120 | dnl
|
|---|
| 121 | dnl if the user hasn't specified CFLAGS, then
|
|---|
| 122 | dnl if compiler is gcc, then
|
|---|
| 123 | dnl use -O2 and some warning flags
|
|---|
| 124 | dnl else
|
|---|
| 125 | dnl use os-specific flags or -O
|
|---|
| 126 | if test -n "$auto_cflags"; then
|
|---|
| 127 | if test -n "$GCC"; then
|
|---|
| 128 | CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
|
|---|
| 129 | else
|
|---|
| 130 | case "$host_os" in
|
|---|
| 131 | *hpux*) CFLAGS="$CFLAGS +O3" ;;
|
|---|
| 132 | *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
|
|---|
| 133 | *) CFLAGS="$CFLAGS -O" ;;
|
|---|
| 134 | esac
|
|---|
| 135 | fi
|
|---|
| 136 | fi
|
|---|
| 137 |
|
|---|
| 138 | dnl
|
|---|
| 139 | dnl In case of {cyg,gnu}win32. Should be a _target_ test.
|
|---|
| 140 | dnl Might also be erelevant for DJGPP.
|
|---|
| 141 | dnl
|
|---|
| 142 | case "$host_os" in
|
|---|
| 143 | *win32) exeext='.exe';;
|
|---|
| 144 | *) exeext='';;
|
|---|
| 145 | esac
|
|---|
| 146 | AC_SUBST(exeext)
|
|---|
| 147 |
|
|---|
| 148 | dnl
|
|---|
| 149 | dnl Checks for basic compiler characteristics.
|
|---|
| 150 | dnl
|
|---|
| 151 | AC_C_CONST
|
|---|
| 152 | AC_C_INLINE
|
|---|
| 153 | AC_C_VOLATILE
|
|---|
| 154 | AC_C_BIGENDIAN
|
|---|
| 155 | AC_C_PROTOTYPES
|
|---|
| 156 |
|
|---|
| 157 | if test x"$am_cv_prog_cc_stdc" != xno; then :
|
|---|
| 158 | AC_SUBST(U, [])
|
|---|
| 159 | AC_SUBST(ANSI2KNR, [])
|
|---|
| 160 | else
|
|---|
| 161 | AC_SUBST(U, [_])
|
|---|
| 162 | AC_SUBST(ANSI2KNR, [./ansi2knr])
|
|---|
| 163 | fi
|
|---|
| 164 |
|
|---|
| 165 | dnl
|
|---|
| 166 | dnl Checks for header files that might be missing.
|
|---|
| 167 | dnl
|
|---|
| 168 |
|
|---|
| 169 | dnl Check for basic headers, even those we assume the presence of.
|
|---|
| 170 | dnl This is because Autoconf default includes check for STDC_HEADERS,
|
|---|
| 171 | dnl HAVE_SYS_TYPES_H, etc. before including them.
|
|---|
| 172 | AC_HEADER_STDC
|
|---|
| 173 | AC_CHECK_HEADERS(sys/types.h sys/stat.h)
|
|---|
| 174 | dnl Now check for the others.
|
|---|
| 175 | AC_CHECK_HEADERS(string.h strings.h stdarg.h limits.h unistd.h sys/time.h)
|
|---|
| 176 | AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
|
|---|
| 177 | AC_CHECK_HEADERS(stdint.h inttypes.h signal.h setjmp.h pwd.h)
|
|---|
| 178 | AC_HEADER_TIME
|
|---|
| 179 |
|
|---|
| 180 | dnl
|
|---|
| 181 | dnl Check integral type sizes.
|
|---|
| 182 | dnl
|
|---|
| 183 | AC_CHECK_SIZEOF(short)
|
|---|
| 184 | AC_CHECK_SIZEOF(int)
|
|---|
| 185 | AC_CHECK_SIZEOF(long)
|
|---|
| 186 | AC_CHECK_SIZEOF(long long)
|
|---|
| 187 |
|
|---|
| 188 | dnl
|
|---|
| 189 | dnl Check for large file support. This check needs to come fairly
|
|---|
| 190 | dnl early because it could (in principle) affect whether functions and
|
|---|
| 191 | dnl headers are available, whether they work, etc.
|
|---|
| 192 | dnl
|
|---|
| 193 | AC_SYS_LARGEFILE
|
|---|
| 194 | AC_CHECK_SIZEOF(off_t)
|
|---|
| 195 |
|
|---|
| 196 | dnl
|
|---|
| 197 | dnl Checks for non-universal or system-specific types.
|
|---|
| 198 | dnl
|
|---|
| 199 | AC_TYPE_SIZE_T
|
|---|
| 200 | AC_TYPE_PID_T
|
|---|
| 201 | AC_CHECK_TYPES(uint32_t)
|
|---|
| 202 | AC_TYPE_SIGNAL
|
|---|
| 203 | AC_CHECK_TYPES(sig_atomic_t, [], [], [
|
|---|
| 204 | #include <stdio.h>
|
|---|
| 205 | #include <sys/types.h>
|
|---|
| 206 | #if HAVE_INTTYPES_H
|
|---|
| 207 | # include <inttypes.h>
|
|---|
| 208 | #endif
|
|---|
| 209 | #ifdef HAVE_SIGNAL_H
|
|---|
| 210 | # include <signal.h>
|
|---|
| 211 | #endif
|
|---|
| 212 | ])
|
|---|
| 213 |
|
|---|
| 214 | dnl
|
|---|
| 215 | dnl Checks for library functions.
|
|---|
| 216 | dnl
|
|---|
| 217 | AC_FUNC_ALLOCA
|
|---|
| 218 | AC_FUNC_MMAP
|
|---|
| 219 | AC_FUNC_FSEEKO
|
|---|
| 220 | AC_CHECK_FUNCS(strdup strstr strcasecmp strncasecmp strpbrk memmove)
|
|---|
| 221 | AC_CHECK_FUNCS(gettimeofday mktime strptime timegm strerror snprintf vsnprintf)
|
|---|
| 222 | AC_CHECK_FUNCS(usleep select ftello sigblock sigsetjmp signal)
|
|---|
| 223 | AC_CHECK_FUNCS(symlink access isatty strtoll strtoimax)
|
|---|
| 224 |
|
|---|
| 225 | dnl
|
|---|
| 226 | dnl Call Wget's local macros defined in aclocal.
|
|---|
| 227 | dnl
|
|---|
| 228 | WGET_STRUCT_UTIMBUF
|
|---|
| 229 | WGET_SOCKLEN_T
|
|---|
| 230 | WGET_FNMATCH
|
|---|
| 231 | WGET_NANOSLEEP
|
|---|
| 232 | WGET_POSIX_CLOCK
|
|---|
| 233 | WGET_NSL_SOCKET
|
|---|
| 234 |
|
|---|
| 235 | dnl
|
|---|
| 236 | dnl Check if we need to compile in getopt.c.
|
|---|
| 237 | dnl
|
|---|
| 238 | AC_CHECK_FUNC(getopt_long, [], [
|
|---|
| 239 | GETOPT_OBJ='getopt$o'
|
|---|
| 240 | ])
|
|---|
| 241 | AC_SUBST(GETOPT_OBJ)
|
|---|
| 242 |
|
|---|
| 243 | dnl
|
|---|
| 244 | dnl Checks for libraries.
|
|---|
| 245 | dnl
|
|---|
| 246 |
|
|---|
| 247 | dnl Check for OpenSSL
|
|---|
| 248 | if test x"$with_ssl" != x"no"
|
|---|
| 249 | then
|
|---|
| 250 | dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
|
|---|
| 251 | dnl doesn't record its dependency on libdl, so we need to make sure
|
|---|
| 252 | dnl -ldl ends up in LIBS on systems that have it. Most OSes use
|
|---|
| 253 | dnl dlopen(), but HP-UX uses shl_load().
|
|---|
| 254 | AC_CHECK_LIB(dl, dlopen, [], [
|
|---|
| 255 | AC_CHECK_LIB(dl, shl_load)
|
|---|
| 256 | ])
|
|---|
| 257 |
|
|---|
| 258 | dnl Now actually check for -lssl
|
|---|
| 259 | AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
|
|---|
| 260 | #include <openssl/ssl.h>
|
|---|
| 261 | #include <openssl/x509.h>
|
|---|
| 262 | #include <openssl/err.h>
|
|---|
| 263 | #include <openssl/rand.h>
|
|---|
| 264 | #include <openssl/des.h>
|
|---|
| 265 | #include <openssl/md4.h>
|
|---|
| 266 | #include <openssl/md5.h>
|
|---|
| 267 | ], [SSL_library_init ()])
|
|---|
| 268 | if test x"$LIBSSL" != x
|
|---|
| 269 | then
|
|---|
| 270 | AC_MSG_NOTICE([compiling in support for SSL])
|
|---|
| 271 | AC_DEFINE([HAVE_SSL], 1,
|
|---|
| 272 | [Define if SSL support is being compiled in.])
|
|---|
| 273 | SSL_OBJ='openssl$o'
|
|---|
| 274 | elif test x"$with_ssl" != x
|
|---|
| 275 | then
|
|---|
| 276 | AC_MSG_ERROR([--with-ssl was given, but OpenSSL is not available.])
|
|---|
| 277 | fi
|
|---|
| 278 | fi
|
|---|
| 279 | AC_SUBST(SSL_OBJ)
|
|---|
| 280 |
|
|---|
| 281 | dnl Enable NTLM if requested and if SSL is available.
|
|---|
| 282 | NTLM_OBJ=''
|
|---|
| 283 | if test x"$LIBSSL" != x
|
|---|
| 284 | then
|
|---|
| 285 | if test x"$ENABLE_NTLM" != xno
|
|---|
| 286 | then
|
|---|
| 287 | AC_DEFINE([ENABLE_NTLM], 1,
|
|---|
| 288 | [Define if you want the NTLM authorization support compiled in.])
|
|---|
| 289 | NTLM_OBJ='http-ntlm$o'
|
|---|
| 290 | fi
|
|---|
| 291 | else
|
|---|
| 292 | dnl If SSL is unavailable and the user explicitly requested NTLM,
|
|---|
| 293 | dnl abort.
|
|---|
| 294 | if test x"$ENABLE_NTLM" = xyes
|
|---|
| 295 | then
|
|---|
| 296 | AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
|
|---|
| 297 | fi
|
|---|
| 298 | fi
|
|---|
| 299 | AC_SUBST(NTLM_OBJ)
|
|---|
| 300 |
|
|---|
| 301 | dnl
|
|---|
| 302 | dnl Find an MD5 implementation. Since Wget rarely needs MD5, we try
|
|---|
| 303 | dnl to use an existing library implementation to save on code size.
|
|---|
| 304 | dnl
|
|---|
| 305 |
|
|---|
| 306 | if test x"$wget_need_md5" = xyes
|
|---|
| 307 | then
|
|---|
| 308 | dnl This should be moved to an AC_DEFUN, but I'm not sure how to
|
|---|
| 309 | dnl manipulate MD5_OBJ from the defun.
|
|---|
| 310 |
|
|---|
| 311 | MD5_OBJ='gen-md5$o'
|
|---|
| 312 | found_md5=no
|
|---|
| 313 |
|
|---|
| 314 | dnl Check for the system MD5 library on Solaris. We don't check for
|
|---|
| 315 | dnl something simple like "MD5Update" because there are a number of
|
|---|
| 316 | dnl MD5 implementations that use that name, but have an otherwise
|
|---|
| 317 | dnl incompatible interface. md5_calc is, hopefully, specific to the
|
|---|
| 318 | dnl Solaris MD5 library.
|
|---|
| 319 | if test x"$found_md5" = xno; then
|
|---|
| 320 | AC_CHECK_LIB(md5, md5_calc, [
|
|---|
| 321 | dnl Some installations have bogus <md5.h> in the compiler's
|
|---|
| 322 | dnl include path, making the system md5 library useless.
|
|---|
| 323 | AC_MSG_CHECKING([for working md5.h])
|
|---|
| 324 | AC_COMPILE_IFELSE([#include <md5.h>
|
|---|
| 325 | ], [
|
|---|
| 326 | AC_MSG_RESULT(yes)
|
|---|
| 327 | AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define to use Solaris MD5.])
|
|---|
| 328 | LIBS="-lmd5 $LIBS"
|
|---|
| 329 | found_md5=yes
|
|---|
| 330 | AC_MSG_NOTICE([using the Solaris MD5 implementation])
|
|---|
| 331 | ], [AC_MSG_RESULT(no)])
|
|---|
| 332 | ])
|
|---|
| 333 | fi
|
|---|
| 334 |
|
|---|
| 335 | dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
|
|---|
| 336 | dnl implementation.
|
|---|
| 337 | if test x"$found_md5" = xno; then
|
|---|
| 338 | if test x"$LIBSSL" != x; then
|
|---|
| 339 | AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define to use OpenSSL MD5.])
|
|---|
| 340 | found_md5=yes
|
|---|
| 341 | AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
|
|---|
| 342 | fi
|
|---|
| 343 | fi
|
|---|
| 344 |
|
|---|
| 345 | dnl If none of the above worked, use the one we ship with Wget.
|
|---|
| 346 | if test x"$found_md5" = xno; then
|
|---|
| 347 | AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define to use built-in MD5.])
|
|---|
| 348 | MD5_OBJ="$MD5_OBJ gnu-md5\$o"
|
|---|
| 349 | found_md5=yes
|
|---|
| 350 | AC_MSG_NOTICE([using the GNU MD5 implementation])
|
|---|
| 351 | fi
|
|---|
| 352 | fi
|
|---|
| 353 | AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
|
|---|
| 354 | AC_SUBST(MD5_OBJ)
|
|---|
| 355 |
|
|---|
| 356 | dnl **********************************************************************
|
|---|
| 357 | dnl Checks for IPv6
|
|---|
| 358 | dnl **********************************************************************
|
|---|
| 359 |
|
|---|
| 360 | dnl
|
|---|
| 361 | dnl We test for IPv6 by checking, in turn, for availability of
|
|---|
| 362 | dnl getaddrinfo, presence of the INET6 address/protocol family, and
|
|---|
| 363 | dnl the existence of struct sockaddr_in6. If any of them is missing,
|
|---|
| 364 | dnl IPv6 is disabled, and the code reverts to old-style gethostbyname.
|
|---|
| 365 | dnl
|
|---|
| 366 | dnl If --enable-ipv6 is explicitly specified on the configure command
|
|---|
| 367 | dnl line, we check for IPv6 and abort if not found. If --disable-ipv6
|
|---|
| 368 | dnl is specified, we disable IPv6 and don't check for it. The default
|
|---|
| 369 | dnl is to autodetect IPv6 and use it where available.
|
|---|
| 370 | dnl
|
|---|
| 371 |
|
|---|
| 372 | AC_ARG_ENABLE(ipv6,
|
|---|
| 373 | AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
|
|---|
| 374 | [case "${enable_ipv6}" in
|
|---|
| 375 | no)
|
|---|
| 376 | AC_MSG_NOTICE([disabling IPv6 at user request])
|
|---|
| 377 | dnl Disable IPv6 checking
|
|---|
| 378 | ipv6=no
|
|---|
| 379 | ;;
|
|---|
| 380 | yes)
|
|---|
| 381 | dnl IPv6 explicitly enabled: force its use (abort if unavailable).
|
|---|
| 382 | ipv6=yes
|
|---|
| 383 | force_ipv6=yes
|
|---|
| 384 | ;;
|
|---|
| 385 | auto)
|
|---|
| 386 | dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
|
|---|
| 387 | ipv6=yes
|
|---|
| 388 | ;;
|
|---|
| 389 | *)
|
|---|
| 390 | AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
|
|---|
| 391 | ;;
|
|---|
| 392 | esac
|
|---|
| 393 | ], [
|
|---|
| 394 | dnl If nothing is specified, assume auto-detection.
|
|---|
| 395 | ipv6=yes
|
|---|
| 396 | ]
|
|---|
| 397 | )
|
|---|
| 398 |
|
|---|
| 399 | if test "X$ipv6" = "Xyes"; then
|
|---|
| 400 | AC_CHECK_FUNCS(getaddrinfo, [], [
|
|---|
| 401 | AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
|
|---|
| 402 | ipv6=no
|
|---|
| 403 | ])
|
|---|
| 404 | fi
|
|---|
| 405 |
|
|---|
| 406 | if test "X$ipv6" = "Xyes"; then
|
|---|
| 407 | PROTO_INET6([], [
|
|---|
| 408 | AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
|
|---|
| 409 | ipv6=no
|
|---|
| 410 | ])
|
|---|
| 411 | fi
|
|---|
| 412 |
|
|---|
| 413 | if test "X$ipv6" = "Xyes"; then
|
|---|
| 414 | TYPE_STRUCT_SOCKADDR_IN6([],[
|
|---|
| 415 | AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
|
|---|
| 416 | ipv6=no
|
|---|
| 417 | ])
|
|---|
| 418 | if test "X$ipv6" = "Xyes"; then
|
|---|
| 419 | WGET_STRUCT_SOCKADDR_STORAGE
|
|---|
| 420 | MEMBER_SIN6_SCOPE_ID
|
|---|
| 421 | fi
|
|---|
| 422 | fi
|
|---|
| 423 |
|
|---|
| 424 | if test "X$ipv6" = "Xyes"; then
|
|---|
| 425 | AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
|
|---|
| 426 | AC_MSG_NOTICE([Enabling support for IPv6.])
|
|---|
| 427 | elif test "x$force_ipv6" = "xyes"; then
|
|---|
| 428 | AC_MSG_ERROR([IPv6 support requested but not found; aborting])
|
|---|
| 429 | fi
|
|---|
| 430 |
|
|---|
| 431 |
|
|---|
| 432 | dnl
|
|---|
| 433 | dnl Set of available languages.
|
|---|
| 434 | dnl
|
|---|
| 435 | dnl Originally this used to be static, looking like this:
|
|---|
| 436 | dnl ALL_LINGUAS="cs de hr it ..."
|
|---|
| 437 | dnl The downside was that configure needed to be rebuilt whenever a
|
|---|
| 438 | dnl new language was added.
|
|---|
| 439 | dnl
|
|---|
| 440 | ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
|
|---|
| 441 |
|
|---|
| 442 | dnl internationalization macros
|
|---|
| 443 | WGET_WITH_NLS
|
|---|
| 444 |
|
|---|
| 445 | dnl
|
|---|
| 446 | dnl Find makeinfo. We used to provide support for Emacs processing
|
|---|
| 447 | dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
|
|---|
| 448 | dnl unavailable, but that broke with the addition of makeinfo-specific
|
|---|
| 449 | dnl command-line options, such as `-I'. Now we depend on makeinfo to
|
|---|
| 450 | dnl build the Info documentation.
|
|---|
| 451 | dnl
|
|---|
| 452 |
|
|---|
| 453 | AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
|
|---|
| 454 |
|
|---|
| 455 | dnl
|
|---|
| 456 | dnl Find perl and pod2man
|
|---|
| 457 | dnl
|
|---|
| 458 |
|
|---|
| 459 | AC_PATH_PROGS(PERL, [perl5 perl], no)
|
|---|
| 460 | AC_PATH_PROG(POD2MAN, pod2man, no)
|
|---|
| 461 |
|
|---|
| 462 | if test "x${POD2MAN}" = xno; then
|
|---|
| 463 | COMMENT_IF_NO_POD2MAN="# "
|
|---|
| 464 | else
|
|---|
| 465 | COMMENT_IF_NO_POD2MAN=
|
|---|
| 466 | fi
|
|---|
| 467 | AC_SUBST(COMMENT_IF_NO_POD2MAN)
|
|---|
| 468 |
|
|---|
| 469 | dnl
|
|---|
| 470 | dnl Create output
|
|---|
| 471 | dnl
|
|---|
| 472 | AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
|
|---|
| 473 | po/Makefile.in windows/Makefile])
|
|---|
| 474 | AC_CONFIG_HEADERS([src/config.h])
|
|---|
| 475 | AH_BOTTOM([
|
|---|
| 476 | #include "config-post.h"
|
|---|
| 477 | ])
|
|---|
| 478 | AC_CONFIG_FILES([stamp-h], [echo timestamp > stamp-h])
|
|---|
| 479 | AC_CONFIG_COMMANDS([default], [WGET_PROCESS_PO])
|
|---|
| 480 | AC_OUTPUT
|
|---|
