Context Navigation

driveio.asm@ 156

Last change on this file since 156 was 152, checked in by Ben Rietbroek, 8 years ago

Splitted-up the load/save LVM sector functions [v1.1.1-testing]

The high-level variants use '[CurPartition_Location]' to get the LBA
address of the MBR/EBR. However, we also need access to LVM information
at other points and we don't want to mess with '[CurPartition_Location]'
there. So, the new low-level variants, *XBR, take the LBA address of
the MBR/EBR and BIOS disk number in registers. Since the IPT stores the
LBA address where the partition tables for a partition are located,
the *XBR funtions now provide a convenient way to load the corresponding
LVM sector.

CAUTION:
This is a testbuild !
AirBoot uses the BIOS to access disks and a small coding error can trash
partition tables or other vital disk structures. You are advised to make
backups of TRACK0 and EBRs before using this testbuild. More info at:
https://rousseaux.github.io/netlabs.air-boot/pdf/AirBoot-v1.1.0-manual.pdf

File size: 72.4 KB

Line
1	; AiR-BOOT (c) Copyright 1998-2008 M. Kiewitz
2	;
3	; This file is part of AiR-BOOT
4	;
5	; AiR-BOOT is free software: you can redistribute it and/or modify it under
6	; the terms of the GNU General Public License as published by the Free
7	; Software Foundation, either version 3 of the License, or (at your option)
8	; any later version.
9	;
10	; AiR-BOOT is distributed in the hope that it will be useful, but WITHOUT ANY
11	; WARRANTY: without even the implied warranty of MERCHANTABILITY or FITNESS
12	; FOR A PARTICULAR PURPOSE. See the GNU General Public License for more
13	; details.
14	;
15	; You should have received a copy of the GNU General Public License along with
16	; AiR-BOOT. If not, see <http://www.gnu.org/licenses/>.
17	;
18	;---------------------------------------------------------------------------
19	; AiR-BOOT / DRIVE I/O
20	;---------------------------------------------------------------------------
21
22
23
24	IFDEF MODULE_NAMES
25	DB 'DRIVEIO',0
26	ENDIF
27
28	;
29	; Check if INT13X extensions are supported.
30	; AirBoot requires these extensions, and will halt if they are not available.
31	; Modified: [CurIO_UseExtension]
32	DriveIO_CheckFor13extensions Proc Near Uses ax bx cx dx
33	mov ah, 41h
34	mov bx, 55AAh
35	mov dl, [BIOS_BootDisk] ; We check using the boot-disk
36	int 13h
37
38	IFDEF AUX_DEBUG
39	IF 0
40	DBG_TEXT_OUT_AUX 'DriveIO_CheckFor13extensions:'
41	PUSHRF
42	call DEBUG_DumpRegisters
43	;~ call AuxIO_DumpParagraph
44	;~ call AuxIO_TeletypeNL
45	mov si, offset [Scratch]
46	mov word ptr [si], 50h
47	mov ah, 48h
48	int 13h
49	call DEBUG_DumpRegisters
50	;~ call AuxIO_DumpSector
51	POPRF
52	ENDIF
53	ENDIF
54
55	jc PCCF13E_NotFound ; Error occured
56	cmp bx, 0AA55h
57	je PCCF13E_Found
58	PCCF13E_NotFound:
59	ret
60	PCCF13E_Found:
61	and cx, 1 ; Check 42h-44h,47h,48h supported
62	jz PCCF13E_NotFound ; Sig OK but no support, strange beast
63	mov byte ptr [CurIO_UseExtension], 1
64	ret
65	DriveIO_CheckFor13extensions EndP
66
67
68	; Note: Some routines set DS/ES to CS or even address via CS, even if its not
69	; needed. This was done for SECURITY. So DO NOT remove it.
70	; Its there to make sure the correct data is loaded/written to/from
71	; harddrive.
72	;
73	; IF YOU MODIFY ANYTHING IN HERE, YOU MAY EASILY BREAK YOUR HARDDRIVE!
74
75	; Will only load base-configuration, will NOT load IPT nor Hide-Config
76	; Those are originally loaded on startup and will NOT get reloaded.
77	DriveIO_LoadConfiguration Proc Near Uses ax bx cx dx es
78
79	IFDEF AUX_DEBUG
80	IF 0
81	DBG_TEXT_OUT_AUX 'DriveIO_LoadConfiguration:'
82	PUSHRF
83	;~ call DEBUG_DumpRegisters
84	;~ call AuxIO_DumpParagraph
85	;~ call AuxIO_TeletypeNL
86	POPRF
87	ENDIF
88	ENDIF
89
90	;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
91	mov ax, cs
92	mov es, ax
93	mov bx, offset Configuration
94	xor dh, dh
95	mov dl, [BIOS_BootDisk] ; Disk we booted from
96	mov cx, 0037h ; Sector 55 (CHS)
97	mov ax, 0201h ; Function 02, read 1 sector...
98	int 13h
99	jnc DIOLC_NoError
100	call MBR_LoadError ; Will Abort BootUp
101
102
103	DIOLC_NoError:
104	ret
105	DriveIO_LoadConfiguration EndP
106
107	DriveIO_SaveConfiguration Proc Near Uses ax bx cx dx ds es si
108
109	IFDEF AUX_DEBUG
110	IF 0
111	DBG_TEXT_OUT_AUX 'DriveIO_SaveConfiguration:'
112	PUSHRF
113	;~ call DEBUG_DumpRegisters
114	;~ call AuxIO_DumpParagraph
115	;~ call AuxIO_TeletypeNL
116	POPRF
117	ENDIF
118	ENDIF
119
120	mov ax, cs
121	mov ds, ax
122	mov es, ax ; Safety first (CS==DS==ES)
123	; --- Overwrite Floppy-Name with "FloppyDrive"
124	mov si, offset TXT_Floppy_Drive
125	mov di, offset PartitionTable
126	sub di, 30 ; Adjust to Floppy-Name
127	mov cx, 11
128	rep movsb
129	mov si, offset Configuration ; Calculate new checksum
130	xor bx, bx
131
132	; Changed from 5 to calculated value (not here, see compat. issue below)
133	; Fixes issue: #2987 -- "air-boot doesn't remember drive letter"
134	; Size of the ab-configuration in 512 byte sectors
135	;mov cx, (MBR_BackUpMBR - Configuration) / 200h
136
137	; AB v1.07 stores a 5 sector configuration with a 5 sector checksum.
138	; AB v1.0.8+ should stores a 7 sector configuration with a
139	; 7 sector checksum.
140	; Because 5 was hardcoded here, SET(A)BOOT v1.07 will see see an AB v1.0.8+
141	; config as corrupted, while this is not the case.
142	; So, for compatibility reasons, in v1.0.8+, the checksum stored is over
143	; 5 sectors, to be compatible with v1.07.
144	; This may change (be corrected) in future versions !
145	mov cx,5
146
147	mov dx, [CFG_CheckConfig]
148	mov [CFG_CheckConfig], bx
149	DIOSC_Loop:
150	call MBR_GetCheckOfSector
151	loop DIOSC_Loop
152	mov [CFG_CheckConfig], bx
153	; --------------------------------------------------------------------
154	; ES == CS
155	mov bx, offset Configuration
156	xor dh, dh
157	mov dl, [BIOS_BootDisk] ; Disk we booted from
158	mov cx, 0037h ; Sector 55 (CHS)
159
160	; Changed from 5 to calculated value
161	; Fixes issue: #2987 -- "air-boot doesn't remember drive letter"
162	; Size of the ab-configuration in 512 byte sectors
163	mov al, (MBR_BackUpMBR - Configuration) / 200h
164	mov ah,03h
165	;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
166	int 13h
167	jnc DIOSC_NoError
168	call MBR_SaveError ; Will Abort BootUp
169	DIOSC_NoError:
170	ret
171	DriveIO_SaveConfiguration EndP
172
173	DriveIO_UpdateFloppyName Proc Near Uses bx cx dx ds si es di
174	mov ax, cs
175	mov ds, ax
176	mov es, ax
177
178	mov ah, 00h ; Function 0 - Reset Drive
179	xor dl, dl
180	int 13h
181	xor dx, dx ; Cylinder=0, Head=0
182	mov cx, 1 ; Sector=1, Drive=0
183	mov bx, offset TmpSector ; ES:BX - TmpSector
184	mov ax, 0201h ; Function 2 - Load Sector
185	int 13h
186	jnc DIOUFN_AllFine
187
188	; --- Overwrite Floppy-Name with "No Disc"
189	mov si, offset TXT_Floppy_NoDisc
190	xor ax, ax
191	DIOUFN_WriteFloppyName:
192	mov di, offset PartitionTable
193	sub di, 30 ; Adjust to Floppy-Name
194	mov cl, 11
195	rep movsb
196	ret ; AX=-1 -> GotDisc, =0 -> NoDisc
197
198	; --- Floppy found and read, data in TempSector
199	DIOUFN_AllFine:
200	mov ax, -1
201	mov si, offset TXT_Floppy_NoName
202	cmp wptr es:[bx+54], 'AF'
203	jne DIOUFN_WriteFloppyName
204	cmp wptr es:[bx+56], '1T'
205	jne DIOUFN_WriteFloppyName
206	cmp bptr es:[bx+58], '2'
207	jne DIOUFN_WriteFloppyName
208	mov si, bx
209	add si, 43 ; FAT12 - Volume Label Location
210	jmp DIOUFN_WriteFloppyName
211	DriveIO_UpdateFloppyName EndP
212
213	; =============================================================================
214	; HARDDRIVE / GENERAL ACCESS
215	; =============================================================================
216	; The following routines are used for harddisc/floppy access.
217	; The access is done via INT 13h/CHS or INT 13h/LBA.
218	; Access will be done prefered by INT 13h/CHS, because it's (I wonder!) much
219	; faster, than the LBA-method. I don't know, why LBA is so slow. Perhaps BIOS.
220	;
221	; Internal access (to AiR-BOOT) is always done via INT 13h/CHS.
222
223	DriveIO_GetHardDriveCount Proc Near Uses ds si
224	push ds
225	push si
226	push 0040h
227	pop ds
228	mov si, 0075h
229	mov dh, ds:[si] ; 40:75 -> POST: Total Harddiscs == DL
230	pop si
231	pop ds
232	mov [TotalHarddiscs], dh
233	ret
234	DriveIO_GetHardDriveCount EndP
235
236
237	; Fills our LBA-Usage table. It holds the LBA-address, where BIOS/CHS access is
238	; stopped and BIOS/LBA access is started.
239	; This is calculated by Sector*Heads. Comparing will get done with Bit 25-10
240	; on LBA sectors, so we actually divide sector number by 1024.
241	DriveIO_InitLBASwitchTable Proc Near Uses es di
242	mov di, offset LBASwitchTable
243	mov dh, [TotalHarddiscs]
244	mov dl, 80h ; First disk to process
245	DIOILUT_DriveLoop:
246	push dx
247	push di
248	mov ah, 08h
249	int 13h ; DISK - GET DRIVE PARAMETERS
250	mov ah, 0FBh ; Assume 255 heads/63 sectors, if error
251	jc DIOILUT_Error
252	and cl, 111111b ; Isolate lower 6 bits of CL -> sector count
253	;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
254	;movzx ax, cl
255	mov al,cl
256	mov ah,0
257
258	mov bl, dh ; DH -> max head number
259	mul bl ; AX = Sectors*Heads
260	shl ah, 1
261	shl ah, 1 ; Shift 2 bits, so we are able to compare to
262	; bit 16-23 of the LBA address
263	DIOILUT_Error:
264	pop di
265	pop dx
266	mov bptr ds:[di], ah ; Save that value
267	inc di ; Go to next BYTE
268	inc dl ; Next disk
269	dec dh ; Decrease disks to process
270	jnz DIOILUT_DriveLoop ; Next disk if DH != 0
271	ret
272	DriveIO_InitLBASwitchTable EndP
273
274	; #########################################################################
275	; Routine: Loads partition to ExecBase and checks for validity
276	; #########################################################################
277	; Calling : bx:ax - Absolute sector
278	; cx:dx - Cylinder/Sector, Side/Drive (hi/lo-byte)
279	; Returns : Carry Set if invalid partition encountered
280	; Preserve: all registers
281	; #########################################################################
282	DriveIO_LoadPartition Proc Near Uses si
283
284	IFDEF AUX_DEBUG
285	IF 0
286	DBG_TEXT_OUT_AUX 'DriveIO_LoadPartition:'
287	PUSHRF
288	call DEBUG_DumpRegisters
289	;~ call AuxIO_DumpParagraph
290	;~ call AuxIO_TeletypeNL
291	POPRF
292	ENDIF
293	ENDIF
294
295	mov wptr cs:[CurPartition_Location+0], ax
296	mov wptr cs:[CurPartition_Location+2], bx
297	mov wptr cs:[CurPartition_Location+4], dx
298	mov wptr cs:[CurPartition_Location+6], cx ; Saves the location
299	mov si, offset PartitionSector ; DS:SI - ExecBase
300
301
302	;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
303	call DriveIO_LoadSector
304
305	clc
306	cmp wptr [si+LocBR_Magic], 0AA55h
307	je DIOLP_Success
308	; We check, if we are scanning partitions. In that case, if CHS is not 0/0/1
309	; we will display a "bad partition table" message and halt the system.
310	cmp cx, 0001h
311	jne DIOLP_Failed
312	or dh, dh
313	jnz DIOLP_Failed
314	stc ; Set carry, so no partition table
315	DIOLP_Success:
316
317
318
319	ret
320	DIOLP_Failed:
321	jmp DriveIO_GotLoadError
322	DriveIO_LoadPartition EndP
323
324	; #########################################################################
325	; Routine: Writes a partition from ExecBase to its original sector
326	; #########################################################################
327	; Calling : none
328	; Returns : none
329	; Preserve: all registers
330	; #########################################################################
331	DriveIO_SavePartition Proc Near Uses ax bx cx dx si
332
333	IFDEF AUX_DEBUG
334	IF 0
335	DBG_TEXT_OUT_AUX 'DriveIO_SavePartition:'
336	PUSHRF
337	;~ call DEBUG_DumpRegisters
338	;~ call AuxIO_DumpParagraph
339	;~ call AuxIO_TeletypeNL
340	POPRF
341	ENDIF
342	ENDIF
343
344	mov ax, wptr cs:[CurPartition_Location+0]
345	mov bx, wptr cs:[CurPartition_Location+2]
346	mov dx, wptr cs:[CurPartition_Location+4]
347	mov cx, wptr cs:[CurPartition_Location+6] ; Gets prev. saved location
348	mov si, offset PartitionSector ; DS:SI - ExecBase
349	cmp wptr [si+LocBR_Magic], 0AA55h ; Checks for signature, if not found
350	jne DIOSP_SevereError ; we assume a really bad error
351	call DriveIO_SaveSector
352	DIOSP_SevereError:
353	ret
354	DriveIO_SavePartition EndP
355
356
357
358	;##############################################################################
359	;# The location of LVM sectors depends on the OS/2 geometry used when the disk
360	;# was prepared. This geometry is present in the Master LVM sector, which has
361	;# already been located if it exists. All partitions, whether primary or
362	;# logical, have an entry in a partition table. For primary partitions this
363	;# table is located in the MBR, while for logical partitions this table is
364	;# located in the EBR for that logical partition. An LVM record is located
365	;# LVM_SPT-1 sectors above an MBR or EBR. The Master LVM record contains the
366	;# information for all primary partitions. For logical partitions, the LVM
367	;# sector only has one entry, because EBRs are chained. The global LVM info,
368	;# like disk-name, sectors per track, etc. is replicated between the Master
369	;# LVM sector and LVM sectors corresponding to logical partitions. This info
370	;# is kept in sync by the OS/2 LVM Engine.
371	;##############################################################################
372	;# ACTION : Attempts to load the corresponding LVM sector for a partition
373	;# ----------------------------------------------------------------------------
374	;# EFFECTS : Modifies DAP structure and fills or clears sector buffer
375	;# ----------------------------------------------------------------------------
376	;# IN : MEM - Location info is in [CurPartition_Location]
377	;# ----------------------------------------------------------------------------
378	;# OUT : CF=1 - failure, no valid LVM sector was loaded
379	;# : SI - Points to the sector buffer ([LVMSector])
380	;##############################################################################
381	DriveIO_LoadLVMSector Proc Near Uses ax bx cx dx di
382
383	IFDEF AUX_DEBUG
384	IF 0
385	DBG_TEXT_OUT_AUX 'DriveIO_LoadLVMSector:'
386	PUSHRF
387	call DEBUG_DumpRegisters
388	;~ call AuxIO_DumpSector
389	;~ call AuxIO_DumpParagraph
390	;~ call AuxIO_TeletypeNL
391	POPRF
392	ENDIF
393	ENDIF
394
395	; Clear the sector buffer
396	mov si, offset [LVMSector]
397	call ClearSectorBuffer
398
399	; Quit with CY if LVM is ignored in SETUP
400	test byte ptr [CFG_IgnoreLVM], 1 ; ZF=0 means ignore LVM
401	jnz DIOLLVMS_NoLVMSector ; Quit if so
402
403	; Load the location of the current partition being acted upon.
404	; Note that this is not the actual LBA of the partition, but the
405	; sector that has the partition table that contains the entry
406	; for the partition. In other words, for primary partitions the LBA
407	; address points to the MBR while for extended partitions it points
408	; to an EBR. In both cases the LVM sector is located LVM_SPT-1 above.
409	; Also note that the BIOS CHS values (DH and CX) below are not used,
410	; because we explicitly use LBA sector loading.
411	mov ax, wptr cs:[CurPartition_Location+0] ; LBA lo of MBR/EBR
412	mov bx, wptr cs:[CurPartition_Location+2] ; LBA hi of MBR/EBR
413	mov dx, wptr cs:[CurPartition_Location+4] ; BIOS disk num & head
414	mov cx, wptr cs:[CurPartition_Location+6] ; BIOS cyl & sec
415
416	; Do the actual loading.
417	; This is in a separate function so that LVM records can also be
418	; loaded using the MBR/EBR LBA addresses from IPT entries.
419	call DriveIO_LoadLVMSectorXBR
420	jc DIOLLVMS_NoLVMSector
421
422	; We're done, indicate success and return
423	clc
424	jmp DIOLLVMS_Done
425
426	DIOLLVMS_NoLVMSector:
427
428	; Clear the sector buffer
429	mov si, offset [LVMSector]
430	call ClearSectorBuffer
431	mov bptr [si+LocLVM_SignatureStart], 0
432
433	; Indicate no valid LVM sector was loaded
434	stc
435
436	DIOLLVMS_Done:
437
438	ret
439	DriveIO_LoadLVMSector EndP
440
441
442
443
444
445	;------------------------------------------------------------------------------
446	; Attempts to load the corresponding LVM sector for a partition
447	;------------------------------------------------------------------------------
448	; IN : AX - LBA lo of MBR or EBR
449	; : BX - LBA hi of MBR or EBR
450	; ; DL - BIOS disk number
451	; ; SI - Pointer to sector buffer (usually [LVMSec])
452	; OUT : CF=0 - A valid LVM sector was loaded
453	; NOTE : LocIPT_AbsolutePartTable and LocIPT_Drive can provide LBA and DISK
454	;------------------------------------------------------------------------------
455	DriveIO_LoadLVMSectorXBR Proc Near
456
457	IFDEF AUX_DEBUG
458	IF 1
459	DBG_TEXT_OUT_AUX 'DriveIO_LoadLVMSectorXBR:'
460	PUSHRF
461	call DEBUG_DumpRegisters
462	;~ call AuxIO_DumpSector
463	;~ call AuxIO_DumpParagraph
464	;~ call AuxIO_TeletypeNL
465	POPRF
466	ENDIF
467	ENDIF
468
469	; Save all registers
470	pusha
471
472	; Calculate the entry in the DISKINFO array for this disk,
473	; and put the LVM_SPT in DI
474	push bx
475	call DriveIO_CalcDiskInfoPointer
476	mov di, [bx+LocDISKINFO_LVM_Secs]
477	pop bx
478
479	; If the LVM_SPT is ZERO, no LVM info is present and we quit with CY
480	test di, di ; See if it is 0
481	jz DriveIO_LoadLVMSectorXBR_no_lvm ; Quit if so
482
483	; Adjust the location to point to the LVM sector
484	add ax, di ; Add the LVM sectors-per-track
485	adc bx, 0 ; Propagate LBA lo overflow to LBA hi
486	sub ax, 1 ; LVM sector is located one sector below
487	sbb bx, 0 ; Propagate borrow to LBA hi
488
489	; Load the LVM sector into sector buffer pointed to by SI
490	mov di, ds ; Segment of that buffer
491	call DriveIO_ReadSectorLBA ; Read the LVM sector
492
493	IFDEF AUX_DEBUG
494	IF 1
495	DBG_TEXT_OUT_AUX 'LVMSecLoaded'
496	PUSHRF
497	call DEBUG_DumpRegisters
498	;~ call AuxIO_DumpSector
499	mov cx, 3
500	@@:
501	call AuxIO_DumpParagraph
502	call AuxIO_TeletypeNL
503	add si, 16
504	loop @B
505	;~ call AuxIO_DumpParagraph
506	;~ call AuxIO_TeletypeNL
507	POPRF
508	ENDIF
509	ENDIF
510
511	jc DriveIO_LoadLVMSectorXBR_no_lvm ; Quit on error
512
513	; Check the validity of the LVM sector, quit with CY if invalid
514	call LVM_ValidateSector ; Check signature and CRC
515	jnc DriveIO_LoadLVMSectorXBR_no_lvm ; Quit if not valid
516
517	; We're done, indicate success and return
518	clc
519	jmp DriveIO_LoadLVMSectorXBR_done
520
521	DriveIO_LoadLVMSectorXBR_no_lvm:
522	; Indicate no valid LVM sector was loaded
523	stc
524
525	DriveIO_LoadLVMSectorXBR_done:
526	; Restore all registers
527	popa
528
529	ret
530	DriveIO_LoadLVMSectorXBR EndP
531
532
533	;##############################################################################
534	;# The location of LVM sectors depends on the OS/2 geometry used when the disk
535	;# was prepared. This geometry is present in the Master LVM sector, which has
536	;# already been located if it exists. All partitions, whether primary or
537	;# logical, have an entry in a partition table. For primary partitions this
538	;# table is located in the MBR, while for logical partitions this table is
539	;# located in the EBR for that logical partition. An LVM record is located
540	;# LVM_SPT-1 sectors above an MBR or EBR. The Master LVM record contains the
541	;# information for all primary partitions. For logical partitions, the LVM
542	;# sector only has one entry, because EBRs are chained. The global LVM info,
543	;# like disk-name, sectors per track, etc. is replicated between the Master
544	;# LVM sector and LVM sectors corresponding to logical partitions. This info
545	;# is kept in sync by the OS/2 LVM Engine.
546	;##############################################################################
547	;# ACTION : Attempts to save the corresponding LVM sector for a partition
548	;# ----------------------------------------------------------------------------
549	;# EFFECTS : Modifies DAP structure and writes LVM sector to disk
550	;# ----------------------------------------------------------------------------
551	;# IN : MEM - Location info is in [CurPartition_Location]
552	;# : SI - Pointer to sector buffer
553	;# ----------------------------------------------------------------------------
554	;# OUT : CF=1 - failure, no valid LVM sector was saved
555	;##############################################################################
556	DriveIO_SaveLVMSector Proc Near Uses ax bx cx dx di
557
558	IFDEF AUX_DEBUG
559	IF 0
560	DBG_TEXT_OUT_AUX 'DriveIO_SaveLVMSector:'
561	PUSHRF
562	call DEBUG_DumpRegisters
563	;~ call AuxIO_DumpParagraph
564	;~ call AuxIO_TeletypeNL
565	POPRF
566	ENDIF
567	ENDIF
568
569	; Quit with CY if LVM is ignored in SETUP
570	test byte ptr [CFG_IgnoreLVM], 1 ; ZF=0 means ignore LVM
571	jnz DIOSLVMS_NoLVMSector ; Quit if so
572
573	; Load the location of the current partition being acted upon.
574	; Note that this is not the actual LBA of the partition, but the
575	; sector that has the partition table that contains the entry
576	; for the partition. In other words, for primary partitions the LBA
577	; address points to the MBR while for extended partitions it points
578	; to an EBR. In both cases the LVM sector is located LVM_SPT-1 above.
579	; Also note that the BIOS CHS values (DH and CX) below are not used,
580	; because we explicitly use LBA sector loading.
581	mov ax, wptr cs:[CurPartition_Location+0] ; LBA lo of MBR/EBR
582	mov bx, wptr cs:[CurPartition_Location+2] ; LBA hi of MBR/EBR
583	mov dx, wptr cs:[CurPartition_Location+4] ; BIOS disk num & head
584	mov cx, wptr cs:[CurPartition_Location+6] ; BIOS cyl & sec
585
586	; Do the actual saving.
587	; This is in a separate function so that LVM records can also be
588	; saved using the MBR/EBR LBA addresses from IPT entries.
589	call DriveIO_SaveLVMSectorXBR
590	jc DIOSLVMS_NoLVMSector
591
592	; We're done, indicate success and return
593	clc
594	jmp DIOSLVMS_Done
595
596	DIOSLVMS_NoLVMSector:
597	; Indicate no valid LVM sector was saved
598	stc
599
600	DIOSLVMS_Done:
601	ret
602	DriveIO_SaveLVMSector EndP
603
604
605	;------------------------------------------------------------------------------
606	; Attempts to save the corresponding LVM sector for a partition
607	;------------------------------------------------------------------------------
608	; IN : AX - LBA lo of MBR or EBR
609	; : BX - LBA hi of MBR or EBR
610	; ; DL - BIOS disk number
611	; ; SI - Pointer to sector buffer (usually [LVMSec])
612	; OUT : CF=0 - A valid LVM sector was saved
613	; NOTE : LocIPT_AbsolutePartTable and LocIPT_Drive can provide LBA and DISK
614	;------------------------------------------------------------------------------
615	DriveIO_SaveLVMSectorXBR Proc Near
616
617	; Save all registers
618	pusha
619
620	; Check the validity of the LVM sector, quit with CY if invalid
621	push ax ; Save LBA lo
622	call LVM_ValidateSector ; Check signature and CRC
623	pop ax ; Restore LBA lo
624	jnc DriveIO_SaveLVMSectorXBR_no_lvm ; Quit if not valid
625
626	; Calculate the entry in the DISKINFO array for this disk,
627	; and put the LVM_SPT in DI
628	push bx
629	call DriveIO_CalcDiskInfoPointer
630	mov di, [bx+LocDISKINFO_LVM_Secs]
631	pop bx
632
633	; If the LVM_SPT is ZERO, no LVM info is present and we quit with CY
634	test di, di ; See if it is 0
635	jz DriveIO_SaveLVMSectorXBR_no_lvm ; Quit if so
636
637	; Adjust the location to point to the LVM sector
638	add ax, di ; Add the LVM sectors-per-track
639	adc bx, 0 ; Propagate LBA lo overflow to LBA hi
640	sub ax, 1 ; LVM sector is located one sector below
641	sbb bx, 0 ; Propagate borrow to LBA hi
642
643	; Save the LVM sector pointed to by SI
644	mov di, ds ; Segment of that buffer
645	call DriveIO_WriteSectorLBA ; Read the LVM sector
646
647	IFDEF AUX_DEBUG
648	IF 1
649	DBG_TEXT_OUT_AUX 'LVMSecSaved'
650	PUSHRF
651	call DEBUG_DumpRegisters
652	call AuxIO_DumpSector
653	;~ call AuxIO_DumpParagraph
654	;~ call AuxIO_TeletypeNL
655	POPRF
656	ENDIF
657	ENDIF
658
659	jc DriveIO_SaveLVMSectorXBR_no_lvm ; Quit on error
660
661	; We're done, indicate success and return
662	clc
663	jmp DriveIO_SaveLVMSectorXBR_done
664
665	DriveIO_SaveLVMSectorXBR_no_lvm:
666	; Indicate no valid LVM sector was loaded
667	stc
668
669	DriveIO_SaveLVMSectorXBR_done:
670	; Restore all registers
671	popa
672
673	ret
674	DriveIO_SaveLVMSectorXBR EndP
675
676
677
678	; Special error message instead of "LOAD ERROR" during partition scanning,
679	; so users will notice that something is bad with their partition table(s)
680	DriveIO_GotLoadError Proc Near
681	test byte ptr cs:[CurIO_Scanning], 1 ; Must be CS:, cause DS!=CS maybe here
682	jnz InScanMode
683	jmp MBR_LoadError
684	InScanMode:
685	mov si, offset TXT_BrokenPartitionTable
686	push cs
687	pop ds
688	call MBR_Teletype
689	mov si, offset BrokenHDD
690	sub dl, 50h ; 80h -> '0'
691	cmp dl, 39h
692	jbe DIOGLE_BelowA
693	add dl, 7 ; 3Ah -> 'A'
694	DIOGLE_BelowA:
695	mov bptr [si+5], dl
696	call MBR_Teletype
697
698	; JWasm: cannot jump to local label in other procedure.
699	; Changed to halt here.
700	;jmp MBRLE_Halt
701	DriveIO_GotLoadError_halt:
702	jmp DriveIO_GotLoadError_halt
703	DriveIO_GotLoadError EndP
704
705	; #########################################################################
706	; Routine: Loads a specified sector to DS:DI
707	; #########################################################################
708	; Calling : bx:ax - Absolute sector
709	; cx:dx - Cylinder/Sector, Side/Drive (hi/lo-byte)
710	; ds:si - Destination-Adress
711	; Returns : none
712	; Preserve: all registers
713	; #########################################################################
714	DriveIO_LoadSector Proc Near Uses ax bx cx dx ds si es di
715
716	IFDEF AUX_DEBUG
717	IF 0
718	DBG_TEXT_OUT_AUX 'DriveIO_LoadSector:'
719	PUSHRF
720	call DEBUG_DumpRegisters
721	;~ call AuxIO_DumpParagraph
722	;~ call AuxIO_TeletypeNL
723	POPRF
724	ENDIF
725	ENDIF
726
727	; Is the drive not a harddrive?
728	cmp dl, 80h
729	jb DIOLS_UseNormal
730
731	test byte ptr cs:[CurIO_UseExtension], 1
732	jz DIOLS_UseNormal
733	; Are we forced do use LBA via Setting?
734	jnz DIOLS_UseExtension
735
736	; Upper 8 bits of LBA-address set?
737	; Then use LBA (maximum boundary is 16320x16x63 = FB0400h)
738	or bh, bh
739	jnz DIOLS_UseExtension
740	; Compare Switch-Table value to bit 16-23 of LBA-address
741	mov di, dx
742	and di, 007Fh
743	cmp bptr cs:[LBASwitchTable+di], bl
744	jbe DIOLS_UseExtension
745
746	DIOLS_UseNormal:
747
748	IFDEF AUX_DEBUG
749	IF 0
750	DBG_TEXT_OUT_AUX 'DriveIO_ReadSectorCHS:'
751	PUSHRF
752	call DEBUG_DumpRegisters
753	call AuxIO_DumpParagraph
754	call AuxIO_TeletypeNL
755	POPRF
756	ENDIF
757	ENDIF
758
759	mov di, 3 ; retry count
760	DIOLS_ErrorLoop:
761	push ds
762	pop es
763	mov bx, si ; ES:BX - Destination
764	mov ax, 0201h ; Function 2 - Load Sector
765	int 13h
766	jnc DIOLS_Success
767	dec di ; decrement retry count
768	jnz DIOLS_ErrorLoop
769
770	; Sector load failed...
771	jmp DriveIO_GotLoadError
772
773	DIOLS_UseExtension:
774
775	mov di, ds ; segment for transfer address
776	call DriveIO_ReadSectorLBA ; extended read
777	jc DriveIO_GotLoadError ; halt on error
778
779	;~ push cx
780	;~ mov cs:[INT13X_DAP_NumBlocks], 1 ; Copy ONE sector
781	;~ mov wptr cs:[INT13X_DAP_Transfer+0], si
782	;~ mov cx, ds
783	;~ mov wptr cs:[INT13X_DAP_Transfer+2], cx ; Fill out Transfer Adress
784	;~ mov wptr cs:[INT13X_DAP_Absolute+0], ax
785	;~ mov wptr cs:[INT13X_DAP_Absolute+2], bx ; Fill out Absolute Sector
786	;~ push cs
787	;~ pop ds
788	;~ mov si, offset [INT13X_DAP]
789	;~ mov ah, 42h ; Extended Read
790	;~ int 13h
791	;~ pop cx
792	;~ jnc DIOLS_Success
793
794	; Sector load failed...
795	;~ jmp DriveIO_GotLoadError
796
797	DIOLS_Success:
798
799	IFDEF AUX_DEBUG
800	IF 0
801	DBG_TEXT_OUT_AUX 'sector loaded'
802	PUSHRF
803	;~ call DEBUG_DumpRegisters
804	;~ call AuxIO_DumpSector
805	mov cx, 32
806	@@:
807	call AuxIO_DumpParagraph
808	call AuxIO_TeletypeNL
809	add si, 16
810	loop @B
811	POPRF
812	ENDIF
813	ENDIF
814	ret
815	DriveIO_LoadSector EndP
816
817
818	;##############################################################################
819	;# ACTION : Loads the Master Boot Record from the specified drive into buffer
820	;# ----------------------------------------------------------------------------
821	;# EFFECTS : Modifies DAP structure and fills or clears transfer buffer
822	;# ----------------------------------------------------------------------------
823	;# IN : DL - BIOS disk number (80h,81h,etc)
824	;# : SI - Pointer to transfer buffer
825	;# ----------------------------------------------------------------------------
826	;# OUT : CF=1 - failure
827	;# : AL.0 - MBR signature present
828	;# : AL.1 - Primary partitions present
829	;# : AL.2 - Extended partitions present
830	;# : AL.3 - AiR-BOOT signature present
831	;# : AL.4:7 - Reserved, returned as 0
832	;# : AH.0:7 - Reserved, returned as 0
833	;##############################################################################
834	DriveIO_LoadMBR Proc Near uses bx cx dx si di
835
836	; Always clear the transfer buffer first
837	call ClearSectorBuffer
838
839	; Assume an invalid MBR
840	xor ax, ax
841
842	; Accept only valid harddisks
843	call DriveIO_IsValidHarddisk
844	jc DriveIO_LoadMBR_exit
845
846	; Save the address of the transfer buffer
847	mov di, si
848
849	; Read the MBR from disk
850	xor ax, ax ; LBA low
851	xor bx, bx ; LBA high
852	xor dh, dh ; Head 0
853	mov cx, 1 ; Sector 1
854	call DriveIO_LoadSector ; Read the sector from disk
855
856	; Check the loaded MBR for a signature
857	xor ax, ax ; Assume an invalid MBR
858	mov dx, [si+LocBR_Magic] ; Get word from MBR signature location
859	cmp dx, 0aa55h ; Is it the magic value ?
860	jne DriveIO_LoadMBR_exit ; Nope, no need to test anything else
861
862	; Indicate we have a MBR signature
863	or al, 01h
864
865	; Advance to the partition table
866	add si, 01beh
867
868	; Total of 4 entries to check
869	mov cx, 4
870
871	DriveIO_LoadMBR_next_entry:
872	mov dl, [si+LocBRPT_SystemID] ; Get partition-type / system-id
873	add si, 10h ; Point to next entry
874	test dl, dl ; Nothing in this one ?
875	loopz DriveIO_LoadMBR_next_entry ; Then check next entry
876
877	; All entries checked and last one was also empty, we're done
878	jz DriveIO_LoadMBR_check_ab
879
880	; Found a non-empty entry, set bits according to its type
881	cmp dl, 05h ; Old style extended container ?
882	jne @F ; Nope...
883	or al, 04h ; Yep, mark ext. container present
884	@@: cmp dl, 0fh ; New style extended container ?
885	jne @F ; Nope...
886	or al, 04h ; Yep, mark ext. container present
887	@@: or al, 02h ; Then is must be a primary
888	jcxz DriveIO_LoadMBR_check_ab ; CX=0? Then all entries processed,
889	jmp DriveIO_LoadMBR_next_entry ; otherwise check next entry
890
891	; Check if an AiR-BOOT signature is present
892	DriveIO_LoadMBR_check_ab:
893	mov si, offset [MBR_ABSig] ; Offset of AiR-BOOT signature
894	inc di ; Advance buffer pointer
895	inc di ; to AiR-BOOT signature location
896	mov cx, 7 ; Length of AiR-BOOT signature
897	cld ; Direction upwards
898	repe cmpsb ; Compare 7 bytes
899	jne DriveIO_LoadMBR_exit ; Nope, no AiR-BOOT on this disk
900	or al, 08h ; Yep, AiR-BOOT is on this disk
901	;~ jmp DriveIO_LoadMBR_exit
902
903	DriveIO_LoadMBR_exit:
904	ret
905	DriveIO_LoadMBR EndP
906
907
908	;##############################################################################
909	;# ACTION : Reads a sector from disk using INT13 extensions
910	;# ----------------------------------------------------------------------------
911	;# EFFECTS : Modifies DAP structure and fills transfer buffer
912	;# ----------------------------------------------------------------------------
913	;# IN : BX:AX - LBA address of sector
914	;# : DI:SI - SEG:OFF of transfer buffer
915	;# ----------------------------------------------------------------------------
916	;# OUT : CF=1 - failure
917	;##############################################################################
918	DriveIO_ReadSectorLBA Proc Near
919
920	IFDEF AUX_DEBUG
921	IF 0
922	DBG_TEXT_OUT_AUX 'DriveIO_ReadSectorLBA:'
923	PUSHRF
924	call DEBUG_DumpRegisters
925	call AuxIO_DumpParagraph
926	call AuxIO_TeletypeNL
927	POPRF
928	ENDIF
929	ENDIF
930
931	; Push all registers
932	pusha
933	push ds
934	push es
935
936	; One sector to read
937	mov cs:[INT13X_DAP_NumBlocks], 1
938
939	; Setup transfer address
940	mov wptr cs:[INT13X_DAP_Transfer+0], si ; offset
941	mov wptr cs:[INT13X_DAP_Transfer+2], di ; segment
942
943	; Setup LBA64 address of requested sector
944	mov wptr cs:[INT13X_DAP_Absolute+0], ax ; low word lower part
945	mov wptr cs:[INT13X_DAP_Absolute+2], bx ; high word lower part
946	mov wptr cs:[INT13X_DAP_Absolute+4], 0 ; low word upper part
947	mov wptr cs:[INT13X_DAP_Absolute+6], 0 ; high word upper part
948
949	; Address of packet
950	mov si, offset [INT13X_DAP] ; disk address packet
951
952	; Do the extended read
953	mov ah, 42h ; read function
954	int 13h ; transfer to bios
955
956	; Error occured
957	jc DriveIO_ReadSectorLBA_exit
958
959	; AH should also be zero
960	test ah, ah
961	stc
962	jnz DriveIO_ReadSectorLBA_exit
963
964	; Disk read succeeded, clear CF
965	clc
966
967	DriveIO_ReadSectorLBA_exit:
968
969	; Pop all registers
970	pop es
971	pop ds
972	popa
973
974	ret
975	DriveIO_ReadSectorLBA EndP
976
977
978
979	;##############################################################################
980	;# ACTION : Writes a sector to disk using INT13 extensions
981	;# ----------------------------------------------------------------------------
982	;# EFFECTS : Modifies DAP structure and mofifies the disk
983	;# ----------------------------------------------------------------------------
984	;# IN : BX:AX - LBA address of sector
985	;# : DI:SI - SEG:OFF of transfer buffer
986	;# ----------------------------------------------------------------------------
987	;# OUT : CF=1 - failure
988	;##############################################################################
989	DriveIO_WriteSectorLBA Proc Near
990
991	IFDEF AUX_DEBUG
992	IF 0
993	DBG_TEXT_OUT_AUX 'DriveIO_WriteSectorLBA:'
994	PUSHRF
995	call DEBUG_DumpRegisters
996	call AuxIO_DumpParagraph
997	call AuxIO_TeletypeNL
998	POPRF
999	ENDIF
1000	ENDIF
1001
1002	; Push all registers
1003	pusha
1004	push ds
1005	push es
1006
1007	; One sector to read
1008	mov cs:[INT13X_DAP_NumBlocks], 1
1009
1010	; Setup transfer address
1011	mov wptr cs:[INT13X_DAP_Transfer+0], si ; offset
1012	mov wptr cs:[INT13X_DAP_Transfer+2], di ; segment
1013
1014	; Setup LBA64 address of requested sector
1015	mov wptr cs:[INT13X_DAP_Absolute+0], ax ; low word lower part
1016	mov wptr cs:[INT13X_DAP_Absolute+2], bx ; high word lower part
1017	mov wptr cs:[INT13X_DAP_Absolute+4], 0 ; low word upper part
1018	mov wptr cs:[INT13X_DAP_Absolute+6], 0 ; high word upper part
1019
1020	; Address of packet
1021	mov si, offset [INT13X_DAP] ; disk address packet
1022
1023	; Do the extended write
1024	xor al, al ; no write verify
1025	mov ah, 43h ; write function
1026	int 13h ; transfer to bios
1027
1028	; Error occured
1029	jc DriveIO_WriteSectorLBA_exit
1030
1031	; AH should also be zero
1032	test ah, ah
1033	stc
1034	jnz DriveIO_WriteSectorLBA_exit
1035
1036	; Disk write succeeded, clear CF
1037	clc
1038
1039	DriveIO_WriteSectorLBA_exit:
1040
1041	; Pop all registers
1042	pop es
1043	pop ds
1044	popa
1045
1046	ret
1047	DriveIO_WriteSectorLBA EndP
1048
1049
1050
1051
1052	;##############################################################################
1053	;# The Master LVM sector is not necessarily located at the end of the BIOS
1054	;# view of TRACK0. Its location depends on the OS/2 geometry active when the
1055	;# disk was partitioned. For disks < 502MiB this will most likely be LBA sector
1056	;# 62, but for disks >502MiB, extended OS/2 geometry was used and DANIS506
1057	;# uses SPT=127 for disks < 1TiB while IBMS506 uses SPT=255.
1058	;# When a huge disk < 1TiB was partitioned with IBMS506, thus using SPT=255,
1059	;# and the driver was later changed to DANIS506, DANI uses SPT=255, eventhough
1060	;# the disk < 1TiB. Whether it is DANI that is LVM aware or something else
1061	;# (maybe LVM itself) that makes DANI use the correct geometry has yet to be
1062	;# investigated.
1063	;#
1064	;# Related geometry issues are also present with USB sticks, which can get
1065	;# assigned a geometry by OS/2, which can depend if the stick was partitioned
1066	;# on foreign systems or not, or even OS/2 manufacturing a geometry that is not
1067	;# the same as the BIOS reports to us here. In both cases, fixed disks and
1068	;# removable disks, the geometry recorded in the BPB of a partition can also
1069	;# influence the geometry that OS/2 assigns. This is the case when 'preparing'
1070	;# disks for LVM use, in which case BPB values could be incorporated.
1071	;#
1072	;# What this all boils down to, is that the geometry reported by the BIOS is
1073	;# of no practical use, especially not when taking BIOS USB MSD emulation into
1074	;# account. These are among the reasons why AirBoot needs to use LBA addressing
1075	;# when handling LVM stuff and why LBA use cannot be disabled in the SETUP
1076	;# anymore.
1077	;#
1078	;# So, a Master LVM sector can be present on any sector from LBA 254 downwards
1079	;# and the only way to locate the correct one is to scan all the way down and,
1080	;# if one is found, do proper validation on its values, because it may also be
1081	;# a 'phantom' LVM sector left over from previous partition layouts.
1082	;# Most of such 'phantoms' can be filtered out by verifying the location of
1083	;# the found sector against the OS/2 geometry it specifies itself, which means
1084	;# it must be located at the LBA of the SPT-1 it specifies.
1085	;##############################################################################
1086	;# ACTION : Locates the Master LVM sector on the specified disk
1087	;# ----------------------------------------------------------------------------
1088	;# EFFECTS : Leaves [Scratch] with last sector read or cleared
1089	;# ----------------------------------------------------------------------------
1090	;# IN : DL - BIOS disk number of drive to search
1091	;# ----------------------------------------------------------------------------
1092	;# OUT : CF=1 - found
1093	;# : BX:AX - LBA address of LVM sector if found, 0 otherwise
1094	;##############################################################################
1095	DriveIO_LocateMasterLVMSector Proc Near uses cx dx si di ds es
1096
1097	IFDEF AUX_DEBUG
1098	IF 1
1099	DBG_TEXT_OUT_AUX 'DriveIO_LocateMasterLVMSector:'
1100	PUSHRF
1101	call DEBUG_DumpRegisters
1102	;~ call AuxIO_DumpSector
1103	;~ call AuxIO_DumpParagraph
1104	;~ call AuxIO_TeletypeNL
1105	POPRF
1106	ENDIF
1107	ENDIF
1108
1109	; LBA address to start scanning down from
1110	mov cx, 255
1111
1112	; Make sure ES==DS
1113	push ds
1114	pop es
1115
1116	; Because JCXZ is used, LBA sector 0 is never loaded and checked.
1117	; This is of course no problem since it is the MBR.
1118	DriveIO_LocateMasterLVMSector_next:
1119	mov si, offset [Scratch] ; Use scratch area to load sectors
1120	call ClearSectorBuffer ; Clear the scratch area
1121	clc ; Indicate Master LVM sector not found
1122	jcxz DriveIO_LocateMasterLVMSector_done
1123
1124	; Read the LBA sector specified in CX
1125	mov ax, cx ; LBA low
1126	xor bx, bx ; LBA high
1127	mov di, ds ; Segment of scratch buffer
1128	mov si, offset [Scratch] ; Offset of scratch buffer
1129	call DriveIO_ReadSectorLBA ; Read the sector
1130	lahf ; Save CF
1131	dec cx ; Prepare LBA of next sector to read
1132	sahf ; Restore CF
1133	; No need to do any LVM sector validation when read error, read next
1134	jc DriveIO_LocateMasterLVMSector_next
1135
1136	; See if the read sector has a valid signature and checksum
1137	call LVM_ValidateSector
1138
1139	; NC indicates invalid or none-LVM sector, read next
1140	jnc DriveIO_LocateMasterLVMSector_next
1141
1142	; We have found a valid LVM sector !
1143	; So it contains the OS/2 geometry for the disk.
1144	; That means this LVM sector itself must be located on the last sector
1145	; of the SPT value its OS/2 geometery specifies, which, in LBA terms
1146	; is LVM SPT-1 -- let's check that...
1147	mov bx, offset [Scratch] ; Offset of the loaded LVM sector
1148	mov al, [bx+LocLVM_Secs] ; Get the LVM SPT value (<=255)
1149	dec al ; Adjust to LVM LBA
1150	mov ah, cl ; Get next LVM LBA to search
1151	inc ah ; This one was found here
1152	cmp al, ah ; If same, LVM LBA location OK
1153	jne DriveIO_LocateMasterLVMSector_next
1154
1155	; The LVM sector we found is at the location it should be on disk,
1156	; so it's almost 99% sure this is the correct one.
1157	; Now we should compare the start and sizes of the partitions in the
1158	; MBR with the partitions specified in this LVM record.
1159	; We'll implement that later after some more research.
1160	; For now we assume this is the correct Master LVM sector for the disk.
1161	inc cx ; CX was prepared to read next, correct that
1162	stc ; Indicate we have found the Master LVM sector
1163
1164	DriveIO_LocateMasterLVMSector_done:
1165	mov bx, 0 ; A Master LVM sector always has high LBA=0
1166	mov ax, cx ; Low LBA of Master LVM sector
1167
1168	; We leave it up to the caller to store the value in a proper place
1169	ret
1170	DriveIO_LocateMasterLVMSector EndP
1171
1172
1173
1174	;
1175	; ############################################################
1176	; # Check for a valid MBR-sector to be written to disk #
1177	; ############################################################
1178	;
1179	; In
1180	; --
1181	; DL = Physical Disk
1182	; BX:CX = LBA sector
1183	; DI:SI = Source buffer
1184	;
1185	; Out
1186	; ---
1187	; CY = 1 if invalid MBR in source buffer, 0 if valid
1188	;
1189	; This routine is called when DriveIO_SaveSector attempts to write to the MBR.
1190	; It checks if the sector to be written has some sensible values in certain
1191	; places. In fact, if the sector is written to the boot-disk, the AiR-BOOT
1192	; signature should be present and the partition table should be the same
1193	; as the one at the start of the AiR-BOOT code in memory, except maybe for the
1194	; active flags.
1195	; For other disks, only the active flags are checked to be 00h or 80h and
1196	; the AA55h MBR signature.
1197	;
1198	DriveIO_ProtectMBR Proc Near
1199	pusha ; Push all registers
1200	push es ; Push ES because we need it for string instructions
1201	push cs ; Make ES point...
1202	pop es ; to CS
1203
1204	; Save the pointer to the sector to write in BX
1205	mov bx,si
1206
1207	;
1208	; If the sector to be written is not the boot-disk, then skip
1209	; checking the AiR-BOOT MBR.
1210	;
1211	cmp dl, [BIOS_BootDisk]
1212	jne DriveIO_ProtectMBR_is_not_bootdisk
1213
1214	;
1215	; The boot-disk is accessed so the sector to be written must be
1216	; the AiR-BOOT MBR. This is the same as the first 512 bytes
1217	; relocated to 8000:0000 and this the start of the AB-code.
1218	;
1219	mov si,bx ; Get pointer to sector to write
1220	xor di,di ; Point DI to start of AB-code (MBR)
1221	mov cx, offset [MBR_PartTable] ; Bytes upto P-table must be same
1222	cld ; Compare upwards
1223	repe cmpsb ; Compare upto P-table
1224
1225	; If not the same this is not the an AiR-BOOT boot-disk MBR !
1226	jne DriveIO_ProtectMBR_not_valid_MBR ; SEVERE ERROR !
1227
1228	; Continue with signature check
1229	jmp DriveIO_ProtectMBR_check_signature
1230
1231
1232	;
1233	; The disk is not the boot-disk so we don't know what kind of MBR is on it.
1234	; Some sanity checks should be here.
1235	;
1236	DriveIO_ProtectMBR_is_not_bootdisk:
1237
1238	;
1239	; sanity checks...
1240	;
1241
1242	; Continue with signature check
1243	jmp DriveIO_ProtectMBR_check_signature
1244
1245
1246	DriveIO_ProtectMBR_check_signature:
1247	; See if the sector to write contains a valid signature
1248	mov si,bx ; Get pointer to sector to write
1249	mov di, offset [MBR_Sig] ; Offset to MBR signature
1250	add si,di ; Make SI point to it in sec to write
1251	lodsw ; Load it
1252	cmp ax,0aa55h ; See if it is valid
1253
1254	; If no signature this cannot be a valid MBR !
1255	jne DriveIO_ProtectMBR_not_valid_MBR ; SEVERE ERROR !
1256
1257
1258	;
1259	; The sector to be written seems to be valid.
1260	; Set CY=0 to indicate a valid MBR.
1261	;
1262	DriveIO_ProtectMBR_is_valid_MBR:
1263	clc
1264	jmp DriveIO_ProtectMBR_end
1265
1266	;
1267	; Something is terribly wrong; a non-MBR sector seems about to be written.
1268	; Set CY=1 and let the calling code handle this situation.
1269	;
1270	DriveIO_ProtectMBR_not_valid_MBR:
1271	stc
1272	jmp DriveIO_ProtectMBR_end
1273
1274	;
1275	; Return to the caller with no registers modyfied except FLAGS.
1276	;
1277	DriveIO_ProtectMBR_end:
1278	pop es
1279	popa
1280	ret
1281	DriveIO_ProtectMBR Endp
1282
1283
1284
1285	; #########################################################################
1286	; Routine: Checks if the MBR is addressed by either CHS or LBA
1287	; #########################################################################
1288	; Calling : bx:ax - Absolute sector
1289	; cx:dx - Cylinder/Sector, Side/Drive (hi/lo-byte)
1290	; Returns : ZF=1 if MBR is addressed, else ZF=0
1291	; Preserve: all registers
1292	; #########################################################################
1293	DriveIO_MBR_Addressed Proc
1294	push ax
1295	push bx
1296
1297	or bx,ax ; Results in 0 in BX if MBR is addressed by LBA
1298	jz DriveIO_MBR_Addressed_done
1299
1300	mov ax,cx ; Results in 1 in AX if CYL 0, SEC 1 is addressed
1301	add al,dh ; Results in 1 in AX if HEAD 0 is addressed
1302	dec ax ; Results in 0 in AX if MBR is addressed by CHS
1303
1304	DriveIO_MBR_Addressed_done:
1305	pop bx
1306	pop ax
1307	ret
1308	DriveIO_MBR_Addressed EndP
1309
1310
1311
1312
1313	; #########################################################################
1314	; Routine: Writes DS:SI to a specified sector
1315	; #########################################################################
1316	; Calling : bx:ax - Absolute sector
1317	; cx:dx - Cylinder/Sector, Side/Drive (hi/lo-byte)
1318	; ds:si - Source-Adress
1319	; Returns : none
1320	; Preserve: all registers
1321	; #########################################################################
1322	DriveIO_SaveSector Proc Near Uses ax bx cx dx ds si es di
1323
1324	IFDEF AUX_DEBUG
1325	IF 0
1326	DBG_TEXT_OUT_AUX 'DriveIO_SaveSector:'
1327	PUSHRF
1328	;~ call DEBUG_DumpRegisters
1329	;~ call AuxIO_DumpParagraph
1330	;~ call AuxIO_TeletypeNL
1331	POPRF
1332	ENDIF
1333	ENDIF
1334
1335
1336	;!
1337	;! DEBUG_BLOCK
1338	;! Force write to LBA0 to test interception routine.
1339	;! Do NOT enable unless you are debugging, will overwrite MBR !
1340	;!
1341	IFDEF AUX_DEBUG
1342	IF 0
1343	pushf
1344	pusha
1345	xor ax,ax
1346	xor bx,bx
1347	xor cx,cx
1348	inc cx
1349	xor dh,dh
1350	popa
1351	popf
1352	ENDIF
1353	ENDIF
1354
1355	;
1356	; Check if the MBR is the destination for the write.
1357	; ZF=1 if so.
1358	;
1359	call DriveIO_MBR_Addressed
1360	jnz DriveIO_SaveSector_continue_write
1361
1362
1363	; MBR is addressed, check the sector that is requested to be written.
1364	; For the bootdisk it should contain the AiR-BOOT signature, valid
1365	; partition-table entries and the AA55h signature.
1366	; If not, something is terribly wrong in some piece of the AB code.
1367	; For any other disk (80h+) at least a valid partition table should
1368	; be present together with the AA55h signature.
1369	call DriveIO_ProtectMBR
1370	jnc DriveIO_SaveSector_continue_write
1371
1372
1373	;
1374	; WE HAVE A SEVERE ERROR CONDITION !
1375	; SOME AB CODE TRIES TO WRITE A NON-MBR TO THE DISK !
1376	; ASK THE USER TO REPORT THIS !
1377	; HALT THE SYSTEM !
1378	;
1379
1380	; Show error-box
1381	mov cx, 0C04h
1382	mov si, offset NonMBRwrite
1383	call SETUP_ShowErrorBox
1384	mov cx, 0C04h
1385	mov si, offset NonMBRwrite_rep
1386	call SETUP_ShowErrorBox
1387
1388
1389	IFDEF AUX_DEBUG
1390	IF 0
1391	pushf
1392	pusha
1393	mov si, offset [NonMBRwrite]
1394	call AuxIO_TeletypeNL
1395	call AuxIO_Print
1396	call AuxIO_TeletypeNL
1397	popa
1398	popf
1399	ENDIF
1400	ENDIF
1401
1402	; Show popup and halt the system.
1403	jmp HaltSystem
1404
1405
1406
1407	;
1408	; Continue the write if not MBR sector or MBR to write is validated.
1409	;
1410	DriveIO_SaveSector_continue_write:
1411	test byte ptr cs:[CurIO_UseExtension], 1
1412	jz DIOSS_UseNormal
1413	; Are we forced do use LBA via Setting?
1414	; Always use INT13X on v1.0.8+.
1415	;~ test byte ptr cs:[CFG_ForceLBAUsage], 1
1416	;~ jnz DIOSS_UseExtension
1417	jmp DIOSS_UseExtension
1418	; Is the drive not a harddrive?
1419	cmp dl, 80h
1420	jb DIOSS_UseNormal
1421	; Upper 8 bits of LBA-address set? -> Use LBA (maximum boundary is FB0400h)
1422	or bh, bh
1423	jnz DIOSS_UseExtension
1424	; Compare Switch-Table value to bit 16-23 of LBA-address
1425	mov di, dx
1426	and di, 007Fh
1427	cmp bptr cs:[LBASwitchTable+di], bl
1428	jbe DIOSS_UseExtension
1429
1430	DIOSS_UseNormal:
1431
1432	IFDEF AUX_DEBUG
1433	IF 0
1434	DBG_TEXT_OUT_AUX 'DriveIO_WriteSectorCHS:'
1435	PUSHRF
1436	call DEBUG_DumpRegisters
1437	call AuxIO_DumpParagraph
1438	call AuxIO_TeletypeNL
1439	POPRF
1440	ENDIF
1441	ENDIF
1442
1443	mov di, 3 ; retry count
1444	DIOSS_ErrorLoop:
1445	push ds
1446	pop es
1447	mov bx, si ; ES:BX - Destination
1448	mov ax, 0301h ; Function 3 - Write Sector
1449	int 13h
1450	jnc DIOSS_Success
1451	dec di ; decrement retry count
1452	jnz DIOSS_ErrorLoop
1453	call MBR_SaveError
1454
1455	DIOSS_UseExtension:
1456
1457	mov di, ds ; segment for transfer address
1458	call DriveIO_WriteSectorLBA ; extended write
1459	jc MBR_SaveError ; halt on error
1460
1461	;~ push cx
1462	;~ mov cs:[INT13X_DAP_NumBlocks], 1 ; Copy ONE sector
1463	;~ mov wptr cs:[INT13X_DAP_Transfer+0], si
1464	;~ mov cx, ds
1465	;~ mov wptr cs:[INT13X_DAP_Transfer+2], cx ; Fill out Transfer Adress
1466	;~ mov wptr cs:[INT13X_DAP_Absolute+0], ax
1467	;~ mov wptr cs:[INT13X_DAP_Absolute+2], bx ; Fill out Absolute Sector
1468	;~ push cs
1469	;~ pop ds
1470	;~ mov si, offset [INT13X_DAP]
1471	;~ mov ax, 4300h ; Extended Write (No Verify)
1472	;~ int 13h
1473	;~ pop cx
1474	;~ jnc DIOSS_Success
1475	;~ call MBR_SaveError
1476
1477	DIOSS_Success:
1478	ret
1479	DriveIO_SaveSector EndP
1480
1481
1482
1483
1484	;##############################################################################
1485	;# When a disk has a Master LVM sector, it means it has been prepared for use
1486	;# by OS/2 and contains important information about how OS/2 views its geometry
1487	;# and other disk related properties. This function assumes the LBA address
1488	;# of the Master LVM sector has already been located and simply loads the
1489	;# sector into [LVMSector].
1490	;#
1491	;# Note that because this is an operation similar to the regular loading of
1492	;# sectors, the disk I/O semantics are used here. This means CF=0 when an LVM
1493	;# sector is successfully loaded and CF=1 otherwise.
1494	;##############################################################################
1495	;# ACTION : Loads the Master LVM sector if one exists
1496	;# ----------------------------------------------------------------------------
1497	;# EFFECTS : Modifies DAP structure and [LVMSector]
1498	;# ----------------------------------------------------------------------------
1499	;# IN : DL - BIOS disk number (80h,81h,etc)
1500	;# ----------------------------------------------------------------------------
1501	;# OUT : CF=0 - Valid Master LVM sector found and loaded
1502	;##############################################################################
1503	DriveIO_LoadMasterLVMSector Proc Near
1504
1505	IFDEF AUX_DEBUG
1506	IF 0
1507	DBG_TEXT_OUT_AUX 'DriveIO_LoadMasterLVMSector:'
1508	PUSHRF
1509	;~ call DEBUG_DumpRegisters
1510	;~ call AuxIO_DumpParagraph
1511	;~ call AuxIO_TeletypeNL
1512	POPRF
1513	ENDIF
1514	ENDIF
1515
1516	; Save all registers
1517	pusha
1518
1519	; Check if BIOS disk number is valid
1520	call DriveIO_IsValidHarddisk
1521	jc DriveIO_LoadMasterLVMSector_error
1522
1523	; Calculate the entry in the DISKINFO array for this disk
1524	call DriveIO_CalcDiskInfoPointer
1525
1526	; Save the entry for later recalls
1527	mov bp, bx
1528
1529	; Get the LBA address of the Master LVM sector
1530	mov ax, [bx+LocDISKINFO_LVM_MasterLBA+00h]
1531	mov bx, [bx+LocDISKINFO_LVM_MasterLBA+02h]
1532
1533	; LBA of Master LVM sector cannot be 0, so none was found during
1534	; the gathering of disk information.
1535	mov cx, ax
1536	or cx, bx
1537	jz DriveIO_LoadMasterLVMSector_error
1538
1539	; Load it into [LVMSector]
1540	mov di, ds
1541	mov si, offset [LVMSector]
1542	call DriveIO_ReadSectorLBA
1543	jc DriveIO_LoadMasterLVMSector_error
1544
1545	; Validate the Master LVM sector
1546	call LVM_ValidateSector
1547
1548	; Complement success indicator to conform to semantics of this function
1549	cmc
1550
1551	; Master LVM sector was valid and is now loaded in [LVMSector]
1552	jnc DriveIO_LoadMasterLVMSector_ret
1553
1554	DriveIO_LoadMasterLVMSector_error:
1555
1556	; Clear the sector buffer for safety reasons
1557	mov si, offset [LVMSector]
1558	call ClearSectorBuffer
1559
1560	; Indicate no Master LVM sector loaded
1561	stc
1562
1563	DriveIO_LoadMasterLVMSector_ret:
1564
1565	; Restore all registers
1566	popa
1567
1568	ret
1569	DriveIO_LoadMasterLVMSector Endp
1570
1571
1572
1573
1574	;##############################################################################
1575	;# There is much information to know about the connected disks.
1576	;# We also want this information clustered per disk and available before
1577	;# further disk and partition scanning takes place.
1578	;# This function gathers such information like INT13, INT13X, MBR, LVM, more.
1579	;# Especially important is the LVM information, because that contains the
1580	;# geometry OS/2 uses to access the disk. Other important information is the
1581	;# presence of valid MBRs, logical partitions and whatnot.
1582	;# This function gathers such information and stores it in a DISKINFO structure
1583	;# for which an instance exists for every disk found.
1584	;##############################################################################
1585	;# ACTION : Gather disk information and store this in the BSS
1586	;# ----------------------------------------------------------------------------
1587	;# EFFECTS : Modifies DAP structure and the buffers it uses, fills DISKINFO[n]
1588	;# ----------------------------------------------------------------------------
1589	;# IN : DL - BIOS disk number (80h,81h,etc)
1590	;# ----------------------------------------------------------------------------
1591	;# OUT : CF=1 - failure
1592	;##############################################################################
1593	DriveIO_GatherDiskInfo Proc Near
1594
1595	IFDEF AUX_DEBUG
1596	IF 1
1597	DBG_TEXT_OUT_AUX 'DriveIO_GatherDiskInfo:'
1598	PUSHRF
1599	call DEBUG_DumpRegisters
1600	;~ call AuxIO_DumpParagraph
1601	;~ call AuxIO_TeletypeNL
1602	POPRF
1603	ENDIF
1604	ENDIF
1605
1606	; Push all registers we use
1607	pusha
1608	push ds
1609	push es
1610
1611	; Make sure ES=DS
1612	push ds
1613	pop es
1614
1615	; Check if BIOS disk number is valid
1616	call DriveIO_IsValidHarddisk
1617	jc DriveIO_GatherDiskInfo_error
1618
1619	; Calculate the entry in the DISKINFO array for this disk
1620	call DriveIO_CalcDiskInfoPointer
1621
1622	; Save the entry for later recalls
1623	mov bp, bx
1624
1625	; Store the BIOS disk number in the structure
1626	mov [bx+LocDISKINFO_DiskNum], dl
1627
1628	; ------------------------------------------------------------------- [ INT13 ]
1629
1630	; Get BIOS Disk Parameters (legacy method)
1631	mov ah, 08h ; Get Disk Parameters
1632	int 13h ; Call BIOS
1633
1634	; CF=1 or AH!=0 indicates error
1635	jc DriveIO_GatherDiskInfo_error
1636	test ah, ah
1637	jnz DriveIO_GatherDiskInfo_error
1638
1639	; Recall DISKINFO entry
1640	mov bx, bp
1641
1642	; Store SPT (WORD)
1643	xor ah, ah ; Zero extend SPT to 16 bits
1644	mov al, cl ; Hi 2 bits max cyl and max sec
1645	and al, 3fh ; Mask max sec (1-based)
1646	mov [bx+LocDISKINFO_I13_Secs], ax ; Store SPT
1647
1648	; Store HEADS (WORD)
1649	xor dl, dl ; Zero extend HEADS to 16 bits
1650	xchg dl, dh ; Get max head (0-based)
1651	inc dx ; Head count
1652	mov [bx+LocDISKINFO_I13_Heads], dx ; Store HEADS
1653
1654	; Store CYLS (WORD)
1655	shr cl, 6 ; Hi 2 bits of max cyl to 1:0
1656	xchg cl, ch ; Max cyl (0-based)
1657	inc cx ; Cyl count
1658	mov [bx+LocDISKINFO_I13_Cyls], cx ; Store CYLS
1659
1660	; Recall BIOS disk number
1661	mov dl, [bx+LocDISKINFO_DiskNum]
1662
1663	; ------------------------------------------------------------------ [ INT13X ]
1664
1665	; Get BIOS Disk Parameters (extended method)
1666	mov si, offset [Scratch] ; Buffer to return disk info
1667	mov ax, 80h ; Size of buffer
1668	mov [si], ax ; Store it in first word
1669	mov ah, 48h ; Get Extended Disk Parameters
1670	int 13h ; Call BIOS
1671
1672	; CF=1 or AH!=0 indicates error
1673	jc DriveIO_GatherDiskInfo_error
1674	test ah, ah
1675	jnz DriveIO_GatherDiskInfo_error
1676
1677	; Store flags (WORD)
1678	cld ; Direction up
1679	lodsw ; Buffersize, discard
1680	lodsw ; Flags (CHS valid etc)
1681	mov [bx+LocDISKINFO_I13X_Flags], ax ; Store them
1682
1683	; Store CYLS (DWORD)
1684	lodsw ; Cyl count low
1685	mov [bx+LocDISKINFO_I13X_Cyls+00h], ax ; Store CYLS low
1686	lodsw ; Cyl count high
1687	mov [bx+LocDISKINFO_I13X_Cyls+02h], ax ; Store CYLS high
1688
1689	; Store HEADS (DWORD)
1690	lodsw ; Head count low
1691	mov [bx+LocDISKINFO_I13X_Heads+00h], ax ; Store HEADS low
1692	lodsw ; Head count high
1693	mov [bx+LocDISKINFO_I13X_Heads+02h], ax ; Store HEADS high
1694
1695	; Store SPT (DWORD)
1696	lodsw ; Secs per track low
1697	mov [bx+LocDISKINFO_I13X_Secs+00h], ax ; Store SPT low
1698	lodsw ; Secs per track high
1699	mov [bx+LocDISKINFO_I13X_Secs+02h], ax ; Store SPT high
1700
1701	; Store total LBA sectors (QWORD)
1702	lea di, [bx+LocDISKINFO_I13X_SecsLBA]
1703	mov cx, 4
1704	rep movsw
1705
1706	; Store sector size (WORD)
1707	lodsw
1708	mov [bx+LocDISKINFO_I13X_SecSize], ax
1709
1710	; Store bus name (4 bytes, space padded, v3.0+)
1711	lea si, [Scratch+24h]
1712	lea di, [bx+LocDISKINFO_I13X_HostBus]
1713	movsw
1714	movsw
1715
1716	; Store interface name (8 bytes, space padded, v3.0+)
1717	lea di, [bx+LocDISKINFO_I13X_Interface]
1718	mov cx, 4
1719	rep movsw
1720
1721	; Should gather some more INT13X info here,
1722	; like maybe Advanced Format stuff or so.
1723	; We'll investigate that at a later time.
1724
1725	; --------------------------------------------------------------------- [ MBR ]
1726
1727	; Load the MBR
1728	mov si, offset [TmpSector]
1729	call DriveIO_LoadMBR
1730
1731	; Store MBR flags (valid sig, partitions present, airboot installed)
1732	mov [bx+LocDISKINFO_MbrFlags], al
1733
1734	; Recall BIOS disk number
1735	mov dl, [bx+LocDISKINFO_DiskNum]
1736
1737	; --------------------------------------------------------------------- [ LVM ]
1738
1739	; Locate the Master LVM sector, if any
1740	call DriveIO_LocateMasterLVMSector
1741
1742	; Save Master LVM sector LBA high
1743	mov cx, bx
1744
1745	; Recall DISKINFO entry
1746	mov bx, bp
1747
1748	; Store Master LVM sector LBA
1749	mov [bx+LocDISKINFO_LVM_MasterLBA+00h], ax
1750	mov [bx+LocDISKINFO_LVM_MasterLBA+02h], cx
1751
1752	; No Master LVM sector found, so skip storing LVM info for this disk
1753	jnc DriveIO_GatherDiskInfo_no_master_lvm
1754
1755	; Load the Master LVM sector into [LVMSector]
1756	call DriveIO_LoadMasterLVMSector
1757
1758	; No valid Master LVM sector, so skip storing LVM info for this disk
1759	jc DriveIO_GatherDiskInfo_no_master_lvm
1760
1761	; A valid Master LVM sector has been loaded into [LVMSector]
1762	mov si, offset [LVMSector]
1763
1764	; Get the number of sectors per track (OS/2 geometry)
1765	mov ax, [si+LocLVM_Secs+00h]
1766	mov cx, [si+LocLVM_Secs+02h]
1767
1768	; Store it
1769	mov [bx+LocDISKINFO_LVM_Secs+00h], ax
1770	mov [bx+LocDISKINFO_LVM_Secs+02h], cx
1771
1772	; Get the number of heads (OS/2 geometry)
1773	mov ax, [si+LocLVM_Heads+00h]
1774	mov cx, [si+LocLVM_Heads+02h]
1775
1776	; Store it
1777	mov [bx+LocDISKINFO_LVM_Heads+00h], ax
1778	mov [bx+LocDISKINFO_LVM_Heads+02h], cx
1779
1780	; Should gather some more LVM info here,
1781	; like OS/2 extended geometry and other flags.
1782	; We'll implement that at a later time.
1783
1784	DriveIO_GatherDiskInfo_no_master_lvm:
1785
1786	; When no Master LVM sector was found,
1787	; the LVM info in the DISKINFO structure for the disk
1788	; will be ZERO because the area was cleared in PRECRAP.
1789
1790	; Indicate success
1791	clc
1792
1793	jmp DriveIO_GatherDiskInfo_ret
1794
1795	DriveIO_GatherDiskInfo_error:
1796	stc
1797	DriveIO_GatherDiskInfo_ret:
1798
1799
1800	IFDEF AUX_DEBUG
1801	IF 1
1802	DBG_TEXT_OUT_AUX '[DISKINFO]'
1803	PUSHRF
1804	call DEBUG_DumpRegisters
1805	;~ call AuxIO_DumpParagraph
1806	;~ call AuxIO_TeletypeNL
1807	mov si, bp
1808	mov cx, 4
1809	@@:
1810	call AuxIO_DumpParagraph
1811	call AuxIO_TeletypeNL
1812	add si, 16
1813	loop @B
1814	mov si, offset [Scratch]
1815	mov cx, 4
1816	@@:
1817	call AuxIO_DumpParagraph
1818	call AuxIO_TeletypeNL
1819	add si, 16
1820	loop @B
1821	mov si, offset [LVMSector]
1822	mov cx, 7
1823	@@:
1824	call AuxIO_DumpParagraph
1825	call AuxIO_TeletypeNL
1826	add si, 16
1827	loop @B
1828	POPRF
1829	ENDIF
1830	ENDIF
1831
1832	; Restore registers
1833	pop es
1834	pop ds
1835	popa
1836
1837	ret
1838	DriveIO_GatherDiskInfo EndP
1839
1840	;------------------------------------------------------------------------------
1841	; Scan all disks to gather information
1842	;------------------------------------------------------------------------------
1843	; IN : None
1844	; OUT : CF=1 - some failure occured
1845	; : ZF=1 - no harddisks
1846	; NOTE : This does the preliminary gathering of disk information
1847	;------------------------------------------------------------------------------
1848	DriveIO_ScanDisks Proc Near
1849
1850	IFDEF AUX_DEBUG
1851	IF 1
1852	DBG_TEXT_OUT_AUX 'DriveIO_ScanDisks:'
1853	PUSHRF
1854	call DEBUG_DumpRegisters
1855	;~ call AuxIO_DumpParagraph
1856	;~ call AuxIO_TeletypeNL
1857	POPRF
1858	ENDIF
1859	ENDIF
1860
1861	; Save all registers
1862	pusha
1863
1864	; Get number of disks in DH
1865	call DriveIO_GetHardDriveCount
1866
1867	; Check if there are any disks to scan
1868	xor cx, cx ; Prepare 16-bit counter
1869	mov cl, dh ; Number of disks now in CX
1870	jcxz DriveIO_ScanDisks_end ; Quit if no disks
1871
1872	; Scan disks from 80h upward
1873	mov dl, 80h ; BIOS number of first disk
1874	DriveIO_ScanDisks_next:
1875	call DriveIO_GatherDiskInfo ; Gather info for this disk
1876	jc DriveIO_ScanDisks_end ; Quit if some error occured
1877	inc dl ; Advance to next disk
1878	loop DriveIO_ScanDisks_next ; Scan next disk if there is one
1879	test dl, dl ; Set ZF=0
1880	clc ; Indicate success
1881
1882	DriveIO_ScanDisks_end:
1883	; Restore all registers
1884	popa
1885
1886	ret
1887	DriveIO_ScanDisks EndP
1888
1889	;------------------------------------------------------------------------------
1890	; Calculate pointer to entry in DISKINFO structure
1891	;------------------------------------------------------------------------------
1892	; IN : DL BIOS disk number (80h etc)
1893	; OUT : BX Pointer to entry
1894	; NOTE : BIOS disk number must be valid
1895	;------------------------------------------------------------------------------
1896	DriveIO_CalcDiskInfoPointer Proc Near
1897	xchg bx, ax ; AX is used for calculation
1898	mov al, DISKINFO_Size ; Size of DISKINFO structure
1899	mov ah, dl ; BIOS disk number
1900	sub ah, 80h ; Now 0-based index
1901	mul ah ; Now offset into DISKINFO array
1902	add ax, offset [DiskInformation] ; Base of DISKINFO array
1903	xchg bx, ax ; BX now points to entry for disk
1904	ret
1905	DriveIO_CalcDiskInfoPointer EndP
1906
1907	;------------------------------------------------------------------------------
1908	; Check if the BIOS disk number in DL is a harddisk and in range
1909	;------------------------------------------------------------------------------
1910	; IN : DL BIOS disk number (80h etc)
1911	; OUT : CF=1 if invalid disk number or out of range
1912	; NOTE : Only modifies flags
1913	;------------------------------------------------------------------------------
1914	DriveIO_IsValidHarddisk Proc Near Uses dx
1915	cmp dl, 80h ; BIOS disk number must be at least 80h
1916	jb @F ; Not a harddisk, exit with CY
1917	mov dh, dl ; Save to do compare
1918	sub dh, 80h ; Now 0 based disk number
1919	inc dh ; Now 1 based disk number
1920	cmp [TotalHarddiscs], dh ; Out of range, exit with CY
1921	@@: ret
1922	DriveIO_IsValidHarddisk EndP
1923
1924
1925	; Values for sectors per track table corresponding to DriveIO_IsHugeDrive return value.
1926	;~ secs_per_track_table db 63,127,255,255,255,255
1927
1928	;~ db_lmlvm db 'Load Master LVM -- disk: ',0

Note: See TracBrowser for help on using the repository browser.

Context Navigation

source: trunk/bootcode/regular/driveio.asm@ 156

Download in other formats: