Context Navigation

airboot.asm@ 180

Last change on this file since 180 was 176, checked in by Ben Rietbroek, 8 years ago

AiR-BOOT v1.1.1-PUBLIC-TEST-RELEASE-20170408 [v1.1.1-testing]

We are at 99.999% from v1.1.2-RELEASE, which will be published shortly.
The build for this public test-release should be available here:
https://github.com/rousseaux/netlabs.air-boot/releases

CAUTION:
This is a testbuild !
AirBoot uses the BIOS to access disks and a small coding error can trash
partition tables or other vital disk structures. You are advised to make
backups of TRACK0 and EBRs before using this testbuild. More info at:
https://rousseaux.github.io/netlabs.air-boot/pdf/AirBoot-v1.1.0-manual.pdf

File size: 98.8 KB

Line
1	;
2	; AiR-BOOT (c) Copyright 1998-2008 M. Kiewitz
3	;
4	; This file is part of AiR-BOOT
5	;
6	; AiR-BOOT is free software: you can redistribute it and/or modify it under
7	; the terms of the GNU General Public License as published by the Free
8	; Software Foundation, either version 3 of the License, or (at your option)
9	; any later version.
10	;
11	; AiR-BOOT is distributed in the hope that it will be useful, but WITHOUT ANY
12	; WARRANTY: without even the implied warranty of MERCHANTABILITY or FITNESS
13	; FOR A PARTICULAR PURPOSE. See the GNU General Public License for more
14	; details.
15	;
16	; You should have received a copy of the GNU General Public License along with
17	; AiR-BOOT. If not, see <http://www.gnu.org/licenses/>.
18	;
19
20
21
22
23
24
25
26	;##############################################################################
27	; AiR-BOOT / DEFINITIONS
28	;##############################################################################
29
30	;
31	; Include AiR-BOOT Version Information.
32	; This version-info is defined using simpel EQU's so it can serve as a
33	; single source for other formats. The AiR-BOOT signature and the
34	; OS/2 BLDLEVEL use this basic version information.
35	;
36	include ../include/version.inc
37
38	;
39	; Include OS/2 BLDLEVEL Information.
40	; It uses the version-information in VERSION.INC to build it's signature.
41	;
42	include bldlevel.inc
43
44	;
45	; Include some macro's.
46	; This file contains the ORIGIN macro that is used to detect overlaps.
47	;
48	include ../include/asm.inc
49
50
51	; We actually don't want to use this directive because it generates extra
52	; NOP instructions that we can do without.
53	; TASM also has a bug in that when the .ERR2 directive is used when
54	; the .386 directive is in effect, the JUMPS directive is also active
55	; and cannot be turned off.
56	; NOJUMPS seems to have no effect in this situation.
57	; In this case 4 NOP instructions are generated after forward referencing jump
58	; instructions, to allow for automatic recoding by TASM.
59	; This seems to be a TASM bug. (v2,v3,v4, dunno v5)
60	IFDEF TASM
61	;~ JUMPS
62	ENDIF
63
64
65	;
66	; If defined then each module is prefixed with it's name.
67	; This is used for debugging purposes but it also increases code space.
68	; It should be off in release code.
69	;
70	;~ MODULE_NAMES EQU
71
72
73
74	; -----------------------------------------------------------------------------
75	; DEBUG
76	; -----------------------------------------------------------------------------
77
78	;
79	; Enable this to include Debug Modules and enable COM-port debugging.
80	; To have room for the debug-code, the FX-code can only be enabled
81	; when AUX_DEBUG is not defined.
82	;
83	;~ AUX_DEBUG EQU
84
85	;
86	; To have FX enabled, make sure FX_ENABLE is defined.
87	; There is no need (for now) to remove Cooper Bars from the setup-menu
88	; because AiR-BOOT does not crash when enabling Cooper Bars while FX
89	; is not compiled in. Only TAB to post-screen does not work.
90	; Way to go Martin !
91	;
92	IFNDEF AUX_DEBUG
93	FX_ENABLED EQU
94	ENDIF
95
96
97
98	; -----------------------------------------------------------------------------
99	; AUX
100	; -----------------------------------------------------------------------------
101	;
102	; bits 7-5 = datarate
103	; (000=110,001=150,010=300,011=600,100=1200,101=2400,110=4800,111=9600 bps)
104	; bits 4-3 = parity
105	; (00 or 10 = none, 01 = odd, 11 = even)
106	; bit 2 = stop-bits
107	; (set = 2 stop-bits, clear = 1 stop-bit)
108	; bits 1-0 = data-bits
109	; (00 = 5, 01 = 6, 10 = 7, 11 = 8)
110	;
111
112	; 9600 bps, no parity, 1 stop-bit, 8 bits per char
113	AUX_INIT_PARMS EQU 11100011b
114
115	; Com-port for debugging, 0 is disabled
116	BIOS_COM_PORT EQU 1
117
118	; Default word value for BIOS_AuxParms variable
119	; Note that is has moved since v1.07
120	BIOS_AUXPARMS_DEFAULT EQU (AUX_INIT_PARMS SHL 8) OR BIOS_COM_PORT
121
122	; Default byte value for BIOS_BootDisk variable
123	BIOS_BOOTDISK_DEFAULT EQU 80h
124
125
126
127	; -----------------------------------------------------------------------------
128	; LABELS
129	; -----------------------------------------------------------------------------
130	; Address labels after code-move
131	BootBaseSeg equ 08000h ; Pre-boot, in the low 640K
132	BootBasePtr equ 0h ; We put our MBR to this location
133	BootBaseExec equ BootBasePtr+offset MBR_RealStart
134	StackSeg equ 07000h ; Put the stack below the code
135	StartBaseSeg equ 00000h ; Pre-boot, we are in low memory
136	StartBasePtr equ 07C00h ; BIOS starts our MBR at 0:7C00
137
138
139
140	; -----------------------------------------------------------------------------
141	; VIDEO
142	; -----------------------------------------------------------------------------
143	; Video pages, no INT 10h is used for menu-drawing etc.
144	VideoIO_Page0 equ 0B800h
145	VideoIO_Page1 equ 0B900h
146	VideoIO_Page2 equ 0BA00h
147	VideoIO_Page4 equ 0BC00h
148	VideoIO_FXSegment equ 0A000h
149
150	; Special line-drawing characters
151	TextChar_WinLineRight equ 0C4h
152	TextChar_WinLineDown equ 0B3h
153	TextChar_WinRep1 equ 0D1h
154	TextChar_WinRep2 equ 0C5h
155	TextChar_WinRep3 equ 0CFh
156	TextChar_WinRep4 equ 0B5h
157	TextChar_WinRep5 equ 0C6h
158	TextChar_WinRep6 equ 0D8h
159
160
161	; -----------------------------------------------------------------------------
162	; DISK INFORMATION
163	; -----------------------------------------------------------------------------
164	; Offsets into the DISKINFO structures located in the array [DiskInformation]
165
166	; BIOS disk number and MBR flags
167	LocDISKINFO_DiskNum equ 00h ; BYTE - BIOS disk number (80h etc)
168	LocDISKINFO_MbrFlags equ 01h ; BYTE - Valid MBR, etc
169
170	; BIOS INT13 Info
171	LocDISKINFO_I13_Secs equ 02h ; WORD - Max 63
172	LocDISKINFO_I13_Heads equ 04h ; WORD - Max 16 or 255
173	LocDISKINFO_I13_Cyls equ 06h ; WORD - Max 1024
174
175	; BIOS INT13X Info
176	LocDISKINFO_I13X_Flags equ 08h ; WORD - CHS valid, etc
177	LocDISKINFO_I13X_SecSize equ 0ah ; WORD - Normally 512 bytes
178	LocDISKINFO_I13X_Secs equ 0ch ; DWORD - Max 63 ?
179	LocDISKINFO_I13X_Heads equ 10h ; DWORD - Max 255 ?
180	LocDISKINFO_I13X_Cyls equ 14h ; DWORD - Max 2_32 (4294967296)
181	LocDISKINFO_I13X_SecsLBA equ 18h ; QWORD - Max 2^64 (4294967296^2)
182	LocDISKINFO_I13X_HostBus equ 20h ; 4 bytes
183	LocDISKINFO_I13X_Interface equ 24h ; 8 bytes
184
185	; OS/2 LVM Info
186	LocDISKINFO_LVM_Flags equ 2ch ; WORD - OS/2 ext geo, etc
187	LocDISKINFO_LVM_MasterLBA equ 2eh ; DWORD - Max 254
188	LocDISKINFO_LVM_Secs equ 32h ; DWORD - Max 255
189	LocDISKINFO_LVM_Heads equ 36h ; DWORD - Max 255
190	LocDISKINFO_LVM_Cyls equ 3ah ; DWORD - Max 65536
191
192	; Custom Info
193	LocDISKINFO_Flags equ 3eh ; WORD - Custom flags, dunno yet
194
195	; Size of this structure
196	DISKINFO_Size equ 40h ; Size to be allocated
197
198
199	; -----------------------------------------------------------------------------
200	; PARTITION TABLE
201	; -----------------------------------------------------------------------------
202	; Offsets for Partition-Entries in MBR/EBRs
203	LocBRPT_LenOfEntry equ 16 ; Length of a standard MBR or EPR entry
204	LocBRPT_Flags equ 0 ; Bootable, Hidden, etc.
205	LocBRPT_BeginCHS equ 1 ; Packed CHS value
206	LocBRPT_BeginHead equ 1 ; Start head, usually < 16
207	LocBRPT_BeginSector equ 2 ; Start sector, max 63 + cyl high bits
208	LocBRPT_BeginCylinder equ 3 ; Start cylinder 8+2 bits, max 1023
209	LocBRPT_SystemID equ 4 ; Type of system using the partition
210	LocBRPT_EndCHS equ 5 ; Packed CHS value
211	LocBRPT_EndHead equ 5 ; End head, usually < 16
212	LocBRPT_EndSector equ 6 ; End sector, max 63 + cyl high bits
213	LocBRPT_EndCylinder equ 7 ; End cylinder 8+2 bits, max 1023
214	LocBRPT_RelativeBegin equ 8 ; LBA32 address of partition
215	LocBRPT_AbsoluteLength equ 12 ; 32-bit length of partition
216
217	; Signature relative to start of MBR/EBR
218	LocBR_Magic equ 510 ; Offset of 0AA55h signature
219
220
221	; -----------------------------------------------------------------------------
222	; LVM RECORD
223	; -----------------------------------------------------------------------------
224	; Used as a quick compare in LVM.ASM
225	LocLVM_SignatureByte0 equ 02h
226
227	; Offsets for LVM Information Sector.
228	; These are relative to the start of the LVM sector.
229	LocLVM_SignatureStart equ 00h ; 02h,'RMBPMFD' (8 bytes)
230	LocLVM_CRC equ 08h ; CRC is a DWORD
231	LocLVM_Heads equ 1ch ; Number of heads
232	LocLVM_Secs equ 20h ; Sectors per Track
233	LocLVM_DiskName equ 24h ; Name of the disk
234	LocLVM_StartOfEntries equ 3ch ; (contains maximum of 4 entries)
235	LocLVM_LenOfEntry equ 3ch ; Length of an LVM-entry
236
237	; An LVM info-sector can contain information on max. 4 partitions.
238	; All 4 entries will be used when there 4 primary partitions defined.
239	; For logical partitions, the LVM info-sector is located below the start
240	; of the logical partition and only one LVM entry is used in that logical
241	; LVM info-sector.
242	LocLVM_MaxEntries equ 4 ; Max entries in an LVM-sector
243
244
245	; -----------------------------------------------------------------------------
246	; LVM ENTRY
247	; -----------------------------------------------------------------------------
248	; Offsets for LVM entry.
249	; These are relative to the start of the entry.
250	LocLVM_VolumeID equ 00h ; DWORD
251	LocLVM_PartitionID equ 04h ; DWORD
252	LocLVM_PartitionSize equ 08h ; DWORD
253	LocLVM_PartitionStart equ 0ch ; DWORD
254	LocLVM_OnBootMenu equ 10h ; is on IBM BM Bootmenu
255	LocLVM_Startable equ 11h ; is Startable (newly installed system)
256	LocLVM_VolumeLetter equ 12h ; Drive Letter for partition (C-Z or 0)
257	LocLVM_Unknown equ 13h ; unknown BYTE (can be used ?)
258	LocLVM_InstallLetter equ 13h ; unknown BYTE (can be used ?)
259
260	; Truncated to 11 chars when displayed in menu.
261	; MiniLVM sets both to the same value.
262	; Also, MiniLVM uses a 0-byte terminator, so the maximum length is 19d.
263	; Same goes for LocLVM_DiskName.
264	; These offsets are relative to an LVM entry.
265	LocLVM_VolumeName equ 14h ; 20 bytes
266	LocLVM_PartitionName equ 28h ; 20 bytes (Used in menu)
267
268	; LVM constants.
269	LocLVM_LabelLen equ 14h ; Length of LVM Label (Disk/Part/Vol)
270	LocLVM_DiskNameLen equ 14h ; Length of LVM DiskName
271	LocLVM_VolumeNameLen equ 14h ; Length of LVM VolumeName
272	LocLVM_PartitionNameLen equ 14h ; Length of LVM PartitionName
273
274
275	; -----------------------------------------------------------------------------
276	; AiR-BOOT IPT
277	; -----------------------------------------------------------------------------
278	; Offsets for IPT (Internal Partition Table)
279	LocIPT_MaxPartitions equ max_partitions ; 45 in v1.07+
280	LocIPT_LenOfSizeElement equ 6 ; Size of one Size-Element
281	LocIPT_LenOfIPT equ 34 ; Length of an IPT-entry
282	LocIPT_Serial equ 0 ; Serial from MBR ?
283	LocIPT_Name equ 4 ; Name from FS or LVM (part/vol)
284	LocIPT_Drive equ 15 ; Drive-ID (80h,81h)
285	LocIPT_SystemID equ 16 ; Partition-Type (06,07,etc)
286	LocIPT_Flags equ 17 ; AiR-BOOT Flags for part (see below)
287	LocIPT_BootRecordCRC equ 18 ; CRC of Boot-Record
288	LocIPT_LocationBegin equ 20 ; Begin of Partition
289	LocIPT_LocationPartTable equ 23 ; PartitionTable of Partition
290	LocIPT_AbsoluteBegin equ 26 ; Absolute Sector of Begin
291	LocIPT_AbsolutePartTable equ 30 ; Absolute Sector of PartTable
292
293
294	; AiR-BOOT IPT-Flags
295	LocIPT_DefaultFlags equ 00000011b ; Don't know if boot-able :)
296	LocIPT_DefaultNonBootFlags equ 00000010b ; VIBR Detection is always on
297
298	Flags_Bootable equ 00000001b
299	Flags_VIBR_Detection equ 00000010b
300	Flags_HideFeature equ 00000100b
301	Flags_DriveLetter equ 00001000b ; OS/2 FAT16/HPFS only
302	Flags_ExtPartMShack equ 00010000b ; Ext. Partition M$-Hack req ?
303	Flags_NoPartName equ 01000000b
304	Flags_NowFound equ 10000000b ; temp only in OldPartTable
305	Flags_SpecialMarker equ 10000000b ; temp only for HiddenSetup
306
307	FileSysFlags_BootAble equ 00000001b ; Is this Partition boot-able ?
308	FileSysFlags_FAT32 equ 00010000b ; FAT 32 specific name getting
309	FileSysFlags_NoName equ 00100000b ; No Name - use PartitionName
310	FileSysFlags_DriveLetter equ 01000000b ; DriveLetter Feature possible
311
312
313	; -----------------------------------------------------------------------------
314	; AiR-BOOT HPT
315	; -----------------------------------------------------------------------------
316	; Hidden Partition Table
317	; Length of an HPT-entry ((45 * 6 bits-per-part) / 8) * 45
318	; 33.75 = 34 bytes for HPT-entry, coincidently same as length of IPT-entry.
319	; Packed table !
320	LocHPT_LenOfHPT equ 34
321
322
323	; -----------------------------------------------------------------------------
324	; NAVIGATION KEYS
325	; -----------------------------------------------------------------------------
326	; Navigation keys
327	Keys_Up equ 48h
328	Keys_Down equ 50h
329	Keys_Left equ 4Bh
330	Keys_Right equ 4Dh
331	Keys_PageUp equ 49h
332	Keys_PageDown equ 51h
333	Keys_GrayPlus equ 4Eh
334	Keys_GrayMinus equ 4Ah
335	Keys_Plus equ 1Bh
336	Keys_Minus equ 35h
337	Keys_ENTER equ 1Ch
338	Keys_ESC equ 1h
339	Keys_F1 equ 3Bh
340	Keys_F10 equ 44h
341	Keys_C equ 2Eh ; Add. Check for Ctrl!
342	Keys_Y equ 2Ch
343	Keys_Z equ 15h
344	Keys_N equ 31h
345	Keys_TAB equ 0Fh
346	Keys_Delete equ 53h
347	Keys_Backspace equ 0Eh
348	Keys_Space equ 20h
349
350	Keys_Flags_EnterSetup equ 1100b ; Strg+Alt (AL)
351
352
353	; -----------------------------------------------------------------------------
354	; MISC
355	; -----------------------------------------------------------------------------
356	; Initial value for the FreeDriveletterMap
357	; Meaning A,B not free; C-Z free, rest unused. (right to left)
358	; Each partition with an assigned drive-letter clears a bit in this map.
359	; (Not implemented yet)
360	InitialFreeDriveletterMap equ 00000011111111111111111111111100b
361
362	;
363	; The first harddisk is BIOS coded 80h.
364	; This makes a total of 128 disks that could be supported using this coding.
365	; This value is used to store disk-information and this info is allocated
366	; in the BSS. 64 disks ought to be enough for everybody :-)
367	;
368	MaxDisks equ 64
369
370
371
372
373
374
375	;##############################################################################
376	; AiR-BOOT / MAIN-CODE
377	;##############################################################################
378
379	;
380	; Because of the TASM-bug the processor had to be changed to turn JUMPS
381	; off. Existing movzx instructions were replaced with 286 equivalent code.
382	; Out of range relative jumps have been recoded.
383	;
384	; Since version 1.0.8, JWasm is the preferred assembler and Tasm will be
385	; dropped. Also, the chances of AiR-BOOT being used on a 286-machine are
386	; very slim, so a future version will revert back to .386 and also incorporate
387	; 32-bit code. This will enable some enhanced constructs such as scaled
388	; indexing, bit-instructions, 32-bit registers and what not.
389	;
390	.286
391
392	;
393	; For Tasm, MODEL is needed for the USES directive to work.
394	; So always use a model when assembling with Tasm otherwise registers on
395	; function calls that use USES are not saved and restored.
396	; The model itself, has no real effect because we generate a binary image
397	; and not a segmented executable.
398	; For the other assemblers we define no model to get rid of the default C/C++
399	; segments for future object-linked versions of AiR-BOOT.
400	;
401	IFDEF TASM
402	;~ .model large, basic
403	.model tiny,c
404	ENDIF
405
406	;
407	; The below is used to switch between the original 1-segment (code_seg) layout
408	; and the new 2-segment (code_seg and bss_data) layout.
409	; It will be removed in future versions.
410	; The 2-segment layout was needed for JWasm because it does not treat
411	; db ? at the end of a code segment as bss-data.
412	; Therefore, a true BSS segment is now used.
413	; Both the code_seg and the bss_data are grouped to the logical AIRBOOT
414	; segment.
415	; Note that this influences the offsets in the BSS in the list-file and
416	; the wdis disassembly file (.WDA).
417	; They are now segment-relative. The true offset is resolved at link
418	; time.
419	;
420	SEGMENTED EQU
421
422	IFDEF SEGMENTED
423	AIRBOOT GROUP LDRIMAGE,VOLATILE
424	ENDIF
425
426	; Our code-segment starts here.
427	LDRIMAGE SEGMENT USE16 PUBLIC 'CODE'
428
429	IFDEF SEGMENTED
430	ASSUME CS:AIRBOOT, DS:AIRBOOT, ES:nothing, SS:nothing
431	ELSE
432	ASSUME CS:LDRIMAGE,DS:LDRIMAGE,ES:nothing, SS:nothing
433	ENDIF
434
435
436
437	;==============================================================================
438	; Sector 1
439	;==============================================================================
440
441	;------------------------------------------------------------------------------
442	; We are not a .COM file at 100h but a BINARY image
443	; of which only the 1st sector gets loaded at 0000:07c00h
444	; by the BIOS. The code in this 1st sector is position
445	; independent and moves itself to a new location at 8000:0000h.
446	; Then it jumps to a new entry-point and loads the rest of
447	; the image to the new location.
448	org 00000h
449	;------------------------------------------------------------------------------
450
451
452	;
453	; Since AiR-BOOT is a boot-loader residing in track0, the first 512 bytes
454	; have the layout of a Master Boot Record (MBR). When AiR-BOOT get's installed,
455	; the first 512 bytes of this code get's merged with the Partition Table.
456	; The rest is installed in the remaining sectors with sector 62 (LBA 61)
457	; being the last sector used by AiR-BOOT. Sector 63 is reserved for IBM LVM.
458	; The last sector used by AiR-BOOT is a copy of the MBR that AiR-BOOT makes
459	; every time a system gets booted.
460	;
461
462	;
463	; Due to the addition of an extra 'I13X' sugnature and code to preserve the
464	; values of the registers on entry, the MBR-code has become a bit messy.
465	; This will be cleaned-up in future versions.
466	;
467
468	;
469	; Martin had a short jump followed by the AiRBOOT signature at first.
470	; Then he encountered strange behaviour by some M$ operating-systems
471	; if the the first insruction was not a CLI.
472	; But there was no room to insert the CLI and of course he did not want to
473	; change the location of the AiR-BOOT signature.
474	; He solved this by inserting the M$ needed CLI at offset 0 followed by a short
475	; jump that uses the 'A' of the AiR-BOOT signature as the jump displacement.
476	;
477
478
479	; -----------------------------------------------------------------------------
480	; FIRST ENTRY-POINT
481	; -----------------------------------------------------------------------------
482	; BOOKMARK: FIRST ENTRY-POINT (Invoked by BIOS)
483	; ######################################################
484	; # ENTRY-POINT WHERE THE BIOS TRANSFERS CONTROL TO US #
485	; ######################################################
486	AiR_BOOT:
487	; Some M$ operating systems need a CLI
488	; here otherwise they will go beserk
489	; and will do funny things during
490	; boot phase, it's laughable!
491	MBR_1stOpc: cli
492
493	; JMP-Short -> MBR_Start
494	; Uses the 'A' from the signature as the displacement !
495	MBR_JmpOpc db 0EBh
496
497	; ID String, Date (DD,MM,CC,YY), Version Number, Language ID
498	;~ db 'AiRBOOT',24h,02h,20h,12h,01h,08h,TXT_LanguageID
499	MBR_ABSig: InsertAirbootSignature TXT_LanguageID
500
501	; Total Code Sectors Count.
502	; Actual value will be inserted by FIXCODE.
503	MBR_CodeSecs db 1
504
505	; Total Code Sectors Count, dynamically calculated.
506	;~ db (code_end-$)/512
507
508	; Check-Sum for Code
509	MBR_CheckCode dw 0
510
511
512
513	; -----------------------------------------------------------------------------
514	; THIRD ENTRY-POINT
515	; -----------------------------------------------------------------------------
516	; BOOKMARK: THIRD ENTRY-POINT (Relocate code)
517	;
518	; No single instruction below should be changed, added or removed in the code
519	; below as this will cause the jump-link to go haywire.
520	;
521	MBR_Start:
522	;
523	; When we arrive here, no registers have been used yet.
524	; So, they still contain the values the BIOS left in them.
525	; We want to preserve those value's for later inspection
526	; by putting them on the stack.
527	;
528
529	; No space for this instruction here.
530	; We'll enable interrupts later.
531	;sti ; This opcode is dedicated to:
532	; =MICROSOFT JUMP DEPARTMENT=
533
534	; Push all registers with values provided by the BIOS
535	; on the stack.
536	pusha
537
538	;
539	; Setup some base stuff
540	; AX got loaded wrongly for debug, changed the instructions
541	; without modifying the number of bytes.
542	; Don't comment-out the redundant instruction below because it
543	; will change the number of bytes and break the jump-chain.
544	;
545
546	; The segment we are moving ourself from (NOT USED)
547	;mov ax, StartBaseSeg
548	;mov ds, ax
549
550	; Make sure DS points to CS.
551	push cs
552	pop ds
553
554	; Setup the source and destination for the code move.
555	mov si, StartBasePtr ; The offset we move ourself from
556	mov ax, BootBaseSeg ; The target segment we move to
557	mov es, ax
558	;mov di, BootBasePtr ; The target offset we move to
559	; Changed the instruction to make room.
560	; So, BootBasePtr is not used !
561	; The offset in the target segment is assumed to be 0000
562	; anyway.
563	xor di,di
564	;sti
565
566	; Size of the MBR in words.
567	mov cx, 256 ; Pre-boot environment
568
569	;
570	; This moves this 512-byte sector, loaded by the BIOS at
571	; 0000:7c00 to 8000:0000.
572	;
573	cld
574	rep movsw
575
576	; Temporary save SS and SP so we still have access to this
577	; stack after we have setup our own.
578	mov cx,ss
579	mov bx,sp
580
581	; Code an intersegment jump to the new location.
582	; jmp BootBaseSeg:BootBaseExec
583	; Note that DX:BX containts the old SS:SP.
584	db 0EAh
585	dw BootBaseExec ; This is MBR_RealStart + BootBasePtr
586	dw BootBaseSeg ; This is 08000h
587
588
589
590
591	; -----------------------------------------------------------------------------
592	; SIMPLE MBR FUNCTIONS
593	; -----------------------------------------------------------------------------
594	;
595	; Some MBR-functions to provide absolute minimum functionality.
596	;
597
598	;
599	; BOOKMARK: Halt System
600	; Entry-point for halting the system.
601	;
602	MBR_HaltSystem:
603	mov ax, 8600h
604	xor cx, cx
605	mov dx, 500
606	int 15h ; Wait to display the whole screen :]
607	MBR_HaltSys:
608	;~ cli
609	jmp MBR_HaltSys
610
611
612	; Base of some MBR variables
613	ORIGIN 0003Ch
614
615	MBR_Variables:
616
617	; Comport settings.
618	; It had to be moved to create room for the double I13X signature.
619	; It cannot be in the config-area (sector 55)
620	; because that area is crc-protected and would not allow 'poking'.
621	BIOS_AuxParms dw BIOS_AUXPARMS_DEFAULT
622
623	; When the BIOS turns over control to the MBR, DL holds the BIOS disk-number
624	; from which the boot was initiated. This would normally be 80h, corresponding
625	; to the first physical disk. However, some modern BIOSses can directly boot
626	; from other disks, so AirBoot cannot assume being loaded from 80h anymore.
627	; So here we store the BIOS disk-number passed in DL when AirBoot got control.
628	BIOS_BootDisk db BIOS_BOOTDISK_DEFAULT ; Get overwritten with 'DL'
629
630	; Reserved space for future variables.
631	IFDEF AUX_DEBUG
632	reserved db 5 dup('X')
633	ELSE
634	reserved db 5 dup(0)
635	ENDIF
636
637
638
639
640	; -----------------------------------------------------------------------------
641	; SECOND ENTRY-POINT
642	; -----------------------------------------------------------------------------
643
644	;
645	; We arrive here after the first jump using the 'A' of the
646	; AiR-BOOT signature. So we ensure the jump is always at
647	; this offset. We jump here, because Martin needed to
648	; insert a CLI on start and did not want to change the
649	; AiR-BOOT signature because of Microsoft inventions...
650	;
651	ORIGIN 00044h
652
653	; Jump again...
654	; This time to the code that relocates to 8000:0000.
655	; BOOKMARK: SECOND ENTRY_POINT (Skipped over AB signature)
656	jmp MBR_Start
657
658	;
659	; Entry-point when loading fails.
660	;
661	db 'LOAD ERROR!', 0
662	MBR_LoadError Proc Near
663	mov si, offset $-12
664	push cs
665	pop ds
666	call MBR_Teletype
667	MBRLE_Halt:
668	jmp MBRLE_Halt
669	MBR_LoadError EndP
670
671	;
672	; Entry-point when saving fails.
673	;
674	db 'SAVE ERROR!', 0
675	MBR_SaveError Proc Near
676	mov si, offset $-12
677	push cs
678	pop ds
679	call MBR_Teletype
680	MBRSE_Halt:
681	jmp MBRSE_Halt
682	MBR_SaveError EndP
683
684
685	; Put text on the screen using the BIOS tele-type function.
686	; No attributes like color are supported.
687	; In: SI - Pointer to begin of string (EOS is 0)
688	; Destroyed: SI
689	MBR_Teletype Proc Near Uses ax bx cx
690	mov ah, 0Eh
691	mov bx, 7
692	MBRT_Loop:
693	lodsb
694	or al, al
695	jz MBRT_End
696	int 10h
697	jmp MBRT_Loop
698	MBRT_End:
699	ret
700	MBR_Teletype EndP
701
702	;
703	; Rousseau: DO NOT ADD CODE TO THIS SECTION !
704	;
705
706	; In: BX - Base Check
707	; DS:SI - Pointer to 512-byte-area to be included
708	; Out: BX - Base Check Result
709	; Destroyed: SI will get updated (+512)
710	MBR_GetCheckOfSector Proc Near Uses ax cx
711	mov cx, 256
712	MBRGCOS_Loop:
713	lodsw
714	xor ax, 0BABEh
715	xor bx, ax
716	loop MBRGCOS_Loop
717	or bx, bx
718	jnz MBRGCOS_NoFixUp
719	mov bx, 1 ; dont allow 0, cause 0 == empty
720	MBRGCOS_NoFixUp:
721	ret
722	MBR_GetCheckOfSector EndP
723
724
725
726
727
728
729	; -----------------------------------------------------------------------------
730	; ENTRY-POINT OF MOVED CODE
731	; -----------------------------------------------------------------------------
732
733	;
734	; When we arrive here we are running at 8000:0000.
735	; CX:BX contains the SS:SP of the old stack.
736	;
737
738	;
739	; This is where the rest of AiR-BOOT gets loaded from track0.
740	;
741	; BOOKMARK: Running at relocated position (Load additional sectors)
742	;------------------------------------------------------------------------------
743	MBR_RealStart:
744	;
745	; Setup new stack and other segment registers.
746	;
747	mov ax, StackSeg ; 07000h, below the moved code
748	mov ss, ax
749	mov sp, 7FFEh ; Even is better
750	push es ; ES holds segment where we moved to
751	pop ds ; Set DS=ES to Code Segment
752
753	;
754	; Push the old SS:SP which was saved in CX:BX on the new stack.
755	;
756	push cx ; Old SS
757	push bx ; Old SP
758
759	;
760	; Store the BIOS disk-number AirBoot was loaded from.
761	;
762	mov [BIOS_BootDisk], dl
763
764	; Load the configuration-sectors from disk.
765	; These are the main configuration sector and the various
766	; tables that follow it upto but not including the MBR backup.
767	mov bx, offset Configuration ; Location in RAM
768	mov cx, 0037h ; Config sector is at 55d
769	mov al, (MBR_BackUpMBR - Configuration) / 200h
770	mov ah, 02h
771	; DL is already loaded with BIOS disk-number
772	int 13h ; Call BIOS service
773	jnc MBR_ConfigCopy_NoError
774
775	; Some error occured
776	MBR_ConfigCopy_LoadError:
777	jmp MBR_LoadError ; Will Abort BootUp
778
779	; Load the code-sectors from disk.
780	; [MBR_CodeSecs] is filled in by the FIXCODE helper that post
781	; processes the AIRBOOT loader image after it has been built.
782	MBR_ConfigCopy_NoError:
783	mov bx, offset FurtherMoreLoad ; Directly after MBR
784	mov cx, 0002h ; Start at 2nd sector
785	mov al, [MBR_CodeSecs] ; Number of code sectors
786	mov ah, 02h ; Read sectors
787	; DL is already loaded with BIOS disk-number
788	int 13h ; Call BIOS service
789	jnc MBR_RealStart_NoError
790
791	; Some error occured
792	jmp MBR_LoadError ; Will Abort BootUp
793
794
795	; I13X Signatures
796	ORIGIN 000d0h
797
798	; [v1.05+]
799	; Signature for IBM's LVM to detect our "powerful" features ;)
800	;
801	; [v1.0.8+]
802	; Reworked MBR code to be able to create a
803	; double 'I13X' signature.
804	; MBR's created with LVM eCS v1.x have the signature at 0d5h
805	; MBR's created with LVM eCS v2.x have the signature at 0d0h
806	; See eCS bugtracker issue #3002
807	;
808	; Update: These are actually MOV EAX,'X31I' instructions
809	; in the eCS LVM MBR-code. They are at different places in
810	; the v1.x and v2.x LVM MBR-code. Other code might depend on
811	; their presence. Let's protect their location.
812	db 'I13X',0,'I13X',0
813
814
815	MBR_RealStart_NoError:
816	; Now Check Code with CheckSum
817	mov si, offset FurtherMoreLoad
818
819	;movzx cx, bptr ds:[10h]
820	mov cl, ds:[10h]
821	mov ch,0
822
823	; Claculate checksum
824	xor bx, bx
825	MBR_RealStart_CheckCodeLoop:
826	call MBR_GetCheckOfSector
827	loop MBR_RealStart_CheckCodeLoop
828
829	; Verify checksum
830	cmp MBR_CheckCode, bx
831	;~ je MBR_RealStart_CheckSuccess ; CRC verified
832	jmp MBR_RealStart_CheckSuccess ; Ignore CRC
833
834	; Oops, checksum mismatch -- halt the system
835	mov si, offset TXT_ERROR_Attention
836	call MBR_Teletype
837	mov si, offset TXT_ERROR_CheckCode
838	call MBR_Teletype
839	mov si, offset TXT_ERROR_CheckFailed
840	call MBR_Teletype
841	jmp MBR_HaltSystem
842
843
844	;
845	; OK, all loading went fine so the rest of the code
846	; is present now, so we jump to it.
847	; The old SS:SP is still on the stack.
848	;
849	MBR_RealStart_CheckSuccess:
850	jmp AiR_BOOT_Start
851
852
853
854
855
856	;------------------------------------------------------------------------------
857	include text/txtmbr.asm ; All translateable Text in MBR
858	;------------------------------------------------------------------------------
859
860	; Disk Signature
861	ORIGIN 001B8h
862
863
864	; Disk Signature
865	; Note that in an LVM 2.x MBR this collides
866	; with the dummy PTE that it uses to look for IBM-BM
867	; on the second harddisk.
868	; AiR-BOOT installer will merge the field
869	; from the MBR it replaces.
870	MBR_DrvSig db 'DSIG'
871
872	; Unused word at 01BCh.
873	; An LVM 2.x MBR puts 0CC33h here.
874	; AiR-BOOT installer will merge the field
875	; from the MBR it replaces.
876	MBR_Spare dw '$$'
877
878
879	; Partition Table.
880	ORIGIN 001BEh
881
882	; The 4 entries just for show.
883	; AiR-BOOT installer will merge them from the MBR it replaces.
884	MBR_PartTable:
885	db 16 dup('0')
886	db 16 dup('1')
887	db 16 dup('2')
888	db 16 dup('3')
889
890	; Boot Sigbature
891	MBR_Sig dw 0aa55h
892
893
894
895
896
897
898
899	;==============================================================================
900	; Sector 2
901	;==============================================================================
902
903	; -----------------------------------------------------------------------------
904	; FILE-SYSTEM TABLES
905	; -----------------------------------------------------------------------------
906
907	; First sector the rest of the loader image
908	ORIGIN 00200h
909
910	;
911	; Everything beyond this point is loaded on startup
912	; and is NOT existant at first
913	;
914	FurtherMoreLoad:
915
916	;
917	; Filesystem table correlating id with name.
918	;
919
920	; first Normal-Partition-ID, Hidden-Partition-ID
921	; and Default-Partition-Flags.
922	; 01h -> Boot-Able
923	; 10h -> FAT32 - Name Getting Scheme
924	; 20h -> No Name To Get (use Partition Name from IPT)
925	; 40h -> 'L' flag possible
926	db 'AiRSYS-TABLE'
927	FileSysIDs db 01h, 11h,01h, 04h,014h,01h, 06h,016h,41h, 0Eh,00Eh,01h
928	db 07h, 17h,41h, 08h,017h,21h, 35h,035h,20h,0FCh,017h,41h
929	db 09h, 19h,11h, 0Bh,01Bh,11h, 0Ch,01Ch,11h,0EBh,0EBh,01h
930	db 63h, 63h,21h, 81h,081h,21h, 83h,083h,21h, 40h,040h,21h
931	db 0A5h,0A5h,21h,0A6h,0A6h,21h, 82h,082h,20h,0A7h,0A7h,21h
932	db 63h, 63h,21h, 4Dh,04Dh,21h, 4Eh,04Eh,21h, 4Fh,04Fh,21h
933	db 01h, 01h,01h, 01h,001h,01h, 01h,001h,01h, 01h,001h,01h
934	db 01h, 01h,01h, 01h,001h,01h, 01h,001h,01h, 01h,001h,01h
935	db 01h, 01h,01h, 01h,001h,01h, 01h,001h,01h, 01h,001h,01h
936	db 01h, 01h,01h,0FDh,0FDh,20h, 84h,084h,20h,0A0h,0A0h,20h
937	db 0Ah, 0Ah,20h,0FEh,0FEh,21h,0FFh,0FFh,21h, 00h,000h,21h
938	db 16 dup (0)
939
940	FileSysNames db 'FAT12 ', 'FAT16 ', 'FAT16Big', 'FAT16Big'
941	db 'HPFS ', 'NTFS ', 'LVM-Data', 'JFS '
942	db 'FAT32 ', 'FAT32 ', 'FAT32 ', 'BeOS '
943	db 'Unix ', 'Minix ', 'Linux ', 'Venix ' ; x row ;)
944	db 'BSD/386 ', 'OpenBSD ', 'LinuxSwp', 'NeXTSTEP'
945	db 'GNU HURD', 'QNX ', 'QNX ', 'QNX '
946	db ' ', ' ', ' ', ' '
947	db ' ', ' ', ' ', ' '
948	db ' ', ' ', ' ', ' '
949	db ' ', 'Kernel ', ' ', '0V-Award'
950	; db 'OS/2 Man', 'via BIOS', 'Floppy ', 'Unknown '
951	db 'OS2-BMGR', 'via BIOS', 'Floppy ', 'Unknown '
952	; -> 44 Partition-Types
953
954
955
956
957
958
959	;==============================================================================
960	; Sector 3
961	;==============================================================================
962
963	; -----------------------------------------------------------------------------
964	; ENTRY-POINT AFTER LOADING THE REST OF THE CODE
965	; -----------------------------------------------------------------------------
966
967	; The entry-point jumped to from the MBR code
968	ORIGIN 00400h
969
970
971	;##############################################################################
972	;# AiR_BOOT_Start :: This is where the real work begins #
973	;# -------------------------------------------------------------------------- #
974	;# At this point, all of AirBoot is loaded, including its configuration. #
975	;# First, some setup is done, which includes the initialization of variables #
976	;# in the BSS. After that, disks are scanned for partitions and the required #
977	;# house keeping is done to incorporate changes from the previous boot. Then #
978	;# the partition list is prepared and the menu is presented. #
979	;##############################################################################
980	; BOOKMARK: AiR_BOOT_Start (AiR-BOOT now completely loaded)
981	AiR_BOOT_Start:
982
983
984	;
985	; Enable interrupts.
986	;
987	sti
988
989	;
990	; Pop the old SS:SP from the stack and save it in the BSS.
991	; Note that this is outside the normal variable area that gets cleared.
992	; This allows AiR-BOOT to restart itself when debugging and come-up
993	; with access to the original values of registers the BIOS passed.
994	;
995	pop [OldSP]
996	pop [OldSS]
997
998	; Clear the BSS from its real start just upto the end of the variables.
999	; Here 'real start' means from where the BSS begins, which is below
1000	; the point where the first variables are located. The part after
1001	; the variables is not cleared because that is where the old SS:SP is
1002	; stored, which is needed for AirBoot restarts during debugging.
1003	mov bx, offset sobss
1004	mov cx, offset EndOfVariables - offset sobss
1005	xor ax, ax
1006	call FillMemBlock
1007
1008	; Initialize the com-port for debugging
1009	IFDEF AUX_DEBUG
1010	PUSHRF
1011	; Init com-port
1012	call AuxIO_Init
1013	; Hello message
1014	mov si, offset [AuxIOHello]
1015	call AuxIO_Print
1016	; Show Build Info
1017	call AuxIO_PrintBuildInfo
1018	call AuxIO_TeletypeNL
1019	POPRF
1020	ENDIF
1021
1022	; Dump debug information
1023	IFDEF AUX_DEBUG
1024	IF 1
1025	call DEBUG_Dump1
1026	ENDIF
1027	ENDIF
1028
1029	; Verify we still got the BIOS disk in DL
1030	IFDEF AUX_DEBUG
1031	IF 1
1032	DBG_TEXT_OUT_AUX '## AiR_BOOT_Start ##'
1033	PUSHRF
1034	call DEBUG_DumpRegisters
1035	POPRF
1036	ENDIF
1037	ENDIF
1038
1039
1040	; -----------------------------------------------------------------------------
1041	; IBM-BM BOOT PREPARATION
1042	; -----------------------------------------------------------------------------
1043	;
1044	; Since v1.0.8, AiR-BOOT is able to chainload IBM-BM.
1045	; When IBM-BM resides above the 1024-cylinder limit, the 'I13X'
1046	; signature is required at 3000:0000, FS needs to contain 3000h
1047	; and the 32-bit LBA address needs to follow the 'I13X' signature.
1048	; For booting IBM-BM from the second disk, a copy of the MBR of the
1049	; first disk is also required at 0000:7E00.
1050	; This information is derived from the eCS 2.x LVM MBR.
1051	;
1052	; So, now is a good time to copy the MBR of the first disk to
1053	; 0000:7E00 in case the partition that will be started is IBM-BM.
1054	; This copy is located at 8000:0000 and DS already points to this
1055	; segment. The 'I13X' signature and FS will be setup later.
1056	;
1057	pusha ; Save all the general purpose regs
1058	push es ; We need ES too, so save its value
1059	xor ax,ax ; Segment 0000h
1060	mov es,ax ; Make ES point to it
1061	mov si,offset BootBasePtr ; Start of AiR-BOOT which has the MBR
1062	mov di,7e00h ; Destination for the MBR for IBM-BM
1063	mov cx,100h ; 256 words = 512 bytes
1064	cld ; Direction from low to high
1065	rep movsw ; Copy the 256 words of the MBR
1066	pop es ; Restore previous value of ES
1067	popa ; Restore all the general purpose regs
1068
1069
1070	; -----------------------------------------------------------------------------
1071	; PRECRAP
1072	; -----------------------------------------------------------------------------
1073
1074	;
1075	; First it clears the BSS area.
1076	; Note that the old SS:SP is stored outside this area so this
1077	; does not get lost.
1078	; Then initialize various runtime variables and structures.
1079	;
1080	; BOOKMARK: Pre Crap
1081	call PRECRAP_Main
1082	; Number of harddisks and other system-info is now known.
1083
1084	;!
1085	;! DEBUG_BLOCK
1086	;! Let's see what the BIOS supplied us with...
1087	;! Uncomment below to activate.
1088	;!
1089	IFDEF AUX_DEBUG
1090	IF 0
1091	pushf
1092	pusha
1093
1094	; Print title.
1095	mov si,offset [bios_reg]
1096	call AuxIO_Print
1097	; Save the current stack (SS:SP).
1098	mov ax,ss
1099	mov [CurrentSS],ax
1100	mov [CurrentSP],sp
1101
1102	; Restore the old stack.
1103	mov ss,[OldSS]
1104	mov sp,[OldSP]
1105
1106	; Pop the registers with the BIOS values.
1107	popa
1108	; Push them back for AiR-BOOT restart (debug mode).
1109	pusha
1110	; Dump them to the serial-port.
1111	call DEBUG_DumpRegisters
1112	; Restore the current stack.
1113	mov ax,[CurrentSS]
1114	mov ss,ax
1115	mov sp,[CurrentSP]
1116
1117	popa
1118	popf
1119	ENDIF
1120	ENDIF
1121
1122
1123
1124	; -----------------------------------------------------------------------------
1125	; UPDATE MBR
1126	; -----------------------------------------------------------------------------
1127
1128	; Write MBR back to disk to sync MBR variables.
1129	; Otherwise subsequent MBR loads will differ from the RAM stored one,
1130	; which is used by MBR protection to validate parts of the MBR.
1131	xor bx, bx ; 0000h - our load address (8000:0000)
1132	mov cx, 1 ; CHS sector 1, cylinder 0
1133	xor dh, dh ; CHS head 0
1134	mov dl, [BIOS_BootDisk] ; The disk we were loaded from
1135	mov al, 1 ; One sector to write
1136	mov ah, 03h ; BIOS write disk (legacy)
1137	int 13h ; Call BIOS
1138	sti ; Enable ints
1139	;!
1140	;! TODO: Check success
1141	;! Yes, we should check for errors here, coz it would mean AirBoot
1142	;! was loaded from a disk where the MBR cannot be written !
1143	;!
1144
1145
1146
1147	; -----------------------------------------------------------------------------
1148	; SCAN DISKS
1149	; -----------------------------------------------------------------------------
1150
1151	;!
1152	;! DEBUG_BLOCK
1153	;! Dump the registers at this point.
1154	;!
1155	IFDEF AUX_DEBUG
1156	IF 0
1157	PUSHRF
1158	call DEBUG_DumpRegisters
1159	;~ call DEBUG_DumpDriveLetters
1160	;~ call DEBUG_DumpVolumeLetters
1161	;~ call DEBUG_DumpPartitionXref
1162	POPRF
1163	ENDIF
1164	ENDIF
1165
1166
1167	;
1168	; Scan disks for information like size etc.
1169	;
1170	call DriveIO_ScanDisks
1171
1172	;!
1173	;! DEBUG_BLOCK
1174	;! Dump the registers at this point.
1175	;!
1176	IFDEF AUX_DEBUG
1177	IF 0
1178	PUSHRF
1179	call DEBUG_DumpRegisters
1180	;~ call DEBUG_DumpDriveLetters
1181	;~ call DEBUG_DumpVolumeLetters
1182	;~ call DEBUG_DumpPartitionXref
1183	POPRF
1184	ENDIF
1185	ENDIF
1186
1187
1188	; -----------------------------------------------------------------------------
1189	; SCAN FOR PARTITIONS
1190	; -----------------------------------------------------------------------------
1191
1192	;
1193	; Scan disks for partitions
1194	;
1195	call PARTSCAN_ScanForPartitions
1196
1197	;
1198	; Internal Partition Table is now populated.
1199	;
1200
1201	;!
1202	;! DEBUG_BLOCK
1203	;! Dump various tables.
1204	;!
1205	IFDEF AUX_DEBUG
1206	IF 0
1207	PUSHRF
1208	;~ call DEBUG_DumpIPT
1209	;~ call DEBUG_DumpPartitionPointers
1210	;~ call DEBUG_DumpNewPartTable
1211	;~ call DEBUG_DumpDriveLetters
1212	;~ call DEBUG_DumpDriveLetters
1213	;~ call DEBUG_DumpVolumeLetters
1214	;~ call DEBUG_DumpPartitionXref
1215	POPRF
1216	ENDIF
1217	ENDIF
1218
1219
1220	; -----------------------------------------------------------------------------
1221	; RESTORE FORCED DRIVELETTER CORRELATION [LVM]
1222	; -----------------------------------------------------------------------------
1223
1224	;
1225	; Reconnect forced drive-letters to their corresponding
1226	; partitions.
1227	;
1228	; BOOKMARK: Update Driveletters so they are in-sync again
1229	call PARTSCAN_UpdateDriveLetters
1230	; Driveletter <-> Partition correlation is now restored.
1231
1232
1233
1234	;!
1235	;! DEBUG_BLOCK
1236	;! Dump various tables.
1237	;!
1238	IFDEF AUX_DEBUG
1239	IF 0
1240	PUSHRF
1241	;~ call DEBUG_DumpIPT
1242	;~ call DEBUG_DumpPartitionPointers
1243	;~ call DEBUG_DumpNewPartTable
1244	;~ call DEBUG_DumpDriveLetters
1245	;~ call DEBUG_DumpDriveLetters
1246	;~ call DEBUG_DumpVolumeLetters
1247	;~ call DEBUG_DumpPartitionXref
1248	POPRF
1249	ENDIF
1250	ENDIF
1251
1252
1253	; -----------------------------------------------------------------------------
1254	; SHOW WE ARE ALIVE
1255	; -----------------------------------------------------------------------------
1256
1257	;
1258	; Put some info about AiR-BOOT and the system on the screen.
1259	;
1260
1261	; Display number of physical disks found
1262	IFNDEF AUX_DEBUG
1263	mov [TextPosY], 3
1264	ELSE
1265	mov [TextPosY], 4
1266	ENDIF
1267	mov [TextPosX], 0
1268	mov si, offset [DisksFound]
1269	call VideoIO_Print
1270	mov al, [TotalHarddiscs]
1271	mov [TextColorFore], 0fh
1272	call VideoIO_PrintByteDynamicNumber
1273	mov [TextColorFore], 07h
1274
1275	; Display number of partitions found
1276	inc [TextPosY]
1277	mov [TextPosX], 0
1278	mov si, offset [PartitionsFound]
1279	call VideoIO_Print
1280	mov al, [CFG_Partitions]
1281	call VideoIO_PrintByteDynamicNumber
1282
1283	; Display Phase 1 Indicator
1284	inc [TextPosY]
1285	mov [TextPosX], 0
1286	mov si, offset [Phase1]
1287	call VideoIO_Print
1288	mov si, offset [OS2_InstallVolume]
1289	mov al, [si]
1290	test al,al ; See if phase 1 is active
1291	jnz @F
1292	mov si, offset [No]
1293	@@:
1294	call VideoIO_Print
1295
1296	; Display information about the disks found
1297	call VideoIO_DisplayDiskInfo
1298
1299
1300
1301	; -----------------------------------------------------------------------------
1302	; OS/2 PHASE1 CHECK
1303	; -----------------------------------------------------------------------------
1304
1305	;
1306	; BOOKMARK: Check for OS/2 being installed
1307	; Here we check if OS/2 is being installed.
1308	; If so, we forgo the menu and directly boot it.
1309	;
1310
1311	; If the first byte of the name of the Install Volume is not 0
1312	; then we potentially have a phase1 boot.
1313	test byte ptr [OS2_InstallVolume],0ffh
1314	; Nope, so continue normally.
1315	jz MBR_Main_ContinueBoot
1316
1317	; Setup phase1.
1318	; It is still possible that a name was set for the
1319	; Install Volume that does not exist.
1320	; In that case CY will be clear and AL=0FFh.
1321	call PART_SetupPhase1
1322	; Oops, Install Volume not found, continue normally.
1323	jnc MBR_Main_ContinueBoot
1324
1325
1326	;
1327	; == Install Volume Found ==
1328	;
1329
1330
1331	;!
1332	;! DEBUG_BLOCK
1333	;! Dump various tables.
1334	;!
1335	IFDEF AUX_DEBUG
1336	IF 0
1337	PUSHRF
1338	;~ call DEBUG_DumpIPT
1339	;~ call DEBUG_DumpPartitionPointers
1340	;~ call DEBUG_DumpPartitionXref
1341	;~ call DEBUG_DumpNewPartTable
1342	;~ call DEBUG_DumpDriveLetters
1343	POPRF
1344	ENDIF
1345	ENDIF
1346
1347
1348	; BOOKMARK: Scan for Partitions (Only if OS/2 install going on)
1349	; Because one or more partitions are possibly added, the
1350	; PartitionXref table is not 'in sync' and could cause the
1351	; wrong system to be automatically booted.
1352	; So we rescan all partitions causing the PartitionXref
1353	; table to be filled with correct values so the auto-boot
1354	; from the new partition will work correctly.
1355	call PARTSCAN_ScanForPartitions
1356
1357
1358	;!
1359	;! DEBUG_BLOCK
1360	;! Dump various tables.
1361	;!
1362	IFDEF AUX_DEBUG
1363	IF 0
1364	PUSHRF
1365	;~ call DEBUG_DumpIPT
1366	;~ call DEBUG_DumpPartitionPointers
1367	;~ call DEBUG_DumpPartitionXref
1368	;~ call DEBUG_DumpNewPartTable
1369	;~ call DEBUG_DumpDriveLetters
1370	POPRF
1371	ENDIF
1372	ENDIF
1373
1374	; Setup automatic boot to forgo the Menu.
1375	; PART_SetupPhase1 has filled in the other variables.
1376	mov byte ptr [CFG_AutomaticBoot],1
1377
1378	;
1379	; At this point the AiR-BOOT configuration has been altered
1380	; to automatically boot the newly installed system without
1381	; displaying the menu.
1382	; Code further down the road will take care of that.
1383	;
1384	jmp MBR_Main_ContinueBoot
1385
1386
1387
1388
1389	;
1390	; Wether a new system is being installed or not,
1391	; booting continues here.
1392	;
1393	MBR_Main_ContinueBoot:
1394
1395	;
1396	; Inform user how to switch between post-screen and menu
1397	; by putting this info on the screen.
1398	;
1399	mov [TextPosY], 23
1400	mov [TextPosX], 0
1401	mov si, offset [TABMessage]
1402	call VideoIO_Print
1403	inc [TextPosY]
1404	mov [TextPosX], 57
1405	call MBR_TeletypeSyncPos
1406	mov si, offset [PREPMessage]
1407	call MBR_TeletypeBold
1408	mov al,30
1409	call TIMER_WaitTicCount
1410	mov cl, sizeof [PREPMessage]
1411	mov al, ' '
1412	call VideoIO_PrintSingleMultiChar
1413
1414	mov [TextPosX], 25
1415	mov si, offset [BootEndMsg2]
1416	add si, 39
1417	mov [TextColorFore], 08h
1418	call VideoIO_Print
1419
1420
1421	;
1422	; Debug stop.
1423	;
1424
1425	;
1426	; ####################### WAIT FOR KEY ########################
1427	;
1428
1429	; Wait for key so we can see debug log if ab-menu hangs.
1430	;~ xor ax, ax
1431	;~ int 16h
1432	;call SOUND_Beep
1433
1434
1435	; Copy BIOS POST to Second Page
1436	mov ax, VideoIO_Page1
1437	call VideoIO_BackUpTo
1438
1439	;call SOUND_Beep
1440
1441
1442	; BOOKMARK: Save Configuration
1443	; Save configuration so phase1 boot-through is disabled
1444	; on next boot.
1445	mov byte ptr [OS2_InstallVolume], 0
1446	call DriveIO_SaveConfiguration
1447
1448
1449
1450	;
1451	; See if setup needs to be entered.
1452	;
1453	MBR_Main_ReEnterSetup:
1454	call SETUP_CheckEnterSETUP
1455
1456	;
1457	; Do some post processing.
1458	;
1459	; BOOKMARK: After Crap
1460	call AFTERCRAP_Main
1461
1462	MBR_Main_ReEnterBootMenuPre:
1463	; SetUp PartitionPointers for BootMenu (filter non-bootable)
1464	call PART_CalculateMenuPartPointers
1465
1466	; ...and count that one...
1467	cmp byte ptr [PartitionPointerCount], 0
1468	jne MBR_Main_SomethingBootAble
1469	mov si, offset TXT_NoBootAble
1470	call MBR_Teletype
1471	jmp MBR_HaltSystem
1472
1473	MBR_Main_SomethingBootAble:
1474	; FixUp Values, define Timed Setup booting, etc.
1475	call PART_FixUpDefaultPartitionValues
1476
1477
1478
1479	; -------------------------------------------------- BOOT-MENU
1480	MBR_Main_ReEnterBootMenu:
1481	call BOOTMENU_ResetMenuVars ; reset has to be done
1482	test byte ptr [CFG_AutomaticBoot], 1
1483	jz MBR_Main_NoAutomaticBooting
1484
1485
1486	; ------------------------------------------ AUTOMATIC BOOTING
1487	; Select automatic partition, disable automatic booting for
1488	; next time and boot system...
1489	mov byte ptr [CFG_AutomaticBoot], 0
1490	call PASSWORD_AskSystemPwd
1491	mov al, Menu_EntryAutomatic
1492
1493	;mov al, 2
1494
1495	mov Menu_EntrySelected, al ; zero based
1496	jmp MBR_Main_NoBootMenu
1497
1498
1499	MBR_Main_NoAutomaticBooting:
1500
1501	;call SOUND_Beep
1502
1503	test byte ptr [CFG_BootMenuActive], 0FFh
1504	jnz MBR_Main_GotBootMenu
1505	; ----------------------------------------------- NO BOOT-MENU
1506	; Select default partition and boot system...
1507	call PASSWORD_AskSystemPwd
1508
1509	mov al, Menu_EntryDefault
1510	;mov al,0 ; zero based
1511	mov Menu_EntrySelected, al
1512	jmp MBR_Main_NoBootMenu
1513
1514	MBR_Main_GotBootMenu:
1515	; ------------------------------------------ BOOT-MENU VISUALS
1516
1517
1518	IFDEF FX_ENABLED
1519	call FX_StartScreen
1520	ENDIF
1521
1522	; BOOKMARK: Build Main Menu
1523	call BOOTMENU_BuildBackground
1524	call BOOTMENU_BuildMain
1525
1526	IFDEF FX_ENABLED
1527	call FX_EndScreenRight
1528	ENDIF
1529
1530	call PASSWORD_AskSystemPwd
1531	call BOOTMENU_ResetTimedBoot
1532
1533	; BOOKMARK: Display Main Menu
1534	call BOOTMENU_Execute
1535
1536	jc MBR_Main_ReEnterSetup
1537	call BOOTMENU_SetVarsAfterMenu
1538
1539	; ---------------------------------------------------- BOOTING
1540	MBR_Main_NoBootMenu:
1541
1542	IFDEF FX_ENABLED
1543	call FX_StartScreen
1544	ENDIF
1545
1546	IFDEF AUX_DEBUG
1547	IF 0
1548	DBG_TEXT_OUT_AUX 'HALTING'
1549	PUSHRF
1550	;~ call DEBUG_DumpRegisters
1551	;~ call AuxIO_DumpParagraph
1552	;~ call AuxIO_TeletypeNL
1553	@@: jmp @B
1554	POPRF
1555	ENDIF
1556	ENDIF
1557	; BOOKMARK: Display bye-screen and start selected partition
1558	call BOOTMENU_BuildGoodBye
1559
1560	IFDEF FX_ENABLED
1561	call FX_EndScreenRight
1562	ENDIF
1563
1564	call PASSWORD_AskChangeBootPwd
1565
1566	call ANTIVIR_SaveBackUpMBR
1567
1568	; Preload the selected menu-entry
1569	; However, this value will be wrong if OS/2 phase1 is
1570	; active and the installation partition is newly created.
1571	; See below for the adjustment.
1572	mov dl, byte ptr [Menu_EntrySelected]
1573
1574
1575	;
1576	; Prepare to start the partition.
1577	;
1578	jmp MBR_Main_StartPartition
1579
1580
1581
1582	; -----------------------------------------------------------------------------
1583	; START PARTITION
1584	; -----------------------------------------------------------------------------
1585
1586	MBR_Main_StartPartition:
1587
1588	IFDEF AUX_DEBUG
1589	IF 0
1590	PUSHRF
1591	;~ call DEBUG_DumpIPT
1592	;~ call DEBUG_DumpPartitionPointers
1593	;~ call DEBUG_DumpPartitionXref
1594	;~ call DEBUG_DumpNewPartTable
1595	POPRF
1596	ENDIF
1597	ENDIF
1598
1599
1600	; -------------------------------------------- START PARTITION
1601	; THIS DOES NOT RETURN !
1602	call PART_StartPartition
1603
1604
1605
1606
1607	;
1608	; This entry-point restarts AiR-BOOT almost from scratch.
1609	; It skips the movement of the MBR but otherwise it is a functional restart.
1610	; The old BIOS SS:SP where the registers on entry are stored is passed along.
1611	; This entry-point is used for debugging purposes.
1612	;
1613	; BOOKMARK: AiR-BOOT Restart (used for debugging)
1614	AirbootRestart:
1615	mov bx, [OldSP] ; Old SP when BIOS transferred control to AB
1616	mov cx, [OldSS] ; Old SS when BIOS transferred control to AB
1617	xor dh, dh ; Head 0
1618	mov dl, [BIOS_BootDisk] ; Disk AirBoot was loaded from
1619	jmp MBR_RealStart
1620
1621
1622	;
1623	; This entry-point displays a popup that the system is halted
1624	; and then halts the system.
1625	; It is entered on severe error conditions.
1626	;
1627	; BOOKMARK: Halt System
1628	HaltSystem:
1629	call VideoIO_ClearScreen
1630	mov ax,0ababh
1631	mov cx, 0C04h
1632	mov si, offset SystemHalted
1633	call SETUP_ShowErrorBox
1634	; Halt the system.
1635	jmp MBR_HaltSystem
1636
1637
1638
1639
1640
1641
1642	;
1643	; The following section includes various assembler modules
1644	; at the source level. These contain functionality for a
1645	; multitude of categories like disk-access, video-io, lvm,
1646	; debugging, etc. Later versions of AiR-BOOT will use such
1647	; modules at the object-file level so they can be shared
1648	; more easily.
1649	;
1650
1651
1652	; -----------------------------------------------------------------------------
1653	; INCLUDED FILE SECTION
1654	; -----------------------------------------------------------------------------
1655
1656	; BOOKMARK: Include Section
1657
1658	;
1659	; Include other code-modules here.
1660	;
1661
1662	b_std_txt:
1663	include regular/std_text.asm ; Standard (non-translateable text)
1664	size_std_txt = $-b_std_txt
1665
1666	b_driveio:
1667	include regular/driveio.asm ; Drive I/O, Config Load/Save
1668	size_driveio = $-b_driveio
1669
1670	b_lvm:
1671	include special/lvm.asm ; LVM-specific code
1672	size_lvm = $-b_lvm
1673
1674	b_videoio:
1675	include regular/videoio.asm ; Video I/O
1676	size_videoio = $-b_videoio
1677
1678	b_timer:
1679	include regular/timer.asm ; Timer
1680	size_timer = $-b_timer
1681
1682	b_partmain:
1683	include regular/partmain.asm ; Regular Partition Routines
1684	size_partmain = $-b_partmain
1685
1686	b_partscan:
1687	include regular/partscan.asm ; Partition Scanning
1688	size_partscan = $-b_partscan
1689
1690	b_bootmenu:
1691	include regular/bootmenu.asm ; Boot-Menu
1692	size_bootmenu = $-b_bootmenu
1693
1694	b_password:
1695	include regular/password.asm ; Password related
1696	size_password = $-b_password
1697
1698	b_other:
1699	include regular/other.asm ; Other Routines
1700	size_other = $-b_other
1701
1702	b_main:
1703	include setup/main.asm ; The whole AiR-BOOT SETUP
1704	size_main = $-b_main
1705
1706	b_math:
1707	include regular/math.asm ; Math functions (like 32-bit multiply)
1708	size_math = $-b_math
1709
1710	b_txtother:
1711	include text/txtother.asm ; All translateable Text-Strings
1712	size_txtother = $-b_txtother
1713
1714	b_txtmenus:
1715	include text/txtmenus.asm ; All translateable Menu-text
1716	size_txtmenus = $-b_txtmenus
1717
1718	b_charset:
1719	include text/charset.asm ; Special Video Charsets (if needed)
1720	size_charset = $-b_charset
1721
1722	b_conv:
1723	include regular/conv.asm ; Various conversion routines
1724	size_conv = $-b_conv
1725
1726	b_virus:
1727	include special/virus.asm ; Virus Detection / Anti-Virus
1728	size_virus = $-b_virus
1729
1730	b_billsuxx:
1731	include special/f00k/billsuxx.asm ; Extended Partition - Microsoft-Hack
1732	size_billsuxx = $-b_billsuxx
1733
1734	b_sound:
1735	include special/sound.asm ; Sound
1736	size_sound = $-b_sound
1737
1738	b_apm:
1739	include special/apm.asm ; Power Managment Support
1740	size_apm = $-b_apm
1741
1742
1743
1744	;
1745	; Cyrillic support.
1746	;
1747	IFDEF TXT_IncludeCyrillic
1748	b_ccharset:
1749	include special/charset.asm ; Charset Support (e.g. Cyrillic)
1750	size_ccharset = $-b_ccharset
1751	ENDIF
1752
1753	; Various debugging routines, uses AUXIO and CONV
1754	IFDEF AUX_DEBUG
1755	b_debug:
1756	include regular/debug.asm ; Debug module
1757	size_debug = $-b_debug
1758	b_auxio:
1759	include regular/auxio.asm ; Com-port support for debugging
1760	size_auxio = $-b_auxio
1761	ENDIF
1762
1763	;
1764	; We only include this if FX_ENABLED is defined.
1765	; FX is disabled when debugging to have more room for debug-code.
1766	; The module compiles to 50eh = 1294 bytes, so that is a lot.
1767	;
1768	IFDEF FX_ENABLED
1769	b_fx:
1770	include special/fx.asm ; l33t Cooper-Bars/Scrolling <bg>
1771	size_fx = $-b_fx
1772	ENDIF
1773
1774
1775	;
1776	; End of code marker.
1777	;
1778	; BOOKMARK: END OF CODE
1779	db 'BABE'
1780	db 'FACE'
1781
1782
1783	; -----------------------------------------------------------------------------
1784	; END OF CODE
1785	; -----------------------------------------------------------------------------
1786	code_end:
1787
1788
1789
1790
1791
1792
1793
1794
1795
1796
1797	; -----------------------------------------------------------------------------
1798	; BLDLEVEL INFORMATION
1799	; -----------------------------------------------------------------------------
1800
1801	; BOOKMARK: BLDLEVEL Information
1802	ORIGIN 068A0h
1803
1804	;
1805	; The space between this offset and code_end is the space
1806	; available for code.
1807	;
1808	zzz_code_space = $ - code_end
1809
1810
1811	bld_level:
1812	;
1813	; Here we insert the OS/2 BLDLEVEL Information.
1814	; It is composed of the AiR-BOOT version-info and other
1815	; information. It is unique for each release of AiR-BOOT.
1816	;
1817
1818	;
1819	; ?? When AUX_DEBUG is enabled and the above org is active,
1820	; the BLDLEVEL gets corrupted eventhough it gets inserted here
1821	; explicitly. The effect is almost like an 'OR' or a merge
1822	; with the already generated FX code.
1823	; Tasm and JWasm produce different results.
1824	; ??
1825	;
1826	InsertBuildLevel
1827
1828
1829
1830
1831
1832	;==============================================================================
1833	; Sector 53
1834	;==============================================================================
1835
1836	;
1837	; From here on, the layout of the image consists of:
1838	; - AiR-BOOT Protection Image
1839	; - AiR-BOOT Configuration
1840	; - DriveLetters
1841	; - Install Volume
1842	; - Floppy/CDROM/BIOS BOOT ENTRIES
1843	; - Internal Partition Table (IPT)
1844	; - Hidden Partition Table (HPT)
1845	; - MBR Backup
1846	;
1847
1848	;
1849	; After that, the BSS follows with several runtime
1850	; variables and structures.
1851	; The BSS is not part of the image on disk of course.
1852	;
1853
1854	; -----------------------------------------------------------------------------
1855	; PROTECTION IMAGE
1856	; -----------------------------------------------------------------------------
1857
1858	;
1859	; This is the AiR-BOOT MBR Protection Image.
1860	; The stuff generated here gets overwritten when the
1861	; MBR_PROT module, which is assembled separately,
1862	; gets binary merged.
1863	; So you won't find the string below in the generated binary.
1864	;
1865	; BOOKMARK: AiR-BOOT MBR Protection Image
1866	ORIGIN 06900h
1867
1868
1869
1870
1871	;
1872	; Hardcoded to 768 bytes (MBR_PROT.ASM)
1873	; The string below is searched for by the FIXCODE helper and must be
1874	; page (256 bytes) aligned.
1875	;
1876	; It seems to be possible to shrink the protection-image to 768 bytes.
1877	; That gives us an additional 256 bytes of code-space.
1878	; MBR-PROT.ASM,FIXCODE.C,PARTMAIN.ASM and AIR-BOOT.ASM need to be adjusted for that.
1879	; Also the granularity needs to change from 512 bytes to 256 bytes since
1880	; 6900h is not a 512-byte boundary.
1881	;
1882	; 20120908 - Done.
1883	;
1884	MBR_Protection db 'AiR-BOOT MBR-Protection Image'
1885
1886	; Just fill.
1887	;~ db 1024-($-MBR_Protection) dup('M')
1888	db 768-($-MBR_Protection) dup('M')
1889
1890
1891
1892
1893
1894
1895
1896	;==============================================================================
1897	; Sector 55
1898	;==============================================================================
1899	; -----------------------------------------------------------------------------
1900	; AiR-BOOT CONFIGURATION
1901	; -----------------------------------------------------------------------------
1902
1903	;
1904	; This section contains the AiR-BOOT configuration.
1905	; Note that it has a version that should be updated
1906	; when stuff is added.
1907	; Also add stuff to the end so that offsets of other
1908	; variables remain vaild.
1909	;
1910	; BOOKMARK: AiR-BOOT Configuration Sector
1911	ORIGIN 06C00h
1912
1913	Configuration:
1914	; This is the signature for the AiR-BOOT Configuration.
1915	; Note that this configuration section, like the code section,
1916	; is CRC protected. This means that poking values in these
1917	; sections on the disk will invalidate AiR-BOOT and cause it
1918	; to halt. This is a protection method against other software
1919	; modifying stuff in track 0.
1920	db 'AiRCFG-TABLE',0adh
1921	db 01h, 10h, 'U' ; "Compressed" ID String
1922	; Version 1.02 was for code 1.06, 1.03 was internal
1923	; and 1.04,1.05 and 1.06 do not exist.
1924	;
1925	; 1.07 was used with AB v1.07 and introduced the phase1
1926	; system-name. For the rest it is compatible with v1.02.
1927	;
1928	; 1.0.8 is introduced with AB v1.0.8 and indicates the movement
1929	; of several components and the packing of the hideparttable.
1930	; The core configuration has not changed but the generated
1931	; configuration has. The v1.0.8 installer handles upgrading.
1932	;
1933	; It has been decided that uneven minor numbers will be
1934	; test-versions. Therefore v1.0.8 has been bumbed to v1.1.0.
1935	;
1936	; It is not required for the config to have the
1937	; same version as the code, so in the future
1938	; the code version might be higher than the
1939	; config version if there are no changes to the latter.
1940	;
1941
1942	CFG_LastTimeEditLow dw 0 ; Last Time Edited Stamp (will incr every setup)
1943	CFG_LastTimeEditHi dw 0 ; second 16 bit part...
1944
1945	CFG_CheckConfig dw 0 ; Check-Sum for Configuration
1946
1947	CFG_Partitions db 0 ; Count of partitions in IPT
1948	CFG_MiscFlags db 1 ; Miscellaneous Flags (See EQUates)
1949	CFG_PartDefault db 0 ; Default-Partition (Base=0)
1950
1951	CFG_PartLast db 0 ; Which Partition was booted last time ? (Base=0)
1952	CFG_TimedBoot db 1 ; Timed Boot Enable (for REAL Enable look TimedBootEnable)
1953	CFG_TimedSecs db 15 ; Timed Boot - How Many Seconds Till Boot
1954	CFG_TimedDelay dw 123 ; Timed Boot - Delay
1955	CFG_TimedBootLast db 1 ; Timed Boot - Boot From Last Drive Booted From
1956	CFG_RememberBoot db 1 ; Remember Manual Boot Choice
1957	CFG_RememberTimed db 0 ; Remember if Timed Boot (if both disabled: Boot Default)
1958	CFG_IncludeFloppy db 1 ; Include Floppy Drives in Boot-Menu
1959	CFG_BootMenuActive db 1 ; Display Boot-Menu (if Disabled: Boot Default)
1960	; v0.29+ -> 2 - Detailed Bootmenu
1961	CFG_PartitionsDetect db 1 ; Autodetect New Partitions (Auto-Add!)
1962	CFG_PasswordSetup db 0 ; Ask Password when entering Setup
1963	CFG_PasswordSystem db 0 ; Ask Password when booting System
1964	CFG_PasswordChangeBoot db 0 ; Ask Password when changing boot partition
1965	CFG_ProtectMBR db 0 ; Protect MBR via TSR ?
1966	CFG_IgnoreWriteToMBR db 0 ; Just ignore writes to MBR, otherwise crash
1967	CFG_FloppyBootGetName db 0 ; Gets floppy name for display purposes
1968	CFG_DetectVirus db 0 ; Detect Virus ?
1969	CFG_DetectStealth db 0 ; Detect Stealth-Virus ?
1970	CFG_DetectVIBR db 0 ; Detect BootRecord-Virus ?
1971	CFG_AutoEnterSetup db 0 ; Automatic Enter Setup (first install!)
1972	CFG_MasterPassword dw 0101Fh ; Encoded Password (this is just CR)
1973	dw 07A53h
1974	dw 0E797h
1975	dw 0A896h
1976	CFG_BootPassword dw 0101Fh ; Another CR... ;-)
1977	dw 07A53h
1978	dw 0E797h
1979	dw 0A896h
1980	db 0 ; Rude-Protection - Removed since v0.28b
1981	CFG_LinuxRootPartition db 0 ; Linux Root Partition (Base=0)
1982	CFG_TimedKeyHandling db 0 ; Timed Key Handling (for Timed Boot)
1983	; 0 - Do Nothing
1984	; 1 - Reset Time
1985	; 2 - Stop Time
1986	CFG_MakeSound db 0 ; Should be clear ;)
1987	CFG_FloppyBootGetTimer db 0 ; Floppy Name will get updated every 2 secs
1988	CFG_ResumeBIOSbootSeq db 1 ; If BIOS Boot Sequence should be resumed
1989	; 0 - Disabled
1990	; 1 - CD-ROM
1991	; 2 - Network
1992	; 3 - ZIP/LS120
1993	CFG_CooperBars db 0 ; If Cooper Bars should be shown
1994	CFG_LinuxCommandLine db 75 dup (0) ; Linux Command Line
1995	CFG_LinuxKrnlPartition db 0FFh ; FAT-16 Linux Kernel Partition (Base=0)
1996	; FFh -> Disabled
1997	CFG_LinuxDefaultKernel db 'DEFAULT', 4 dup (32), 0 ; Default Kernel Name
1998	CFG_LinuxLastKernel db 11 dup (32), 0 ; Last-Booted Kernel Name
1999	CFG_ExtPartitionMShack db 0 ; Extended Partition M$-Hack Global Enable
2000	CFG_AutomaticBoot db 0 ; Automatic Booting (only one bootup)
2001	CFG_PartAutomatic db 0 ; Partition-No for automatic booting
2002	CFG_ForceLBAUsage db 1 ; LBA-BIOS-API forced on any HDD I/O
2003	CFG_IgnoreLVM db 0 ; Ignores any LVM-Information
2004
2005
2006	;
2007	; THERE IS ROOM RESERVED HERE FOR MORE VARIABLES
2008	;
2009
2010	;
2011	; Drive Letters.
2012	;
2013	; BOOKMARK: Stored Drive Letters
2014	ORIGIN 06CB0h
2015
2016
2017	; -----------------------------------------------------------------------------
2018	; DRIVE LETTERS
2019	; -----------------------------------------------------------------------------
2020
2021	;
2022	; Moved here to make room for packed hiddenparttable.
2023	; This gets filled with drive-letters that are assigned using the dl-feature.
2024	;
2025	DriveLetters db LocIPT_MaxPartitions dup (0)
2026	; Format is:
2027	;============
2028	; Drive-Letter : BYTE (80h-C:, 81h-D:)
2029	; --------------------> 1 Byte * 45
2030
2031
2032
2033	; -----------------------------------------------------------------------------
2034	; INSTALL VOLUME
2035	; -----------------------------------------------------------------------------
2036
2037	;
2038	; Allways have the name of the installation volume
2039	; at this offset.
2040	; So future config changes will not break auto-install.
2041	;
2042	; BOOKMARK: Name of OS/2 Installation Volume
2043	ORIGIN 06D00h
2044
2045	; SET(A)BOOT stores the volume name of the OS/2 system being installed here.
2046	; It is truncated to 11 chars because AiR-BOOT currently does not support
2047	; longer labelnames. The name is also capitalized.
2048	OS2_InstallVolume db 0,'NOPHASEONE' ,0
2049
2050	;
2051	; THERE IS ROOM RESERVED HERE FOR MORE VARIABLES
2052	;
2053
2054
2055	; -----------------------------------------------------------------------------
2056	; FLOPPY/CDROM/BIOS BOOT ENTRIES
2057	; -----------------------------------------------------------------------------
2058
2059	;
2060	; 06DABh - 06C00h = 01ABh = 427 bytes.
2061	; Entries allocated down from 06E00 boundary.
2062	;
2063	; BOOKMARK: Floppy/CD-ROM/BIOS Boot Entries
2064	ORIGIN 06DABh ; 427 Boundry
2065
2066	; (432 - 5 = 427)
2067	AutoDrvLetter db 0
2068	AutoDrvLetterSerial dd 0
2069
2070	; This entry is also 34 bytes long (466 - 34 = 432)
2071	BIOScontIPTentry:
2072	db 0, 0, 0, 0, ' '
2073	db 0, 0FEh, Flags_Bootable
2074	dw 0 ; No Checksum :)
2075	db 0, 1, 0
2076	db 0, 1, 0 ; Location of Partition/Boot Record
2077	dd 0, 0
2078
2079	; VIR variables are for the AiR-BOOT Anti Virus Code
2080	; Most of them are backups of Interrupt Points, so we can check, if a
2081	; stealth virus is on-line, we can intercept its call.
2082	; Normal (non stealth) virus are trapped simply by rereading the MBR sector.
2083	; If a virus is found, we will restore MBR from Sektor 60/62 and stop the
2084	; system from working, so the user has to press reset.
2085	; That's saver than a Reboot.
2086	;
2087	; If a virus is found on the partition to boot, the system will ONLY halt,
2088	; nothing more, because we can not remove it. The user shall do it :)
2089	; Those viruses are detected via a real nasty method...Checksum-Checking of the
2090	; boot-record, which is to be executed. If it does not match the one in our
2091	; internal partition table, we will stop. You may however switch this detection
2092	; off or just reset it by switching 'VIBR Detection'.
2093
2094	; 478 - 12 = 466 ; 466 Sub-Part
2095	CFG_VIR_INT08 dd 0 ; pointer to saved 08h entry point
2096	CFG_VIR_INT13 dd 0 ; pointer to saved 13h entry point
2097	CFG_VIR_INT1C dd 0 ; pointer to saved 1Ch entry point
2098
2099	; 478 Boundry (512-34)
2100	; This entry is also 34 bytes long
2101	FloppyIPTentry db 0, 0, 0, 0, 'FloppyDrive'
2102	db 0, 0FFh, Flags_Bootable
2103	dw 0 ; No Checksum :)
2104	db 0, 1, 0
2105	db 0, 1, 0 ; Location of Partition/Boot Record
2106	dd 0, 0
2107
2108
2109
2110	; -----------------------------------------------------------------------------
2111	; INTERNAL PARTITION TABLE (IPT)
2112	; -----------------------------------------------------------------------------
2113
2114	;
2115	; AiR-BOOT Internal Partition Table (IPT)
2116	;
2117	; BOOKMARK: Internal Partition Table
2118	ORIGIN % (image_size - 0a00h - (image_size - image_size_60secs))
2119
2120
2121	;
2122	; Rousseau: This is the start of the AiR-BOOT IPT
2123	;
2124	PartitionTable db (LocIPT_MaxPartitions * LocIPT_LenOfIPT) dup (0)
2125	; no-partitions detected... :]
2126	; db 1, 0, 0, 0, 'Harddisc 1'
2127	; db 0, 0FFh, Flags_BootAble
2128	; dw 0 ; No Checksum :)
2129	; db 0, 0, 1
2130	; db 0, 0, 1 ; Location of Partition/Boot Record
2131	; dd 0, 0
2132
2133	; Format is:
2134	;============
2135	; SerialNumber * 4
2136	; PartitionName * 11
2137	; Drive * 1
2138	; SystemID * 1 (means the partition type)
2139	; Flags * 1
2140	; Checksum * 2 (for virus checking)
2141	; LocationBegin * 3 (where the partition begins)
2142	; LocationPartTab * 3 (where the partition table is)
2143	; AbsoluteBegin * 4 (where the partition begins, in absolute sectors)
2144	; AbsolutePartTab * 4 (where the partition table is, in absolute sectors)
2145	; --------------------> 34 Bytes (total maximum partition-entries = 30)
2146
2147
2148
2149	; No need to check overlap here because this string will
2150	; be overwritten if the maximum partition count is reached.
2151	; So this is not a critical boundary.
2152	ORG (image_size - 600h - (image_size - image_size_60secs) / 2 - 10)
2153
2154	db 'AiRBOOTPAR' ; 1K internal partition table
2155
2156
2157
2158	; -----------------------------------------------------------------------------
2159	; HIDDEN PARTITION TABLE (HPT)
2160	; -----------------------------------------------------------------------------
2161
2162	;
2163	; Hidden Partition Table (6-bit packed as of v1.0.8)
2164	;
2165	; BOOKMARK: Hidden Partition Table (packed)
2166	ORIGIN % (image_size - 600h - (image_size - image_size_60secs) / 2)
2167
2168	HidePartitionTable db (LocIPT_MaxPartitions * LocHPT_LenOfHPT) dup (0FFh)
2169	; Format is:
2170	;============
2171	; PartitionPtr : BYTE * 30
2172	; --------------------> 30 Bytes * 45
2173
2174	;
2175	; Driveletters were here.
2176	; Moved down to make room for packed hideparttable.
2177	;
2178
2179
2180	;
2181	; End of hidden partition table.
2182	; Check overlap here for security reasons.
2183	;
2184	ORIGIN % (image_size - 200h - 5)
2185
2186	; 79fa - end of packed hide table
2187	db 'ABHID' ; 1K internal Hide-partition table
2188
2189
2190
2191
2192	;==============================================================================
2193	; Sector 62
2194	;==============================================================================
2195	; -----------------------------------------------------------------------------
2196	; MBR BACKUP
2197	; -----------------------------------------------------------------------------
2198
2199	;
2200	; AiR-BOOT MBR Backup.
2201	;
2202	; BOOKMARK: MBR Backup
2203	ORIGIN % (image_size - 200h)
2204
2205
2206	MBR_BackUpMBR db 'AiR-BOOT MBR-BackUp',\
2207	' - Just to fill this sector with something',0
2208	AirBootRocks db 'AiR-BOOT Rocks!',0
2209
2210	db (512 - ($-MBR_BackUpMBR) - 2) dup('M')
2211
2212	; End of Image signature.
2213	;
2214	ORIGIN % (image_size - 2)
2215	dw 0BABEh
2216
2217
2218	;
2219	; End of Image.
2220	;
2221	ORIGIN % (image_size)
2222	image_end:
2223
2224	;
2225	; Terminate LDRIMAGE segment.
2226	;
2227	IFDEF SEGMENTED
2228	LDRIMAGE ENDS
2229	ENDIF
2230
2231
2232
2233
2234
2235
2236
2237	;##############################################################################
2238	; BSS SEGMENT
2239	;##############################################################################
2240
2241	; BOOKMARK: BSS Segment
2242
2243	;
2244	; Open BSS segment.
2245	;
2246	IFDEF SEGMENTED
2247	VOLATILE SEGMENT USE16 PUBLIC 'BSS'
2248	ENDIF
2249
2250
2251
2252	sobss:
2253	sobss_abs = offset sobss + image_size
2254	;------------------------------------------------------------------------------
2255
2256
2257	;
2258	; This is the actual start of the BSS.
2259	; In the past however, we have had a code-loop that went out of bounds,
2260	; overwriting the start of the BSS.
2261	;
2262	; Because important runtime data is stored in the BSS, we offset it
2263	; by 400h bytes. Since the loader-image is always 62 sectors, which
2264	; makes it 7c00h in size, the runtime data starts at 8000h.
2265	; This is the 'BeginOfVariables' location.
2266	;
2267
2268
2269	;
2270	; If segmented, offsets are relative to the BSS segment.
2271	; They are resolved at link-time.
2272	; If not segmented, offsets are relative to the CODE segment.
2273	;
2274	IFDEF SEGMENTED
2275	ORG 00400h ; 7c00h + 400h = 8000h
2276	ELSE
2277	ORG 08000h ; 8000h
2278	ENDIF
2279
2280
2281	; -----------------------------------------------------------------------------
2282	; START OF BSS DATA
2283	; -----------------------------------------------------------------------------
2284	; This space actually gets initialized in PreCrap to NUL (till EndOfVariables)
2285	BeginOfVariables:
2286	BeginOfVariablesAbs = offset BeginOfVariables + image_size
2287
2288
2289	; -----------------------------------------------------------------------------
2290	; SECTOR BUFFERS
2291	; -----------------------------------------------------------------------------
2292	; BOOKMARK: Sector Buffers
2293	PartitionSector db 512 dup (?) ; Temporary Sector for Partition
2294	PBRSector db 512 dup (?) ; Temporary Sector for JFS/HPFS writeback
2295	LVMSector db 512 dup (?) ; Temporary Sector for LVM
2296	TmpSector db 512 dup (?) ; Temporary Sector
2297	Scratch db 512 dup (?) ; Scratch buffer
2298	ALIGN 16
2299
2300
2301	; -----------------------------------------------------------------------------
2302	; NEW PARTITION TABLE
2303	; -----------------------------------------------------------------------------
2304	; Everything used to build a new IPT and reference it to the old one
2305	; BOOKMARK: New Partition Table
2306	NewPartTable db 1536 dup (?) ; New Partition Table
2307	ALIGN 16
2308
2309
2310	; -----------------------------------------------------------------------------
2311	; NEW HIDE PARTITION TABLE
2312	; -----------------------------------------------------------------------------
2313	; BOOKMARK: New Hide-Partition Table
2314	NewHidePartTable db LocIPT_MaxPartitions * LocHPT_LenOfHPT dup (?)
2315	ALIGN 16
2316
2317
2318	; -----------------------------------------------------------------------------
2319	; NEW DRIVE LETTERS
2320	; -----------------------------------------------------------------------------
2321	; BOOKMARK: Logical Drive-Letters
2322	NewDriveLetters db LocIPT_MaxPartitions dup (?)
2323	ALIGN 16
2324
2325
2326	; -----------------------------------------------------------------------------
2327	; PARTITION SIZE TABLE
2328	; -----------------------------------------------------------------------------
2329	; Size-Table (6 bytes per partition)
2330	; BOOKMARK: Partition Size Table
2331	PartitionSizeTable db LocIPT_MaxPartitions * 6 dup (?)
2332	ALIGN 16
2333
2334
2335	; -----------------------------------------------------------------------------
2336	; PARTITION POINTERS
2337	; -----------------------------------------------------------------------------
2338	; Maximum is 52 word entries till now
2339	; BOOKMARK: Partition Pointers
2340	PartitionPointers dw 52 dup (?)
2341	ALIGN 16
2342
2343	; Count of total Partition Pointers
2344	PartitionPointerCount db ?
2345	ALIGN 16
2346
2347
2348	; -----------------------------------------------------------------------------
2349	; XREF TABLE
2350	; -----------------------------------------------------------------------------
2351	; X-Reference Table (holds new partnr, index is old part nr)
2352	; BOOKMARK: Xref Table
2353	PartitionXref db LocIPT_MaxPartitions dup (?)
2354	ALIGN 16
2355
2356
2357	; -----------------------------------------------------------------------------
2358	; VOLUME LETTERS
2359	; -----------------------------------------------------------------------------
2360	; Volume-Letters
2361	; 0 - no LVM support
2362	; 1 - LVM support, but no letter
2363	; 'C'-'Z' - assigned drive letter
2364	; BOOKMARK: Volume Drive Letters
2365	PartitionVolumeLetters db LocIPT_MaxPartitions dup (?)
2366	ALIGN 16
2367
2368
2369	; -----------------------------------------------------------------------------
2370	; MISC VARS AND FLAGS
2371	; -----------------------------------------------------------------------------
2372	; BOOKMARK: Misc Vars and Flags
2373	TotalHarddiscs db ? ; Total harddrives (by POST)
2374	LBASwitchTable db 128 dup (?) ; Bit 25-18 for CHS/LBA Switching
2375	NewPartitions db ? ; Freshly found partitions
2376	; Independent of SaveConfiguration
2377	TooManyPartitions db ? ; Non-zero if too many partitions found
2378
2379	VideoIO_Segment dw ? ; Segment for Video I/O
2380
2381	ExtendedAbsPos dd ? ; Extended Partition Absolute Position
2382	ExtendedAbsPosSet db ? ; If Absolute Position set
2383
2384	CurPartition_Location dw 4 dup (?) ; Where did current partition come from?
2385	CurIO_UseExtension db ? ; 1-Use INT 13h EXTENSIONS
2386	; (filled out by PreCrap)
2387	CurIO_Scanning db ? ; 1-AiR-BOOT is scanning partitions
2388	; (for detailed error message)
2389	ALIGN 16
2390
2391
2392	; -----------------------------------------------------------------------------
2393	; MENU RELATED VARS
2394	; -----------------------------------------------------------------------------
2395	Menu_EntrySelected db ? ; Which partition we boot this time...
2396	Menu_UpperPart db ? ; Which number (Base=0) is the partition upper pos
2397	Menu_AbsoluteX db ? ; Pos where Menu stuff starts
2398	Menu_TotalParts db ? ; Copy of CFG_BootParts
2399	Menu_TotalLines db ? ; Total Lines on Screen used for BootMenu
2400	Menu_EntryDefault db ? ; Default Entry in filtered View
2401	Menu_EntryLast db ? ; LastBooted Entry in filtered View
2402	Menu_EntryAutomatic db ? ; Automatic Entry in filtered View
2403	; - All adjusted to menu locations
2404	ALIGN 16
2405
2406
2407	; -----------------------------------------------------------------------------
2408	; PARTITION RELATED VARS
2409	; -----------------------------------------------------------------------------
2410	PartSetup_UpperPart db ? ; Partition-Setup (like Menu_UpperPart)
2411	PartSetup_ActivePart db ? ; Active Partition
2412	PartSetup_HiddenUpper db ? ; (like Menu_UpperPart)
2413	PartSetup_HiddenX db ? ; Pos for Hidden-Setup
2414	PartSetup_HiddenAdd db ? ; Adjust for Hidden-Setup
2415	ALIGN 16
2416
2417
2418	; -----------------------------------------------------------------------------
2419	; TIMER / SETUP RELATED VARS
2420	; -----------------------------------------------------------------------------
2421	TimedBootEnable db ? ; Local Enable/Disable for timed boot
2422	TimedTimeOut dd ? ; TimeOut Timer for TimedBoot (too much time here;)
2423	TimedSecondLeft db ? ; How many seconds are left till boom ?
2424	TimedSecondBack db ? ; To get a modification noticed
2425	TimedBootUsed db ? ; Timed Boot used for bootup ?
2426	FloppyGetNameTimer dd ? ; Timer for Floppy-Get-Name
2427	SETUP_KeysOnEntry db ? ; which Shift Status was there, when booting ?
2428	SETUP_ExitEvent db ? ; Exit Event to end SETUP
2429	TempPasswordEntry db 17 dup (?)
2430	SETUP_OldPwd db 17 dup (?)
2431	SETUP_NewPwd db 17 dup (?)
2432	SETUP_VerifyPwd db 17 dup (?)
2433	StartSoundPlayed db ?
2434	ChangePartNameSave db ? ; Save label after user-edit ?
2435	SyncLvmLabels db ? ; Sync LVM labels after user-edit ?
2436	ALIGN 16
2437
2438
2439	; -----------------------------------------------------------------------------
2440	; FX RELATED VARS
2441	; -----------------------------------------------------------------------------
2442	FX_UseCount dw ?
2443	FX_OverallTimer dw ?
2444	FX_WideScrollerTimer dw ?
2445	FX_WideScrollerCurPos dw ?
2446	FX_WideScrollerSpeed db ?
2447	FX_WideScrollerSpeedState db ?
2448	FX_WideScrollerDirection db ?
2449	FX_WideScrollerAbsDirection db ?
2450	FX_WideScrollerBounceSpeed db ?
2451	FX_CooperBarsTimer dw ?
2452	ALIGN 16
2453
2454	; Dynamically Generated Tables - do not need to get initialized with NUL
2455	FX_CooperColors db 672 dup (?) ; 7 cooper bars*96 - runtime calculated
2456	FX_CooperState db 7 dup (?)
2457	FX_SinusPos db 7 dup (?)
2458	FX_CooperPos dw 7 dup (?)
2459	ALIGN 16
2460
2461
2462	; -----------------------------------------------------------------------------
2463	; CHARSET BUFFER
2464	; -----------------------------------------------------------------------------
2465	CharsetTempBuffer db 4096 dup (?) ; Uninitialized Charset buffer
2466	ALIGN 16
2467
2468
2469	; -----------------------------------------------------------------------------
2470	; LVM CRC TABLE
2471	; -----------------------------------------------------------------------------
2472	LVM_CRCTable dd 256 dup (?) ; LVM-CRC (->SPECiAL\LVM.asm)
2473	ALIGN 16
2474
2475
2476	; -----------------------------------------------------------------------------
2477	; LVM DRIVE-LETTER MAP
2478	; -----------------------------------------------------------------------------
2479	; Get's initialized at startup to: 00000011111111111111111111111100b
2480	; Meaning A,B not free; C-Z free, rest unused. (right to left)
2481	; Each partition with an assigned drive-letter clears a bit in this map.
2482	FreeDriveletterMap dd ?
2483	ALIGN 16
2484
2485
2486	; -----------------------------------------------------------------------------
2487	; OS/2 PHASE1 RELATED
2488	; -----------------------------------------------------------------------------
2489	Phase1Active db ?
2490	OldPartitionCount db ?
2491	ALIGN 16
2492
2493
2494	; -----------------------------------------------------------------------------
2495	; ARRAY OF DISK INFORMATION STRUCTURES
2496	; -----------------------------------------------------------------------------
2497	; Array of DISKINFO structures
2498	DiskInformation db MaxDisks dup(DISKINFO_Size dup(?))
2499	ALIGN 16
2500
2501
2502	; -----------------------------------------------------------------------------
2503	; INT13X DAP
2504	; -----------------------------------------------------------------------------
2505	; Disk Address Package that holds information for LBA-access using INT13X
2506	INT13X_DAP db ? ; Size of paket, inserted by code
2507	db ? ; Reserved
2508	INT13X_DAP_NumBlocks dw ? ; Number of blocks
2509	INT13X_DAP_Transfer dd ? ; Transfer Adress
2510	INT13X_DAP_Absolute dd ? ; Absolute Sector
2511	dd ? ; Second Part of QWORD
2512	INT13X_DAP_Size = $-offset [INT13X_DAP] ; Calculated size
2513	ALIGN 16
2514
2515
2516	; -----------------------------------------------------------------------------
2517	; DEBUG
2518	; -----------------------------------------------------------------------------
2519	; Some debug area.
2520	dbg_scratch db 512 dup(?)
2521	ALIGN 16
2522
2523
2524	; End of transient variables.
2525	EndOfVariables:
2526	EndOfVariablesAbs = offset EndOfVariables + image_size
2527
2528
2529
2530	; -----------------------------------------------------------------------------
2531	; OLD AND NEW STACKS
2532	; -----------------------------------------------------------------------------
2533	; BOOKMARK: Storage for Old and New Stack Pointers
2534	;
2535	; These need to be outside the variable section because AiR-BOOT can restart
2536	; itself in debug-mode. If the OldSP and OldSS would be in the variable area,
2537	; they would be cleared on AiR-BOOT restart.
2538	;
2539
2540	; The variable section is cleared word-wise, so it could clear one byte extra
2541	; depending on the alignment and size. This DD prevents the OldSP and OldSS
2542	; to be partly overwritten by the clearing routine.
2543	dd ?
2544	ALIGN 16
2545
2546	; SS:SP from before our relocation.
2547	; The registers values when the BIOS transferred control to us were pushed
2548	; on this stack.
2549
2550	OldSP dw ?
2551	OldSS dw ?
2552
2553	; SS:SP currently in use.
2554	; They are temporarily dumped here so we can pop the resgisters from
2555	; the old stack to display them in debug mode.
2556	CurrentSP dw ?
2557	CurrentSS dw ?
2558	ALIGN 16
2559
2560	; Usually, commits are buildable and some minor checking has been done that
2561	; whole disks do not get wiped. However, there are situations where stuff is
2562	; in such a flux that it would be better to do non-buildable commits.
2563	; That makes it possible to record the changes piecemeal without the danger of
2564	; accidently using the resulting loader. Of course everyone is clever enough
2565	; to _never_ build commits marked as 'testing' and install the result in
2566	; environments where wiping all attached disks and sticks would be a problem...
2567	;~ force_build_error dd 0f000h dup(?)
2568
2569	;
2570	; End of BSS segment.
2571	;
2572	eobss:
2573	eobss_abs = offset eobss + image_size
2574	;
2575	; Total RAM occupied, including BSS.
2576	; BASE is 8000:0000, LIMIT is 8000:FFFF.
2577	; Note that the LDRIMAGE is of constant size, 7C00h = 62 sectors of 512 bytes.
2578	;
2579	resident_size = offset eobss + image_size
2580
2581	;
2582	; Close BSS segment.
2583	;
2584	IFDEF SEGMENTED
2585	VOLATILE ENDS
2586	ELSE
2587	LDRIMAGE ENDS
2588	ENDIF
2589
2590	; BOOKMARK: End of Module
2591	END AiR_BOOT
2592

Note: See TracBrowser for help on using the repository browser.

Context Navigation

source: trunk/bootcode/airboot.asm@ 180

Download in other formats: