//=========================================
// Angel wings
//-----------------------------------------
// These wings don't look good in close-up !
// Used in "Casualty of War".
// -----------------------------------------
// Made for Persistence of vision 3.6
//==========================================  
// Copyright 1999-2004 Gilles Tran http://www.oyonale.com
// -----------------------------------------
// This work is licensed under the Creative Commons Attribution License. 
// To view a copy of this license, visit http://creativecommons.org/licenses/by/2.0/ 
// or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.
// You are free:
// - to copy, distribute, display, and perform the work
// - to make derivative works
// - to make commercial use of the work
// Under the following conditions:
// - Attribution. You must give the original author credit.
// - For any reuse or distribution, you must make clear to others the license terms of this work.
// - Any of these conditions can be waived if you get permission from the copyright holder.
// Your fair use and other rights are in no way affected by the above. 
//==========================================  

#include "colors.inc"
global_settings{
    assumed_gamma 1
    radiosity{ recursion_limit 1 brightness 0.5}
}
// Camera
camera{
  location y*10-120*z
  direction 4*z
  look_at y*9
 }
// Light
light_source {< -1000, 1000, -1000>  color White*1.3 }
background{rgb <90,120,250>/255}

// creates a smooth blobby shape
#declare StrengthVal = 1.0; // (+ or -) strength of component's radiating density
#declare RadiusVal   = 1.0; // (0 < RadiusVal) outer sphere of influence on other components
#declare Wing=blob{
    threshold 0.3
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <2,13,0.2> translate y*13 rotate z*-2 rotate y*1}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,12,0.2> translate y*12 rotate z*-10 rotate y*3}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,11,0.2> translate y*11 rotate z*-16 rotate y*5}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,10,0.2> translate y*10 rotate z*-22 rotate y*7}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,9,0.2> translate y*9 rotate z*-28 rotate y*9}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,8,0.2> translate y*8 rotate z*-34 rotate y*11}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,7,0.2> translate y*7 rotate z*-40 rotate y*13}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,6,0.2> translate y*6 rotate z*-46 rotate y*15}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,5,0.2> translate y*5 rotate z*-54 rotate y*17}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,5,0.2> translate y*5 rotate z*-60 rotate y*15}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,5,0.2> translate y*5 rotate z*-66 rotate y*14}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,5,0.2> translate y*5 rotate z*-72 rotate y*13}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,5,0.2> translate y*5 rotate z*-80 rotate y*12}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,5.2,0.2> translate y*5 rotate z*-86 rotate y*11}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,5.3,0.2> translate y*5 rotate z*-92 rotate y*10}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,5.4,0.1> translate y*5 rotate z*-98 rotate y*9}
    
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,4,0.2> translate y*4.1 rotate z*-105 translate x rotate y*8}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,5,0.2> translate y*4.2 rotate z*-110 translate x rotate y*7}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,5,0.2> translate y*4.3 rotate z*-115 translate x rotate y*6}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,5,0.2> translate y*4.5 rotate z*-120 translate x rotate y*5}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,5,0.2> translate y*5 rotate z*-125 translate x rotate y*4}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,6,0.2> translate y*6 rotate z*-130 translate x rotate y*3}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,7,0.2> translate y*6 rotate z*-135 translate x rotate y*2}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,8.5,0.2> translate y*6 rotate z*-140 translate x rotate y*1}
    sphere { <0, 0, 0>, StrengthVal, RadiusVal scale <1.5,8.5,0.2> translate y*6 rotate z*-145 translate x rotate y*0}
    sturm
}

#declare T_Wing=texture{
     pigment{White}
     normal{bumps 0.1 scale 0.5}
     finish{ambient 0 diffuse 0.8}
}
#declare Wings=union{
    object{Wing scale <1.5,1,-1> translate y*12 rotate x*-40}
    object{Wing scale <1.5,1,1> translate y*12 rotate x*40}
    texture{T_Wing}
    translate y*-4
}

object{Wings rotate y*45}