source: trunk/mediafolder/Skripte_eng/Create ~M3U playlist

/* Create an *.m3u playlist from all selected tracks */

/* Load Rexxutil functions */
call RxFuncAdd 'SysLoadFuncs', 'RexxUtil', 'SysLoadFuncs'
call SysLoadFuncs

QC_FIRST=0
QC_NEXT=1
QC_LAST=2

/* Check if we are executing */
if ARG(1)\='/EXECUTE' THEN EXIT

/* The media folder running this skript */
mFldr=ARG(2)
/* And the frame handle */
frameHandle=ARG(3)

/*Get the container handle */
container=WPSWizCallWinFunc( "winQueryContainerHWND", frameHandle)

if container=0 THEN DO
    rc=RxMessageBox("Cannot get container handle!", "",'OK', "Information")
     EXIT
END

pRec=WPSWizCallWinFunc( "winQueryContRecEmphasis", container, 16 , 1)

a=0
tracks.0=0
DO WHILE (pRec\=0 & pRec\=-1)
        /* Get object pointer */
        obj=WPSWizCallWinFunc( "winObjectFromPRec", pRec)
        /* Follow shadows to file system object */
        obj=MFldrCallFunc( "cwGetFileSystemObject", mFldr, obj)
        /* Check if it's an audio object */
        IF MFldrCallFunc( "cwIsA", obj, "CWAudio")\=0 THEN DO
                a=a+1
                tracks.a._obj=obj
        END
        pRec=WPSWizCallWinFunc( "winQueryContRecEmphasis", container, pRec , 1)
        tracks.0=a
END

if tracks.0=0 THEN DO
        rc=RxMessageBox("No audio tracks selected.", "Information",'OK')
        EXIT
END

/* Try to find the desktop folder */

/* Get the persistent object handle */
hObject=WPSWizCallWinFunc( "winQueryObject" ,"<WP_DESKTOP>")

if hObject\=0 THEN DO
        /* Get the class object of the given object pointer */
        classObject=WPSWizCallWPSFunc("somGetClass",mFldr)

        /* Get the object pointer from the handle */
        theObject=WPSWizCallWPSClsFunc("wpclsQueryObject", classObject, hObject)

        /* Query the full path of the object */
        desktop=WPSWizCallFunc("cwQueryRealName", theObject, 1)

        /* The object was locked because of "wpclsQueryObject" */
        rc=WPSWizCallWPSFunc("wpUnlockObject", theObject)
END

if desktop\='' THEN
    desktop=desktop||'\new.m3u'

filedlg:

/* Get a name for the new folder from the user */
theName=WPSWizCallWinFunc( "winFileDlg", 1, "Name for play list", desktop)

/* No name, so quit */
if thename="" THEN exit

/* Check if an error occurred */
if thename="ERROR:" THEN DO
  rc=RxMessageBox("File dialog returned an error!", "Error",'OK', "ERROR")
  EXIT
END

/* Check if file exists */
IF STREAM(theName, 'C', 'query exists')=theName THEN DO

  rc=RxMessageBox("The file already exists. Do you want to add the selected tracks to the contents?", "Create *.M3U playlist",'YESNO', "QUESTION")
IF rc=7 then signal filedlg
END

/* Get the path */
thePath=FILESPEC('drive', thename)||FILESPEC('path', thename)
thePath=LEFT(thePath,LENGTH(thePath)-1)


/* Now put names into the playlist file */
DO a=1 to tracks.0
        objName=MFldrCallFunc( "cwQueryRealName", tracks.a._obj, 1)
call lineout thename, objname
END

call stream thename, 'C', 'close'

/* Open the folder */
rc=SysSetObjectData(theName, "OPEN=DEFAULT")

rc=0

exit